idl/SMESH_Mesh.idl

   1 //  Copyright (C) 2003  OPEN CASCADE, EADS/CCR, LIP6, CEA/DEN,
   2 //  CEDRAT, EDF R&D, LEG, PRINCIPIA R&D, BUREAU VERITAS
   3 //
   4 //  This library is free software; you can redistribute it and/or
   5 //  modify it under the terms of the GNU Lesser General Public
   6 //  License as published by the Free Software Foundation; either
   7 //  version 2.1 of the License.
   8 //
   9 //  This library is distributed in the hope that it will be useful,
  10 //  but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 //  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 //  Lesser General Public License for more details.
  13 //
  14 //  You should have received a copy of the GNU Lesser General Public
  15 //  License along with this library; if not, write to the Free Software
  16 //  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
  17 //
  18 // See http://www.salome-platform.org/ or email : webmaster.salome@opencascade.com
  19 //
  20 //
  21 //
  22 //  File   : SMESH_Mesh.idl
  23 //  Author : Paul RASCLE, EDF
  24 //  $Header$
  25
  26 #ifndef _SMESH_MESH_IDL_
  27 #define _SMESH_MESH_IDL_
  28
  29 #include "SALOME_Exception.idl"
  30 #include "SALOME_GenericObj.idl"
  31 #include "GEOM_Gen.idl"
  32 #include "MED.idl"
  33
  34 module SMESH
  35 {
  36   interface SMESH_Hypothesis;
  37   typedef sequence<SMESH_Hypothesis> ListOfHypothesis;
  38   interface SMESH_GroupBase;
  39   typedef sequence<SMESH_GroupBase> ListOfGroups;
  40
  41   typedef sequence<double    > double_array ;
  42   typedef sequence<long      > long_array ;
  43   typedef sequence<string    > string_array ;
  44   typedef sequence<long_array> array_of_long_array ;
  45
  46   enum log_command
  47     {
  48       ADD_NODE,
  49       ADD_EDGE,
  50       ADD_TRIANGLE,
  51       ADD_QUADRANGLE,
  52       ADD_POLYGON,
  53       ADD_TETRAHEDRON,
  54       ADD_PYRAMID,
  55       ADD_PRISM,
  56       ADD_HEXAHEDRON,
  57       ADD_POLYHEDRON,
  58       REMOVE_NODE,
  59       REMOVE_ELEMENT,
  60       MOVE_NODE,
  61       CHANGE_ELEMENT_NODES,
  62       CHANGE_POLYHEDRON_NODES,
  63       RENUMBER,
  64       ADD_QUADEDGE,
  65       ADD_QUADTRIANGLE,
  66       ADD_QUADQUADRANGLE,
  67       ADD_QUADTETRAHEDRON,
  68       ADD_QUADPYRAMID,
  69       ADD_QUADPENTAHEDRON,
  70       ADD_QUADHEXAHEDRON
  71     };
  72
  73   struct log_block
  74   {
  75     long commandType;
  76     long number;
  77     double_array coords;
  78     long_array indexes;
  79   };
  80
  81   struct PointStruct { double x;
  82                        double y;
  83                        double z; } ;
  84
  85   typedef sequence<PointStruct> nodes_array;
  86
  87   struct DirStruct   { PointStruct PS ; } ;          // analog to Occ Direction
  88
  89   struct AxisStruct  { double x;
  90                        double y;
  91                        double z;
  92                        double vx;
  93                        double vy;
  94                        double vz; } ;
  95
  96   /*!
  97    * Node location on a shape
  98    */
  99   struct NodePosition {
 100     long             shapeID;
 101     GEOM::shape_type shapeType;
 102     double_array     params; // [U] on EDGE, [U,V] on FACE, [] on the rest shapes
 103   };
 104
 105   /*!
 106    * Enumeration for element type, like in SMDS
 107    */
 108   enum ElementType
 109   {
 110     ALL,
 111     NODE,
 112     EDGE,
 113     FACE,
 114     VOLUME
 115   };
 116
 117   /*!
 118    * ElementOrder points out entities of what order are requested
 119    */
 120   enum ElementOrder {
 121     ORDER_ANY,          /*! entities of any order */
 122     ORDER_LINEAR,       /*! entities of 1st order */
 123     ORDER_QUADRATIC     /*! entities of 2nd order */
 124   };
 125
 126   /*!
 127    * Enumeration for hypothesis status (used by AddHypothesis() and RemoveHypothesis() methods)
 128    */
 129   enum Hypothesis_Status // in the order of severity
 130   {
 131     HYP_OK,
 132     HYP_MISSING,      // algo misses a hypothesis
 133     HYP_CONCURENT,    // several applicable hypotheses
 134     HYP_BAD_PARAMETER,// hypothesis has a bad parameter value
 135     HYP_HIDDEN_ALGO,  // an algo is hidden by an upper dim algo generating all-dim elements
 136     HYP_HIDING_ALGO,  // an algo hides lower dim algos by generating all-dim elements
 137     HYP_UNKNOWN_FATAL,//  --- all statuses below should be considered as fatal
 138                       //      for Add/RemoveHypothesis operations
 139     HYP_INCOMPATIBLE, // hypothesis does not fit algo
 140     HYP_NOTCONFORM,   // not conform mesh is produced appling a hypothesis
 141     HYP_ALREADY_EXIST,// such hypothesis already exist
 142     HYP_BAD_DIM,      // bad dimension
 143     HYP_BAD_SUBSHAPE, // shape is neither the main one, nor its subshape, nor a group
 144     HYP_BAD_GEOMETRY  // geometry mismatches algorithm's expectation
 145   };
 146
 147   /*!
 148    * Enumeration for DriverMED read status (used by ImportMEDFile() method)
 149    */
 150   enum DriverMED_ReadStatus // in the order of severity
 151   {
 152     DRS_OK,
 153     DRS_EMPTY,          // a MED file contains no mesh with the given name
 154     DRS_WARN_RENUMBER,  // a MED file has overlapped ranges of element numbers,
 155                         // so the numbers from the file are ignored
 156     DRS_WARN_SKIP_ELEM, // some elements were skipped due to incorrect file data
 157     DRS_FAIL            // general failure (exception etc.)
 158   };
 159
 160   /*!
 161    * Enumeration for DriverMED (used by Perform() method)
 162    */
 163   enum MED_VERSION // in the order of severity
 164   {
 165     MED_V2_1,
 166     MED_V2_2
 167   };
 168
 169   typedef sequence<log_block> log_array;
 170
 171
 172   /*!
 173    * Auxilary flags for advanced extrusion.
 174    * BOUNDARY: create or not boundary for result of extrusion
 175    * SEW:      try to use existing nodes or create new nodes in any case
 176    */
 177   const long EXTRUSION_FLAG_BOUNDARY = 1;
 178   const long EXTRUSION_FLAG_SEW = 2;
 179
 180   interface SMESH_IDSource
 181   {
 182     /*!
 183      * Returns a sequence of all element IDs
 184      */
 185     long_array GetIDs();
 186   };
 187
 188   interface SMESH_Group;
 189   interface SMESH_GroupOnGeom;
 190   interface SMESH_subMesh;
 191   interface SMESH_MeshEditor;
 192   interface SMESH_Mesh : SALOME::GenericObj, SMESH_IDSource
 193   {
 194     /*!
 195      * Return true if there is a geometry to be meshed
 196      */
 197     boolean HasShapeToMesh()
 198       raises (SALOME::SALOME_Exception);
 199
 200     /*!
 201      * Get geom shape to mesh. A result sould not be nil. Use HasShapeToMesh()
 202      * to know if a returned shape
 203      */
 204     GEOM::GEOM_Object GetShapeToMesh()
 205       raises (SALOME::SALOME_Exception);
 206
 207
 208     /*!
 209      * Get the subMesh object associated to a subShape. The subMesh object
 210      * gives access to nodes and elements IDs.
 211      * SubMesh will be used instead of SubShape in a next idl version to
 212      * adress a specific subMesh...
 213      */
 214     SMESH_subMesh GetSubMesh(in GEOM::GEOM_Object aSubObject, in string name)
 215       raises (SALOME::SALOME_Exception);
 216
 217     /*!
 218      * Remove a submesh
 219      */
 220     void RemoveSubMesh(in SMESH_subMesh aSubMesh)
 221       raises (SALOME::SALOME_Exception);
 222
 223
 224     /*!
 225      * Create a group
 226      */
 227     SMESH_Group CreateGroup( in ElementType elem_type,
 228                              in string name )
 229       raises (SALOME::SALOME_Exception);
 230
 231     /*!
 232      * Create a group from geometry group
 233      */
 234     SMESH_GroupOnGeom CreateGroupFromGEOM( in ElementType elem_type,
 235                                           in string name,
 236                                           in GEOM::GEOM_Object theGeomObject )
 237       raises (SALOME::SALOME_Exception);
 238
 239     /*!
 240      * Remove a group
 241      */
 242     void RemoveGroup(in SMESH_GroupBase aGroup)
 243       raises (SALOME::SALOME_Exception);
 244
 245     /*!
 246      *  Remove group with its contents
 247      */
 248     void RemoveGroupWithContents( in SMESH_GroupBase aGroup )
 249       raises (SALOME::SALOME_Exception);
 250
 251     /*!
 252      *  Get the list of groups existing in the mesh
 253      */
 254     ListOfGroups GetGroups()
 255       raises (SALOME::SALOME_Exception);
 256
 257     /*!
 258      *  Get number of groups existing in the mesh
 259      */
 260     long NbGroups()
 261       raises (SALOME::SALOME_Exception);
 262
 263     /*!
 264      * Union of two groups
 265      *    New group is created. All mesh elements that are
 266      *    present in initial groups are added to the new one
 267      */
 268     SMESH_Group UnionGroups (in SMESH_GroupBase aGroup1,
 269                              in SMESH_GroupBase aGroup2,
 270                              in string          name )
 271       raises (SALOME::SALOME_Exception);
 272
 273     /*!
 274      *  Intersection of two groups
 275      *  New group is created. All mesh elements that are
 276      *  present in both initial groups are added to the new one.
 277      */
 278     SMESH_Group IntersectGroups (in SMESH_GroupBase aGroup1,
 279                                  in SMESH_GroupBase aGroup2,
 280                                  in string          name )
 281       raises (SALOME::SALOME_Exception);
 282
 283     /*!
 284      *  Cut of two groups
 285      *  New group is created. All mesh elements that are present in
 286      *  main group but do not present in tool group are added to the new one
 287      */
 288     SMESH_Group CutGroups (in SMESH_GroupBase aMainGroup,
 289                            in SMESH_GroupBase aToolGroup,
 290                            in string          name )
 291       raises (SALOME::SALOME_Exception);
 292
 293     /*!
 294      * Add hypothesis to the mesh, under a particular subShape
 295      * (or the main shape itself)
 296      * The Add method is only used to prepare the build of the mesh and store
 297      * the algorithms and associated parameters.
 298      * Actual job of mesh the shape is done by MESH_Gen.
 299      * @params
 300      * - aSubShape : subShape obtained by a shape explode in GEOM
 301      *   (or main shape)
 302      * - anHyp : hypothesis object
 303      * @return
 304      * - OK if the hypothesis is compatible with the subShape
 305      *   (and all previous hypothesis on the subShape)
 306      * - NOK if the hypothesis is not compatible with the subShape
 307      *   (or one previous hypothesis on the subShape)
 308      * raises exception if hypothesis has not been created
 309      */
 310     Hypothesis_Status AddHypothesis(in GEOM::GEOM_Object aSubObject,
 311                                     in SMESH_Hypothesis anHyp)
 312       raises (SALOME::SALOME_Exception);
 313 //     boolean AddHypothesis(in SMESH_subMesh aSubMesh, in SMESH_Hypothesis anHyp)
 314 //       raises (SALOME::SALOME_Exception);
 315
 316     /*!
 317      * Remove an hypothesis previouly added with AddHypothesis.
 318      */
 319     Hypothesis_Status RemoveHypothesis(in GEOM::GEOM_Object aSubObject,
 320                                        in SMESH_Hypothesis anHyp)
 321       raises (SALOME::SALOME_Exception);
 322 //     boolean RemoveHypothesis(in SMESH_subMesh aSubMesh,
 323 //                           in SMESH_Hypothesis anHyp)
 324 //       raises (SALOME::SALOME_Exception);
 325
 326     /*!
 327      * Get the list of hypothesis added on a subShape
 328      */
 329     ListOfHypothesis GetHypothesisList(in GEOM::GEOM_Object aSubObject)
 330       raises (SALOME::SALOME_Exception);
 331 //     ListOfHypothesis GetHypothesisList(in SMESH_subMesh aSubMesh)
 332 //       raises (SALOME::SALOME_Exception);
 333
 334     /*!
 335      * Get the log of nodes and elements added or removed since previous
 336      * clear of the log.
 337      * @params
 338      * - clearAfterGet : log is emptied after Get (safe if concurrents access)
 339      */
 340     //    string_array GetLog(in boolean clearAfterGet)
 341     //      raises (SALOME::SALOME_Exception);
 342     log_array GetLog(in boolean clearAfterGet)
 343       raises (SALOME::SALOME_Exception);
 344
 345     /*!
 346      * Clear the log of nodes and elements added or removed since previous
 347      * clear. Must be used immediately after GetLog if clearAfterGet is false.
 348      */
 349     void ClearLog()
 350       raises (SALOME::SALOME_Exception);
 351
 352     /*!
 353      * Toggle auto color mode on the object.
 354      * @params
 355      * - theAutoColor : flag which toggles auto color mode.
 356      */
 357     void SetAutoColor(in boolean theAutoColor)
 358       raises (SALOME::SALOME_Exception);
 359
 360     /*!
 361      * Get flag of object's auto color mode.
 362      */
 363     boolean GetAutoColor()
 364       raises (SALOME::SALOME_Exception);
 365
 366     /*!
 367      * Get the internal Id
 368      */
 369     long GetId();
 370
 371     /*!
 372      * Get the study Id
 373      */
 374     long GetStudyId();
 375
 376     /*!
 377      * Obtain instance of SMESH_MeshEditor
 378      */
 379     SMESH_MeshEditor GetMeshEditor()
 380       raises (SALOME::SALOME_Exception);
 381
 382     /*!
 383      * Return SMESH_MeshEditor that would not modify the mesh but
 384      * fill MeshPreviewStruct
 385      */
 386     SMESH_MeshEditor GetMeshEditPreviewer()
 387       raises (SALOME::SALOME_Exception);
 388
 389     /*! Check group names for duplications.
 390      *  Consider maximum group name length stored in MED file.
 391      */
 392     boolean HasDuplicatedGroupNamesMED();
 393
 394     /*!
 395      * Export Mesh to different MED Formats
 396      * @params
 397      * - auto_groups : boolean parameter for creating/not creating
 398      *   the groups Group_On_All_Nodes, Group_On_All_Faces, ... ;
 399      *   the typical use is auto_groups=false.
 400      * - theVersion : define the version of format of MED file, that will be created
 401      */
 402     void ExportToMED( in string file, in boolean auto_groups, in MED_VERSION theVersion )
 403       raises (SALOME::SALOME_Exception);
 404
 405     /*!
 406      * Export Mesh to MED_V2_1 MED format
 407      * Works, just the same as ExportToMED, with MED_VERSION parameter equal to MED_V2_1.
 408      * The method is kept in order to support old functionality
 409      */
 410     void ExportMED( in string file, in boolean auto_groups )
 411       raises (SALOME::SALOME_Exception);
 412
 413     /*!
 414      * Export Mesh to DAT, UNV and STL Formats
 415      * (UNV supported version is I-DEAS 10)
 416      */
 417     void ExportDAT( in string file )
 418       raises (SALOME::SALOME_Exception);
 419     void ExportUNV( in string file )
 420       raises (SALOME::SALOME_Exception);
 421     void ExportSTL( in string file, in boolean isascii )
 422       raises (SALOME::SALOME_Exception);
 423
 424     /*!
 425      * Get MED Mesh
 426      */
 427     SALOME_MED::MESH GetMEDMesh()
 428       raises (SALOME::SALOME_Exception);
 429
 430     /*!
 431      * Get informations about mesh contents
 432      */
 433     long NbNodes()
 434       raises (SALOME::SALOME_Exception);
 435
 436     long NbElements()
 437       raises (SALOME::SALOME_Exception);
 438
 439     long NbEdges()
 440       raises (SALOME::SALOME_Exception);
 441
 442     long NbEdgesOfOrder(in ElementOrder order)
 443       raises (SALOME::SALOME_Exception);
 444
 445     long NbFaces()
 446       raises (SALOME::SALOME_Exception);
 447
 448     long NbFacesOfOrder(in ElementOrder order)
 449       raises (SALOME::SALOME_Exception);
 450
 451     long NbTriangles()
 452       raises (SALOME::SALOME_Exception);
 453
 454     long NbTrianglesOfOrder(in ElementOrder order)
 455       raises (SALOME::SALOME_Exception);
 456
 457     long NbQuadrangles()
 458       raises (SALOME::SALOME_Exception);
 459
 460     long NbQuadranglesOfOrder(in ElementOrder order)
 461       raises (SALOME::SALOME_Exception);
 462
 463     long NbPolygons()
 464       raises (SALOME::SALOME_Exception);
 465
 466     long NbVolumes()
 467       raises (SALOME::SALOME_Exception);
 468
 469     long NbVolumesOfOrder(in ElementOrder order)
 470       raises (SALOME::SALOME_Exception);
 471
 472     long NbTetras()
 473       raises (SALOME::SALOME_Exception);
 474
 475     long NbTetrasOfOrder(in ElementOrder order)
 476       raises (SALOME::SALOME_Exception);
 477
 478     long NbHexas()
 479       raises (SALOME::SALOME_Exception);
 480
 481     long NbHexasOfOrder(in ElementOrder order)
 482       raises (SALOME::SALOME_Exception);
 483
 484     long NbPyramids()
 485       raises (SALOME::SALOME_Exception);
 486
 487     long NbPyramidsOfOrder(in ElementOrder order)
 488       raises (SALOME::SALOME_Exception);
 489
 490     long NbPrisms()
 491       raises (SALOME::SALOME_Exception);
 492
 493     long NbPrismsOfOrder(in ElementOrder order)
 494       raises (SALOME::SALOME_Exception);
 495
 496     long NbPolyhedrons()
 497       raises (SALOME::SALOME_Exception);
 498
 499     long NbSubMesh()
 500       raises (SALOME::SALOME_Exception);
 501
 502     long_array GetElementsId()
 503       raises (SALOME::SALOME_Exception);
 504
 505     long_array GetElementsByType( in ElementType theType )
 506       raises (SALOME::SALOME_Exception);
 507
 508     long_array GetNodesId()
 509       raises (SALOME::SALOME_Exception);
 510
 511     /*!
 512      * Returns type of mesh element
 513      */
 514     ElementType GetElementType( in long id, in boolean iselem )
 515       raises (SALOME::SALOME_Exception);
 516
 517     long_array GetSubMeshElementsId(in long ShapeID)
 518       raises (SALOME::SALOME_Exception);
 519
 520     long_array GetSubMeshNodesId(in long ShapeID, in boolean all )
 521       raises (SALOME::SALOME_Exception);
 522
 523     ElementType GetSubMeshElementType(in long ShapeID)
 524       raises (SALOME::SALOME_Exception);
 525
 526     /*!
 527      * Get mesh description
 528      */
 529     string Dump();
 530
 531     /*!
 532      * Get mesh pointer
 533      */
 534     long long GetMeshPtr();
 535
 536     /*!
 537      * Get XYZ coordinates of node as list of double
 538      * If there is not node for given ID - returns empty list
 539      */
 540     double_array GetNodeXYZ(in long id);
 541
 542     /*!
 543      * For given node returns list of IDs of inverse elements
 544      * If there is not node for given ID - returns empty list
 545      */
 546     long_array GetNodeInverseElements(in long id);
 547
 548     /*!
 549      * \brief Return position of a node on shape
 550      */
 551     NodePosition GetNodePosition(in long NodeID);
 552
 553     /*!
 554      * If given element is node returns IDs of shape from position
 555      * If there is not node for given ID - returns -1
 556      */
 557     long GetShapeID(in long id);
 558
 559     /*!
 560      * For given element returns ID of result shape after
 561      * ::FindShape() from SMESH_MeshEditor
 562      * If there is not element for given ID - returns -1
 563      */
 564     long GetShapeIDForElem(in long id);
 565
 566     /*!
 567      * Returns number of nodes for given element
 568      * If there is not element for given ID - returns -1
 569      */
 570     long GetElemNbNodes(in long id);
 571
 572     /*!
 573      * Returns IDs of nodes of given element
 574      */
 575     long_array GetElemNodes(in long id);
 576
 577     /*!
 578      * Returns ID of node by given index for given element
 579      * If there is not element for given ID - returns -1
 580      * If there is not node for given index - returns -2
 581      */
 582     long GetElemNode(in long id, in long index);
 583
 584     /*!
 585      * Returns true if given node is medium node
 586      * in given quadratic element
 587      */
 588     boolean IsMediumNode(in long ide, in long idn);
 589
 590     /*!
 591      * Returns true if given node is medium node
 592      * in one of quadratic elements
 593      */
 594     boolean IsMediumNodeOfAnyElem(in long idn, in ElementType elem_type);
 595
 596     /*!
 597      * Returns number of edges for given element
 598      */
 599     long ElemNbEdges(in long id);
 600
 601     /*!
 602      * Returns number of faces for given element
 603      */
 604     long ElemNbFaces(in long id);
 605
 606     /*!
 607      * Returns true if given element is polygon
 608      */
 609     boolean IsPoly(in long id);
 610
 611     /*!
 612      * Returns true if given element is quadratic
 613      */
 614     boolean IsQuadratic(in long id);
 615
 616     /*!
 617      * Returns XYZ coordinates of bary center for given element
 618      * as list of double
 619      * If there is not element for given ID - returns empty list
 620      */
 621     double_array BaryCenter(in long id);
 622
 623   };
 624
 625   interface SMESH_subMesh : SALOME::GenericObj, SMESH_IDSource
 626   {
 627     /*!
 628      *
 629      */
 630     long GetNumberOfElements()
 631       raises (SALOME::SALOME_Exception);
 632
 633     /*!
 634      *
 635      */
 636     long GetNumberOfNodes( in boolean all )
 637       raises (SALOME::SALOME_Exception);
 638
 639     /*!
 640      *
 641      */
 642     long_array GetElementsId()
 643       raises (SALOME::SALOME_Exception);
 644
 645     /*!
 646      *
 647      */
 648     long_array GetElementsByType( in ElementType theType )
 649       raises (SALOME::SALOME_Exception);
 650
 651     /*!
 652      * Return type of submesh element
 653      */
 654     ElementType GetElementType( in long id, in boolean iselem )
 655       raises (SALOME::SALOME_Exception);
 656
 657     /*!
 658      *
 659      */
 660     long_array GetNodesId()
 661       raises (SALOME::SALOME_Exception);
 662
 663     /*!
 664      * Get geom shape the submesh is dedicated to
 665      */
 666     GEOM::GEOM_Object GetSubShape()
 667       raises (SALOME::SALOME_Exception);
 668
 669     /*!
 670      * Get SMESH_Mesh which stores nodes coordinates & elements definition
 671      */
 672     SMESH_Mesh GetFather()
 673       raises (SALOME::SALOME_Exception);
 674
 675     /*!
 676      * Get the internal Id
 677      */
 678     long GetId();
 679
 680     /*!
 681      * Get MED subMesh
 682      */
 683     SALOME_MED::FAMILY GetFamily()
 684       raises (SALOME::SALOME_Exception);
 685   };
 686
 687 };
 688
 689 #endif