idl/SMESH_Mesh.idl

   1 //  Copyright (C) 2007-2008  CEA/DEN, EDF R&D, OPEN CASCADE
   2 //
   3 //  Copyright (C) 2003-2007  OPEN CASCADE, EADS/CCR, LIP6, CEA/DEN,
   4 //  CEDRAT, EDF R&D, LEG, PRINCIPIA R&D, BUREAU VERITAS
   5 //
   6 //  This library is free software; you can redistribute it and/or
   7 //  modify it under the terms of the GNU Lesser General Public
   8 //  License as published by the Free Software Foundation; either
   9 //  version 2.1 of the License.
  10 //
  11 //  This library is distributed in the hope that it will be useful,
  12 //  but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 //  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14 //  Lesser General Public License for more details.
  15 //
  16 //  You should have received a copy of the GNU Lesser General Public
  17 //  License along with this library; if not, write to the Free Software
  18 //  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
  19 //
  20 //  See http://www.salome-platform.org/ or email : webmaster.salome@opencascade.com
  21 //
  22 //  File   : SMESH_Mesh.idl
  23 //  Author : Paul RASCLE, EDF
  24 //
  25
  26 #ifndef _SMESH_MESH_IDL_
  27 #define _SMESH_MESH_IDL_
  28
  29 #include "SALOME_Exception.idl"
  30 #include "SALOME_GenericObj.idl"
  31 #include "GEOM_Gen.idl"
  32 #include "MED.idl"
  33
  34 module SMESH
  35 {
  36   interface SMESH_Hypothesis;
  37   typedef sequence<SMESH_Hypothesis> ListOfHypothesis;
  38   interface SMESH_GroupBase;
  39   typedef sequence<SMESH_GroupBase> ListOfGroups;
  40
  41   typedef sequence<double    > double_array ;
  42   typedef sequence<long      > long_array ;
  43   typedef sequence<string    > string_array ;
  44   typedef sequence<long_array> array_of_long_array ;
  45
  46   enum log_command
  47     {
  48       ADD_NODE,
  49       ADD_EDGE,
  50       ADD_TRIANGLE,
  51       ADD_QUADRANGLE,
  52       ADD_POLYGON,
  53       ADD_TETRAHEDRON,
  54       ADD_PYRAMID,
  55       ADD_PRISM,
  56       ADD_HEXAHEDRON,
  57       ADD_POLYHEDRON,
  58       REMOVE_NODE,
  59       REMOVE_ELEMENT,
  60       MOVE_NODE,
  61       CHANGE_ELEMENT_NODES,
  62       CHANGE_POLYHEDRON_NODES,
  63       RENUMBER,
  64       CLEAR_MESH,
  65       ADD_QUADEDGE,
  66       ADD_QUADTRIANGLE,
  67       ADD_QUADQUADRANGLE,
  68       ADD_QUADTETRAHEDRON,
  69       ADD_QUADPYRAMID,
  70       ADD_QUADPENTAHEDRON,
  71       ADD_QUADHEXAHEDRON,
  72       ADD_ELEM0D
  73     };
  74
  75   struct log_block
  76   {
  77     long commandType;
  78     long number;
  79     double_array coords;
  80     long_array indexes;
  81   };
  82
  83   struct PointStruct { double x;
  84                        double y;
  85                        double z; } ;
  86
  87   typedef sequence<PointStruct> nodes_array;
  88
  89   struct DirStruct   { PointStruct PS ; } ;          // analog to Occ Direction
  90
  91   struct AxisStruct  { double x;
  92                        double y;
  93                        double z;
  94                        double vx;
  95                        double vy;
  96                        double vz; } ;
  97
  98   /*!
  99    * Node location on a shape
 100    */
 101   struct NodePosition {
 102     long             shapeID;
 103     GEOM::shape_type shapeType;
 104     double_array     params; // [U] on EDGE, [U,V] on FACE, [] on the rest shapes
 105   };
 106
 107   /*!
 108    * Enumeration for element type, like in SMDS
 109    */
 110   enum ElementType
 111   {
 112     ALL,
 113     NODE,
 114     EDGE,
 115     FACE,
 116     VOLUME,
 117     ELEM0D
 118   };
 119
 120   /*!
 121    * Enumeration for element geometry type, like in SMDS
 122    */
 123   enum GeometryType
 124   {
 125     Geom_POINT,
 126     Geom_EDGE,
 127     Geom_TRIANGLE,
 128     Geom_QUADRANGLE,
 129     Geom_POLYGON,
 130     Geom_TETRA,
 131     Geom_PYRAMID,
 132     Geom_HEXA,
 133     Geom_PENTA,
 134     Geom_POLYHEDRA
 135   };
 136
 137   /*!
 138    * ElementOrder points out entities of what order are requested
 139    */
 140   enum ElementOrder {
 141     ORDER_ANY,          /*! entities of any order */
 142     ORDER_LINEAR,       /*! entities of 1st order */
 143     ORDER_QUADRATIC     /*! entities of 2nd order */
 144   };
 145
 146
 147   /*!
 148    * Enumeration of entity type uses in mesh info array,
 149    *  and should be synchronised with enum in SMDS
 150    */
 151   enum EntityType
 152   {
 153     Entity_Node,
 154     Entity_0D,
 155     Entity_Edge,
 156     Entity_Quad_Edge,
 157     Entity_Triangle,
 158     Entity_Quad_Triangle,
 159     Entity_Quadrangle,
 160     Entity_Quad_Quadrangle,
 161     Entity_Polygon,
 162     Entity_Quad_Polygon,
 163     Entity_Tetra,
 164     Entity_Quad_Tetra,
 165     Entity_Pyramid,
 166     Entity_Quad_Pyramid,
 167     Entity_Hexa,
 168     Entity_Quad_Hexa,
 169     Entity_Penta,
 170     Entity_Quad_Penta,
 171     Entity_Polyhedra,
 172     Entity_Quad_Polyhedra,
 173     Entity_Last
 174   };
 175
 176
 177   /*!
 178    * Enumeration for hypothesis status (used by AddHypothesis() and RemoveHypothesis() methods)
 179    */
 180   enum Hypothesis_Status // in the order of severity
 181   {
 182     HYP_OK,
 183     HYP_MISSING,      // algo misses a hypothesis
 184     HYP_CONCURENT,    // several applicable hypotheses
 185     HYP_BAD_PARAMETER,// hypothesis has a bad parameter value
 186     HYP_HIDDEN_ALGO,  // an algo is hidden by an upper dim algo generating all-dim elements
 187     HYP_HIDING_ALGO,  // an algo hides lower dim algos by generating all-dim elements
 188     HYP_UNKNOWN_FATAL,//  --- all statuses below should be considered as fatal
 189                       //      for Add/RemoveHypothesis operations
 190     HYP_INCOMPATIBLE, // hypothesis does not fit algo
 191     HYP_NOTCONFORM,   // not conform mesh is produced appling a hypothesis
 192     HYP_ALREADY_EXIST,// such hypothesis already exist
 193     HYP_BAD_DIM,      // bad dimension
 194     HYP_BAD_SUBSHAPE, // shape is neither the main one, nor its subshape, nor a group
 195     HYP_BAD_GEOMETRY, // geometry mismatches algorithm's expectation
 196     HYP_NEED_SHAPE    // algorithm can work on shape only
 197   };
 198
 199   /*!
 200    * Enumeration for DriverMED read status (used by ImportMEDFile() method)
 201    */
 202   enum DriverMED_ReadStatus // in the order of severity
 203   {
 204     DRS_OK,
 205     DRS_EMPTY,          // a MED file contains no mesh with the given name
 206     DRS_WARN_RENUMBER,  // a MED file has overlapped ranges of element numbers,
 207                         // so the numbers from the file are ignored
 208     DRS_WARN_SKIP_ELEM, // some elements were skipped due to incorrect file data
 209     DRS_FAIL            // general failure (exception etc.)
 210   };
 211
 212   /*!
 213    * Enumeration for DriverMED (used by Perform() method)
 214    */
 215   enum MED_VERSION // in the order of severity
 216   {
 217     MED_V2_1,
 218     MED_V2_2
 219   };
 220
 221   typedef sequence<log_block> log_array;
 222
 223
 224   /*!
 225    * Auxilary flags for advanced extrusion.
 226    * BOUNDARY: create or not boundary for result of extrusion
 227    * SEW:      try to use existing nodes or create new nodes in any case
 228    */
 229   const long EXTRUSION_FLAG_BOUNDARY = 1;
 230   const long EXTRUSION_FLAG_SEW = 2;
 231
 232   /*!
 233    * Structure used in mesh edit preview data (MeshPreviewStruct)
 234    */
 235   struct ElementSubType { ElementType SMDS_ElementType;
 236                           boolean     isPoly;
 237                           long        nbNodesInElement; };
 238
 239   typedef sequence<ElementSubType> types_array;
 240
 241   /*!
 242    * Structure containing mesh edit preview data
 243    */
 244   struct MeshPreviewStruct { nodes_array nodesXYZ;
 245                              long_array  elementConnectivities;
 246                              types_array elementTypes; };
 247
 248   interface SMESH_IDSource
 249   {
 250     /*!
 251      * Returns a sequence of all element IDs
 252      */
 253     long_array GetIDs();
 254
 255     /*!
 256      * Returns statistic of mesh elements
 257      * Result array of number enityties
 258      */
 259     long_array GetMeshInfo();
 260   };
 261
 262   interface SMESH_Group;
 263   interface SMESH_GroupOnGeom;
 264   interface SMESH_subMesh;
 265   interface SMESH_MeshEditor;
 266
 267   typedef sequence<SMESH_subMesh>     submesh_array;
 268   typedef sequence<submesh_array>     submesh_array_array;
 269
 270   interface SMESH_Mesh : SALOME::GenericObj, SMESH_IDSource
 271   {
 272     /*!
 273      * Return true if there is a geometry to be meshed
 274      */
 275     boolean HasShapeToMesh()
 276       raises (SALOME::SALOME_Exception);
 277
 278     /*!
 279      * Get geom shape to mesh. A result sould not be nil. Use HasShapeToMesh()
 280      * to know if a returned shape
 281      */
 282     GEOM::GEOM_Object GetShapeToMesh()
 283       raises (SALOME::SALOME_Exception);
 284
 285     /*!
 286      * Remove all nodes and elements
 287      */
 288     void Clear()
 289       raises (SALOME::SALOME_Exception);
 290
 291     /*!
 292      * Remove all nodes and elements of submesh
 293      */
 294     void ClearSubMesh(in long ShapeID)
 295       raises (SALOME::SALOME_Exception);
 296
 297     /*!
 298      * Get the subMesh object associated to a subShape. The subMesh object
 299      * gives access to nodes and elements IDs.
 300      * SubMesh will be used instead of SubShape in a next idl version to
 301      * adress a specific subMesh...
 302      */
 303     SMESH_subMesh GetSubMesh(in GEOM::GEOM_Object aSubObject, in string name)
 304       raises (SALOME::SALOME_Exception);
 305
 306     /*!
 307      * Remove a submesh
 308      */
 309     void RemoveSubMesh(in SMESH_subMesh aSubMesh)
 310       raises (SALOME::SALOME_Exception);
 311
 312
 313     /*!
 314      * Create a group
 315      */
 316     SMESH_Group CreateGroup( in ElementType elem_type,
 317                              in string name )
 318       raises (SALOME::SALOME_Exception);
 319
 320     /*!
 321      * Create a group from geometry group
 322      */
 323     SMESH_GroupOnGeom CreateGroupFromGEOM( in ElementType elem_type,
 324                                           in string name,
 325                                           in GEOM::GEOM_Object theGeomObject )
 326       raises (SALOME::SALOME_Exception);
 327
 328     /*!
 329      * Remove a group
 330      */
 331     void RemoveGroup(in SMESH_GroupBase aGroup)
 332       raises (SALOME::SALOME_Exception);
 333
 334     /*!
 335      *  Remove group with its contents
 336      */
 337     void RemoveGroupWithContents( in SMESH_GroupBase aGroup )
 338       raises (SALOME::SALOME_Exception);
 339
 340     /*!
 341      *  Get the list of groups existing in the mesh
 342      */
 343     ListOfGroups GetGroups()
 344       raises (SALOME::SALOME_Exception);
 345
 346     /*!
 347      *  Get number of groups existing in the mesh
 348      */
 349     long NbGroups()
 350       raises (SALOME::SALOME_Exception);
 351
 352     /*!
 353      * Union of two groups
 354      *    New group is created. All mesh elements that are
 355      *    present in initial groups are added to the new one
 356      */
 357     SMESH_Group UnionGroups (in SMESH_GroupBase aGroup1,
 358                              in SMESH_GroupBase aGroup2,
 359                              in string          name )
 360       raises (SALOME::SALOME_Exception);
 361
 362     /*!
 363      * Union of list of groups
 364      * New group is created. All mesh elements that are
 365      * present in initial groups are added to the new one
 366      */
 367     SMESH_Group UnionListOfGroups (in ListOfGroups aListOfGroups,
 368                                    in string       name )
 369       raises (SALOME::SALOME_Exception);
 370
 371     /*!
 372      *  Intersection of two groups
 373      *  New group is created. All mesh elements that are
 374      *  present in both initial groups are added to the new one.
 375      */
 376     SMESH_Group IntersectGroups (in SMESH_GroupBase aGroup1,
 377                                  in SMESH_GroupBase aGroup2,
 378                                  in string          name )
 379       raises (SALOME::SALOME_Exception);
 380
 381     /*!
 382      *  Intersection of list of groups
 383      *  New group is created. All mesh elements that are
 384      *  present in all initial groups simultaneously are added to the new one.
 385      */
 386     SMESH_Group IntersectListOfGroups (in ListOfGroups aListOfGroups,
 387                                        in string       name)
 388       raises (SALOME::SALOME_Exception);
 389
 390     /*!
 391      *  Cut of two groups
 392      *  New group is created. All mesh elements that are present in
 393      *  main group but do not present in tool group are added to the new one
 394      */
 395     SMESH_Group CutGroups (in SMESH_GroupBase aMainGroup,
 396                            in SMESH_GroupBase aToolGroup,
 397                            in string          name )
 398       raises (SALOME::SALOME_Exception);
 399
 400     /*!
 401      *  Cut of lists of groups
 402      *  New group is created. All mesh elements that are present in
 403      *  main groups but do not present in tool groups are added to the new one
 404      */
 405     SMESH_Group CutListOfGroups (in ListOfGroups aMainGroups,
 406                                  in ListOfGroups aToolGroups,
 407                                  in string       name)
 408       raises (SALOME::SALOME_Exception);
 409
 410     /*!
 411      *  Create groups of entities from existing groups of superior dimensions
 412      *  New group is created. System
 413      *  1) extracts all nodes from each group,
 414      *  2) combines all elements of specified dimension laying on these nodes.
 415      */
 416     SMESH_Group CreateDimGroup( in ListOfGroups aListOfGroups,
 417                                 in ElementType  anElemType,
 418                                 in string       name )
 419       raises (SALOME::SALOME_Exception);
 420
 421     /*!
 422      * Convert group on geometry into standalone group
 423      */
 424     SMESH_Group ConvertToStandalone( in SMESH_GroupOnGeom theGeomGroup )
 425       raises (SALOME::SALOME_Exception);
 426
 427     /*!
 428      * Add hypothesis to the mesh, under a particular subShape
 429      * (or the main shape itself)
 430      * The Add method is only used to prepare the build of the mesh and store
 431      * the algorithms and associated parameters.
 432      * Actual job of mesh the shape is done by MESH_Gen.
 433      * @params
 434      * - aSubShape : subShape obtained by a shape explode in GEOM
 435      *   (or main shape)
 436      * - anHyp : hypothesis object
 437      * @return
 438      * - OK if the hypothesis is compatible with the subShape
 439      *   (and all previous hypothesis on the subShape)
 440      * - NOK if the hypothesis is not compatible with the subShape
 441      *   (or one previous hypothesis on the subShape)
 442      * raises exception if hypothesis has not been created
 443      */
 444     Hypothesis_Status AddHypothesis(in GEOM::GEOM_Object aSubObject,
 445                                     in SMESH_Hypothesis anHyp)
 446       raises (SALOME::SALOME_Exception);
 447 //     boolean AddHypothesis(in SMESH_subMesh aSubMesh, in SMESH_Hypothesis anHyp)
 448 //       raises (SALOME::SALOME_Exception);
 449
 450     /*!
 451      * Remove an hypothesis previouly added with AddHypothesis.
 452      */
 453     Hypothesis_Status RemoveHypothesis(in GEOM::GEOM_Object aSubObject,
 454                                        in SMESH_Hypothesis anHyp)
 455       raises (SALOME::SALOME_Exception);
 456 //     boolean RemoveHypothesis(in SMESH_subMesh aSubMesh,
 457 //                           in SMESH_Hypothesis anHyp)
 458 //       raises (SALOME::SALOME_Exception);
 459
 460     /*!
 461      * Get the list of hypothesis added on a subShape
 462      */
 463     ListOfHypothesis GetHypothesisList(in GEOM::GEOM_Object aSubObject)
 464       raises (SALOME::SALOME_Exception);
 465 //     ListOfHypothesis GetHypothesisList(in SMESH_subMesh aSubMesh)
 466 //       raises (SALOME::SALOME_Exception);
 467
 468     /*!
 469      * Get the log of nodes and elements added or removed since previous
 470      * clear of the log.
 471      * @params
 472      * - clearAfterGet : log is emptied after Get (safe if concurrents access)
 473      */
 474     //    string_array GetLog(in boolean clearAfterGet)
 475     //      raises (SALOME::SALOME_Exception);
 476     log_array GetLog(in boolean clearAfterGet)
 477       raises (SALOME::SALOME_Exception);
 478
 479     /*!
 480      * Clear the log of nodes and elements added or removed since previous
 481      * clear. Must be used immediately after GetLog if clearAfterGet is false.
 482      */
 483     void ClearLog()
 484       raises (SALOME::SALOME_Exception);
 485
 486     /*!
 487      * Toggle auto color mode on the object.
 488      * @params
 489      * - theAutoColor : flag which toggles auto color mode.
 490      */
 491     void SetAutoColor(in boolean theAutoColor)
 492       raises (SALOME::SALOME_Exception);
 493
 494     /*!
 495      * Get flag of object's auto color mode.
 496      */
 497     boolean GetAutoColor()
 498       raises (SALOME::SALOME_Exception);
 499
 500     /*!
 501      * Get the internal Id
 502      */
 503     long GetId();
 504
 505     /*!
 506      * Get the study Id
 507      */
 508     long GetStudyId();
 509
 510     /*!
 511      * Obtain instance of SMESH_MeshEditor
 512      */
 513     SMESH_MeshEditor GetMeshEditor()
 514       raises (SALOME::SALOME_Exception);
 515
 516     /*!
 517      * Return SMESH_MeshEditor that would not modify the mesh but
 518      * fill MeshPreviewStruct
 519      */
 520     SMESH_MeshEditor GetMeshEditPreviewer()
 521       raises (SALOME::SALOME_Exception);
 522
 523     /*! Check group names for duplications.
 524      *  Consider maximum group name length stored in MED file.
 525      */
 526     boolean HasDuplicatedGroupNamesMED();
 527
 528     /*!
 529      * Export Mesh to different MED Formats
 530      * @params
 531      * - auto_groups : boolean parameter for creating/not creating
 532      *   the groups Group_On_All_Nodes, Group_On_All_Faces, ... ;
 533      *   the typical use is auto_groups=false.
 534      * - theVersion : define the version of format of MED file, that will be created
 535      */
 536     void ExportToMED( in string file, in boolean auto_groups, in MED_VERSION theVersion )
 537       raises (SALOME::SALOME_Exception);
 538
 539     /*!
 540      * Export Mesh to MED_V2_1 MED format
 541      * Works, just the same as ExportToMED, with MED_VERSION parameter equal to MED_V2_1.
 542      * The method is kept in order to support old functionality
 543      */
 544     void ExportMED( in string file, in boolean auto_groups )
 545       raises (SALOME::SALOME_Exception);
 546
 547     /*!
 548      * Return string representation of a MED file version comprising nbDigits
 549      */
 550     string GetVersionString(in MED_VERSION version, in short nbDigits);
 551
 552     /*!
 553      * Export Mesh to DAT, UNV and STL Formats
 554      * (UNV supported version is I-DEAS 10)
 555      */
 556     void ExportDAT( in string file )
 557       raises (SALOME::SALOME_Exception);
 558     void ExportUNV( in string file )
 559       raises (SALOME::SALOME_Exception);
 560     void ExportSTL( in string file, in boolean isascii )
 561       raises (SALOME::SALOME_Exception);
 562
 563     /*!
 564      * Get MED Mesh
 565      */
 566     SALOME_MED::MESH GetMEDMesh()
 567       raises (SALOME::SALOME_Exception);
 568
 569     /*!
 570      * Get informations about mesh contents
 571      */
 572     long NbNodes()
 573       raises (SALOME::SALOME_Exception);
 574
 575     long NbElements()
 576       raises (SALOME::SALOME_Exception);
 577
 578     long Nb0DElements()
 579       raises (SALOME::SALOME_Exception);
 580
 581     long NbEdges()
 582       raises (SALOME::SALOME_Exception);
 583
 584     long NbEdgesOfOrder(in ElementOrder order)
 585       raises (SALOME::SALOME_Exception);
 586
 587     long NbFaces()
 588       raises (SALOME::SALOME_Exception);
 589
 590     long NbFacesOfOrder(in ElementOrder order)
 591       raises (SALOME::SALOME_Exception);
 592
 593     long NbTriangles()
 594       raises (SALOME::SALOME_Exception);
 595
 596     long NbTrianglesOfOrder(in ElementOrder order)
 597       raises (SALOME::SALOME_Exception);
 598
 599     long NbQuadrangles()
 600       raises (SALOME::SALOME_Exception);
 601
 602     long NbQuadranglesOfOrder(in ElementOrder order)
 603       raises (SALOME::SALOME_Exception);
 604
 605     long NbPolygons()
 606       raises (SALOME::SALOME_Exception);
 607
 608     long NbVolumes()
 609       raises (SALOME::SALOME_Exception);
 610
 611     long NbVolumesOfOrder(in ElementOrder order)
 612       raises (SALOME::SALOME_Exception);
 613
 614     long NbTetras()
 615       raises (SALOME::SALOME_Exception);
 616
 617     long NbTetrasOfOrder(in ElementOrder order)
 618       raises (SALOME::SALOME_Exception);
 619
 620     long NbHexas()
 621       raises (SALOME::SALOME_Exception);
 622
 623     long NbHexasOfOrder(in ElementOrder order)
 624       raises (SALOME::SALOME_Exception);
 625
 626     long NbPyramids()
 627       raises (SALOME::SALOME_Exception);
 628
 629     long NbPyramidsOfOrder(in ElementOrder order)
 630       raises (SALOME::SALOME_Exception);
 631
 632     long NbPrisms()
 633       raises (SALOME::SALOME_Exception);
 634
 635     long NbPrismsOfOrder(in ElementOrder order)
 636       raises (SALOME::SALOME_Exception);
 637
 638     long NbPolyhedrons()
 639       raises (SALOME::SALOME_Exception);
 640
 641     long NbSubMesh()
 642       raises (SALOME::SALOME_Exception);
 643
 644     long_array GetElementsId()
 645       raises (SALOME::SALOME_Exception);
 646
 647     long_array GetElementsByType( in ElementType theType )
 648       raises (SALOME::SALOME_Exception);
 649
 650     long_array GetNodesId()
 651       raises (SALOME::SALOME_Exception);
 652
 653     /*!
 654      * Returns type of mesh element
 655      */
 656     ElementType GetElementType( in long id, in boolean iselem )
 657       raises (SALOME::SALOME_Exception);
 658
 659     long_array GetSubMeshElementsId(in long ShapeID)
 660       raises (SALOME::SALOME_Exception);
 661
 662     long_array GetSubMeshNodesId(in long ShapeID, in boolean all )
 663       raises (SALOME::SALOME_Exception);
 664
 665     ElementType GetSubMeshElementType(in long ShapeID)
 666       raises (SALOME::SALOME_Exception);
 667
 668
 669     /*!
 670      * Methods to set meshing order of submeshes
 671      */
 672
 673     /*!
 674      * \brief Return submesh objects list in meshing order
 675      */
 676     submesh_array_array GetMeshOrder();
 677
 678     /*!
 679      * \brief Set submesh object order
 680      */
 681     boolean SetMeshOrder(in submesh_array_array theSubMeshArray);
 682
 683
 684     /*!
 685      * Get mesh description
 686      */
 687     string Dump();
 688
 689     /*!
 690      * Get mesh pointer
 691      */
 692     long long GetMeshPtr();
 693
 694     /*!
 695      * Get XYZ coordinates of node as list of double
 696      * If there is not node for given ID - returns empty list
 697      */
 698     double_array GetNodeXYZ(in long id);
 699
 700     /*!
 701      * For given node returns list of IDs of inverse elements
 702      * If there is not node for given ID - returns empty list
 703      */
 704     long_array GetNodeInverseElements(in long id);
 705
 706     /*!
 707      * \brief Return position of a node on shape
 708      */
 709     NodePosition GetNodePosition(in long NodeID);
 710
 711     /*!
 712      * If given element is node returns IDs of shape from position
 713      * If there is not node for given ID - returns -1
 714      */
 715     long GetShapeID(in long id);
 716
 717     /*!
 718      * For given element returns ID of result shape after
 719      * ::FindShape() from SMESH_MeshEditor
 720      * If there is not element for given ID - returns -1
 721      */
 722     long GetShapeIDForElem(in long id);
 723
 724     /*!
 725      * Returns number of nodes for given element
 726      * If there is not element for given ID - returns -1
 727      */
 728     long GetElemNbNodes(in long id);
 729
 730     /*!
 731      * Returns IDs of nodes of given element
 732      */
 733     long_array GetElemNodes(in long id);
 734
 735     /*!
 736      * Returns ID of node by given index for given element
 737      * If there is not element for given ID - returns -1
 738      * If there is not node for given index - returns -2
 739      */
 740     long GetElemNode(in long id, in long index);
 741
 742     /*!
 743      * Returns true if given node is medium node
 744      * in given quadratic element
 745      */
 746     boolean IsMediumNode(in long ide, in long idn);
 747
 748     /*!
 749      * Returns true if given node is medium node
 750      * in one of quadratic elements
 751      */
 752     boolean IsMediumNodeOfAnyElem(in long idn, in ElementType elem_type);
 753
 754     /*!
 755      * Returns number of edges for given element
 756      */
 757     long ElemNbEdges(in long id);
 758
 759     /*!
 760      * Returns number of faces for given element
 761      */
 762     long ElemNbFaces(in long id);
 763
 764     /*!
 765      * Returns true if given element is polygon
 766      */
 767     boolean IsPoly(in long id);
 768
 769     /*!
 770      * Returns true if given element is quadratic
 771      */
 772     boolean IsQuadratic(in long id);
 773
 774     /*!
 775      * Returns XYZ coordinates of bary center for given element
 776      * as list of double
 777      * If there is not element for given ID - returns empty list
 778      */
 779     double_array BaryCenter(in long id);
 780
 781     /*! Gets information about imported MED file */
 782     SALOME_MED::MedFileInfo GetMEDFileInfo();
 783
 784     /*!
 785      *  Sets list of notebook variables used for Mesh operations separated by ":" symbol
 786      *  \param theParameters is a string containing the notebook variables
 787      */
 788     void SetParameters (in string theParameters);
 789
 790     /*!
 791      *  Returns list of notebook variables used for Mesh operations separated by ":" symbol
 792      */
 793     string GetParameters();
 794
 795     /*!
 796      *  Returns list of notebook variables used for last Mesh operation
 797      */
 798     string_array GetLastParameters();
 799   };
 800
 801   interface SMESH_subMesh : SALOME::GenericObj, SMESH_IDSource
 802   {
 803     /*!
 804      *
 805      */
 806     long GetNumberOfElements()
 807       raises (SALOME::SALOME_Exception);
 808
 809     /*!
 810      *
 811      */
 812     long GetNumberOfNodes( in boolean all )
 813       raises (SALOME::SALOME_Exception);
 814
 815     /*!
 816      *
 817      */
 818     long_array GetElementsId()
 819       raises (SALOME::SALOME_Exception);
 820
 821     /*!
 822      *
 823      */
 824     long_array GetElementsByType( in ElementType theType )
 825       raises (SALOME::SALOME_Exception);
 826
 827     /*!
 828      * Return type of submesh element
 829      */
 830     ElementType GetElementType( in long id, in boolean iselem )
 831       raises (SALOME::SALOME_Exception);
 832
 833     /*!
 834      *
 835      */
 836     long_array GetNodesId()
 837       raises (SALOME::SALOME_Exception);
 838
 839     /*!
 840      * Get geom shape the submesh is dedicated to
 841      */
 842     GEOM::GEOM_Object GetSubShape()
 843       raises (SALOME::SALOME_Exception);
 844
 845     /*!
 846      * Get SMESH_Mesh which stores nodes coordinates & elements definition
 847      */
 848     SMESH_Mesh GetFather()
 849       raises (SALOME::SALOME_Exception);
 850
 851     /*!
 852      * Get the internal Id
 853      */
 854     long GetId();
 855
 856     /*!
 857      * Get MED subMesh
 858      */
 859     SALOME_MED::FAMILY GetFamily()
 860       raises (SALOME::SALOME_Exception);
 861   };
 862
 863 };
 864
 865 #endif