idl/SMESH_Mesh.idl

   1 // Copyright (C) 2007-2011  CEA/DEN, EDF R&D, OPEN CASCADE
   2 //
   3 // Copyright (C) 2003-2007  OPEN CASCADE, EADS/CCR, LIP6, CEA/DEN,
   4 // CEDRAT, EDF R&D, LEG, PRINCIPIA R&D, BUREAU VERITAS
   5 //
   6 // This library is free software; you can redistribute it and/or
   7 // modify it under the terms of the GNU Lesser General Public
   8 // License as published by the Free Software Foundation; either
   9 // version 2.1 of the License.
  10 //
  11 // This library is distributed in the hope that it will be useful,
  12 // but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 // MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14 // Lesser General Public License for more details.
  15 //
  16 // You should have received a copy of the GNU Lesser General Public
  17 // License along with this library; if not, write to the Free Software
  18 // Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
  19 //
  20 // See http://www.salome-platform.org/ or email : webmaster.salome@opencascade.com
  21 //
  22
  23 //  File   : SMESH_Mesh.idl
  24 //  Author : Paul RASCLE, EDF
  25 //
  26 #ifndef _SMESH_MESH_IDL_
  27 #define _SMESH_MESH_IDL_
  28
  29 #include "SALOME_Exception.idl"
  30 #include "SALOME_GenericObj.idl"
  31 #include "GEOM_Gen.idl"
  32 #include "MED.idl"
  33
  34 module SMESH
  35 {
  36   interface SMESH_Hypothesis;
  37   typedef sequence<SMESH_Hypothesis> ListOfHypothesis;
  38   interface SMESH_GroupBase;
  39   typedef sequence<SMESH_GroupBase> ListOfGroups;
  40   interface SMESH_IDSource;
  41   typedef sequence<SMESH_IDSource> ListOfIDSources;
  42
  43   typedef sequence<double    > double_array ;
  44   typedef sequence<long      > long_array ;
  45   typedef sequence<string    > string_array ;
  46   typedef sequence<long_array> array_of_long_array ;
  47
  48   enum log_command
  49     {
  50       ADD_NODE,
  51       ADD_EDGE,
  52       ADD_TRIANGLE,
  53       ADD_QUADRANGLE,
  54       ADD_POLYGON,
  55       ADD_TETRAHEDRON,
  56       ADD_PYRAMID,
  57       ADD_PRISM,
  58       ADD_HEXAHEDRON,
  59       ADD_POLYHEDRON,
  60       REMOVE_NODE,
  61       REMOVE_ELEMENT,
  62       MOVE_NODE,
  63       CHANGE_ELEMENT_NODES,
  64       CHANGE_POLYHEDRON_NODES,
  65       RENUMBER,
  66       CLEAR_MESH,
  67       ADD_QUADEDGE,
  68       ADD_QUADTRIANGLE,
  69       ADD_QUADQUADRANGLE,
  70       ADD_QUADTETRAHEDRON,
  71       ADD_QUADPYRAMID,
  72       ADD_QUADPENTAHEDRON,
  73       ADD_QUADHEXAHEDRON,
  74       ADD_ELEM0D
  75     };
  76
  77   struct log_block
  78   {
  79     long commandType;
  80     long number;
  81     double_array coords;
  82     long_array indexes;
  83   };
  84
  85   struct PointStruct { double x;
  86                        double y;
  87                        double z; } ;
  88
  89   typedef sequence<PointStruct> nodes_array;
  90
  91   struct DirStruct   { PointStruct PS ; } ;          // analog to Occ Direction
  92
  93   struct AxisStruct  { double x;
  94                        double y;
  95                        double z;
  96                        double vx;
  97                        double vy;
  98                        double vz; } ;
  99
 100   /*!
 101    * Node location on a shape
 102    */
 103   struct NodePosition {
 104     long             shapeID;
 105     GEOM::shape_type shapeType;
 106     double_array     params; // [U] on EDGE, [U,V] on FACE, [] on the rest shapes
 107   };
 108
 109   /*!
 110    * Enumeration for element type, like in SMDS
 111    */
 112   enum ElementType
 113   {
 114     ALL,
 115     NODE,
 116     EDGE,
 117     FACE,
 118     VOLUME,
 119     ELEM0D
 120   };
 121   typedef sequence<ElementType> array_of_ElementType ;
 122
 123   /*!
 124    * Enumeration for element geometry type, like in SMDS
 125    */
 126   enum GeometryType
 127   {
 128     Geom_POINT,
 129     Geom_EDGE,
 130     Geom_TRIANGLE,
 131     Geom_QUADRANGLE,
 132     Geom_POLYGON,
 133     Geom_TETRA,
 134     Geom_PYRAMID,
 135     Geom_HEXA,
 136     Geom_PENTA,
 137     Geom_POLYHEDRA
 138   };
 139
 140   /*!
 141    * ElementOrder points out entities of what order are requested
 142    */
 143   enum ElementOrder {
 144     ORDER_ANY,          /*! entities of any order */
 145     ORDER_LINEAR,       /*! entities of 1st order */
 146     ORDER_QUADRATIC     /*! entities of 2nd order */
 147   };
 148
 149
 150   /*!
 151    * Enumeration of entity type used in mesh info array,
 152    * it should be synchronised with enum SMDSAbs_EntityType
 153    */
 154   enum EntityType
 155   {
 156     Entity_Node,
 157     Entity_0D,
 158     Entity_Edge,
 159     Entity_Quad_Edge,
 160     Entity_Triangle,
 161     Entity_Quad_Triangle,
 162     Entity_Quadrangle,
 163     Entity_Quad_Quadrangle,
 164     Entity_Polygon,
 165     Entity_Quad_Polygon,
 166     Entity_Tetra,
 167     Entity_Quad_Tetra,
 168     Entity_Pyramid,
 169     Entity_Quad_Pyramid,
 170     Entity_Hexa,
 171     Entity_Quad_Hexa,
 172     Entity_Penta,
 173     Entity_Quad_Penta,
 174     Entity_Polyhedra,
 175     Entity_Quad_Polyhedra,
 176     Entity_Last
 177   };
 178
 179
 180   /*!
 181    * Enumeration for hypothesis status (used by AddHypothesis() and RemoveHypothesis() methods)
 182    */
 183   enum Hypothesis_Status // in the order of severity
 184   {
 185     HYP_OK,
 186     HYP_MISSING,      // algo misses a hypothesis
 187     HYP_CONCURENT,    // several applicable hypotheses
 188     HYP_BAD_PARAMETER,// hypothesis has a bad parameter value
 189     HYP_HIDDEN_ALGO,  // an algo is hidden by an upper dim algo generating all-dim elements
 190     HYP_HIDING_ALGO,  // an algo hides lower dim algos by generating all-dim elements
 191     HYP_UNKNOWN_FATAL,//  --- all statuses below should be considered as fatal
 192                       //      for Add/RemoveHypothesis operations
 193     HYP_INCOMPATIBLE, // hypothesis does not fit algo
 194     HYP_NOTCONFORM,   // not conform mesh is produced appling a hypothesis
 195     HYP_ALREADY_EXIST,// such hypothesis already exist
 196     HYP_BAD_DIM,      // bad dimension
 197     HYP_BAD_SUBSHAPE, // shape is neither the main one, nor its subshape, nor a group
 198     HYP_BAD_GEOMETRY, // geometry mismatches algorithm's expectation
 199     HYP_NEED_SHAPE    // algorithm can work on shape only
 200   };
 201
 202   /*!
 203    * Enumeration for DriverMED read status (used by ImportMEDFile() method)
 204    */
 205   enum DriverMED_ReadStatus // in the order of severity
 206   {
 207     DRS_OK,
 208     DRS_EMPTY,          // a MED file contains no mesh with the given name
 209     DRS_WARN_RENUMBER,  // a MED file has overlapped ranges of element numbers,
 210                         // so the numbers from the file are ignored
 211     DRS_WARN_SKIP_ELEM, // some elements were skipped due to incorrect file data
 212     DRS_FAIL            // general failure (exception etc.)
 213   };
 214
 215   /*!
 216    * Enumeration for DriverMED (used by Perform() method)
 217    */
 218   enum MED_VERSION // in the order of severity
 219   {
 220     MED_V2_1,
 221     MED_V2_2
 222   };
 223
 224   typedef sequence<log_block> log_array;
 225
 226
 227   /*!
 228    * Auxilary flags for advanced extrusion.
 229    * BOUNDARY: create or not boundary for result of extrusion
 230    * SEW:      try to use existing nodes or create new nodes in any case
 231    */
 232   const long EXTRUSION_FLAG_BOUNDARY = 1;
 233   const long EXTRUSION_FLAG_SEW = 2;
 234
 235   /*!
 236    * Structure used in mesh edit preview data (MeshPreviewStruct)
 237    */
 238   struct ElementSubType { ElementType SMDS_ElementType;
 239                           boolean     isPoly;
 240                           long        nbNodesInElement; };
 241
 242   typedef sequence<ElementSubType> types_array;
 243
 244   /*!
 245    * Structure containing mesh edit preview data
 246    */
 247   struct MeshPreviewStruct { nodes_array nodesXYZ;
 248                              long_array  elementConnectivities;
 249                              types_array elementTypes; };
 250
 251   interface SMESH_Mesh;
 252
 253   interface SMESH_IDSource
 254   {
 255     /*!
 256      * Returns a sequence of all element IDs
 257      */
 258     long_array GetIDs();
 259
 260     /*!
 261      * Returns statistic of mesh elements
 262      * @return array of number enityties by index of EntityType
 263      */
 264     long_array GetMeshInfo();
 265
 266     /*!
 267      * Returns types of elements it contains
 268      */
 269     array_of_ElementType GetTypes();
 270
 271     /*!
 272      * Returns the mesh
 273      */
 274     SMESH_Mesh GetMesh();
 275   };
 276
 277   interface SMESH_Group;
 278   interface SMESH_GroupOnGeom;
 279   interface SMESH_subMesh;
 280   interface SMESH_MeshEditor;
 281
 282   typedef sequence<SMESH_subMesh>     submesh_array;
 283   typedef sequence<submesh_array>     submesh_array_array;
 284
 285   interface SMESH_Mesh : SALOME::GenericObj, SMESH_IDSource
 286   {
 287     /*!
 288      * Return true if there is a geometry to be meshed
 289      */
 290     boolean HasShapeToMesh()
 291       raises (SALOME::SALOME_Exception);
 292
 293     /*!
 294      * Get geom shape to mesh. A result sould not be nil. Use HasShapeToMesh()
 295      * to know if a returned shape
 296      */
 297     GEOM::GEOM_Object GetShapeToMesh()
 298       raises (SALOME::SALOME_Exception);
 299
 300     /*!
 301      * Remove all nodes and elements
 302      */
 303     void Clear()
 304       raises (SALOME::SALOME_Exception);
 305
 306     /*!
 307      * Remove all nodes and elements of submesh
 308      */
 309     void ClearSubMesh(in long ShapeID)
 310       raises (SALOME::SALOME_Exception);
 311
 312     /*!
 313      * Get the subMesh object associated to a subShape. The subMesh object
 314      * gives access to nodes and elements IDs.
 315      * SubMesh will be used instead of SubShape in a next idl version to
 316      * adress a specific subMesh...
 317      */
 318     SMESH_subMesh GetSubMesh(in GEOM::GEOM_Object aSubObject, in string name)
 319       raises (SALOME::SALOME_Exception);
 320
 321     /*!
 322      * Remove a submesh
 323      */
 324     void RemoveSubMesh(in SMESH_subMesh aSubMesh)
 325       raises (SALOME::SALOME_Exception);
 326
 327
 328     /*!
 329      * Create a group
 330      */
 331     SMESH_Group CreateGroup( in ElementType elem_type,
 332                              in string name )
 333       raises (SALOME::SALOME_Exception);
 334
 335     /*!
 336      * Create a group from geometry group
 337      */
 338     SMESH_GroupOnGeom CreateGroupFromGEOM( in ElementType elem_type,
 339                                           in string name,
 340                                           in GEOM::GEOM_Object theGeomObject )
 341       raises (SALOME::SALOME_Exception);
 342
 343     /*!
 344      * Remove a group
 345      */
 346     void RemoveGroup(in SMESH_GroupBase aGroup)
 347       raises (SALOME::SALOME_Exception);
 348
 349     /*!
 350      *  Remove group with its contents
 351      */
 352     void RemoveGroupWithContents( in SMESH_GroupBase aGroup )
 353       raises (SALOME::SALOME_Exception);
 354
 355     /*!
 356      *  Get the list of groups existing in the mesh
 357      */
 358     ListOfGroups GetGroups()
 359       raises (SALOME::SALOME_Exception);
 360
 361     /*!
 362      *  Get number of groups existing in the mesh
 363      */
 364     long NbGroups()
 365       raises (SALOME::SALOME_Exception);
 366
 367     /*!
 368      * Union of two groups
 369      *    New group is created. All mesh elements that are
 370      *    present in initial groups are added to the new one
 371      */
 372     SMESH_Group UnionGroups (in SMESH_GroupBase aGroup1,
 373                              in SMESH_GroupBase aGroup2,
 374                              in string          name )
 375       raises (SALOME::SALOME_Exception);
 376
 377     /*!
 378      * Union of list of groups
 379      * New group is created. All mesh elements that are
 380      * present in initial groups are added to the new one
 381      */
 382     SMESH_Group UnionListOfGroups (in ListOfGroups aListOfGroups,
 383                                    in string       name )
 384       raises (SALOME::SALOME_Exception);
 385
 386     /*!
 387      *  Intersection of two groups
 388      *  New group is created. All mesh elements that are
 389      *  present in both initial groups are added to the new one.
 390      */
 391     SMESH_Group IntersectGroups (in SMESH_GroupBase aGroup1,
 392                                  in SMESH_GroupBase aGroup2,
 393                                  in string          name )
 394       raises (SALOME::SALOME_Exception);
 395
 396     /*!
 397      *  Intersection of list of groups
 398      *  New group is created. All mesh elements that are
 399      *  present in all initial groups simultaneously are added to the new one.
 400      */
 401     SMESH_Group IntersectListOfGroups (in ListOfGroups aListOfGroups,
 402                                        in string       name)
 403       raises (SALOME::SALOME_Exception);
 404
 405     /*!
 406      *  Cut of two groups
 407      *  New group is created. All mesh elements that are present in
 408      *  main group but do not present in tool group are added to the new one
 409      */
 410     SMESH_Group CutGroups (in SMESH_GroupBase aMainGroup,
 411                            in SMESH_GroupBase aToolGroup,
 412                            in string          name )
 413       raises (SALOME::SALOME_Exception);
 414
 415     /*!
 416      *  Cut of lists of groups
 417      *  New group is created. All mesh elements that are present in
 418      *  main groups but do not present in tool groups are added to the new one
 419      */
 420     SMESH_Group CutListOfGroups (in ListOfGroups aMainGroups,
 421                                  in ListOfGroups aToolGroups,
 422                                  in string       name)
 423       raises (SALOME::SALOME_Exception);
 424
 425     /*!
 426      *  Create groups of entities from existing groups of superior dimensions
 427      *  New group is created. System
 428      *  1) extracts all nodes from each group,
 429      *  2) combines all elements of specified dimension laying on these nodes.
 430      */
 431     SMESH_Group CreateDimGroup( in ListOfGroups aListOfGroups,
 432                                 in ElementType  anElemType,
 433                                 in string       name )
 434       raises (SALOME::SALOME_Exception);
 435
 436     /*!
 437      * Convert group on geometry into standalone group
 438      */
 439     SMESH_Group ConvertToStandalone( in SMESH_GroupOnGeom theGeomGroup )
 440       raises (SALOME::SALOME_Exception);
 441
 442     /*!
 443      * Add hypothesis to the mesh, under a particular subShape
 444      * (or the main shape itself)
 445      * The Add method is only used to prepare the build of the mesh and store
 446      * the algorithms and associated parameters.
 447      * Actual job of mesh the shape is done by MESH_Gen.
 448      * @params
 449      * - aSubShape : subShape obtained by a shape explode in GEOM
 450      *   (or main shape)
 451      * - anHyp : hypothesis object
 452      * @return
 453      * - OK if the hypothesis is compatible with the subShape
 454      *   (and all previous hypothesis on the subShape)
 455      * - NOK if the hypothesis is not compatible with the subShape
 456      *   (or one previous hypothesis on the subShape)
 457      * raises exception if hypothesis has not been created
 458      */
 459     Hypothesis_Status AddHypothesis(in GEOM::GEOM_Object aSubObject,
 460                                     in SMESH_Hypothesis anHyp)
 461       raises (SALOME::SALOME_Exception);
 462 //     boolean AddHypothesis(in SMESH_subMesh aSubMesh, in SMESH_Hypothesis anHyp)
 463 //       raises (SALOME::SALOME_Exception);
 464
 465     /*!
 466      * Remove an hypothesis previouly added with AddHypothesis.
 467      */
 468     Hypothesis_Status RemoveHypothesis(in GEOM::GEOM_Object aSubObject,
 469                                        in SMESH_Hypothesis anHyp)
 470       raises (SALOME::SALOME_Exception);
 471 //     boolean RemoveHypothesis(in SMESH_subMesh aSubMesh,
 472 //                           in SMESH_Hypothesis anHyp)
 473 //       raises (SALOME::SALOME_Exception);
 474
 475     /*!
 476      * Get the list of hypothesis added on a subShape
 477      */
 478     ListOfHypothesis GetHypothesisList(in GEOM::GEOM_Object aSubObject)
 479       raises (SALOME::SALOME_Exception);
 480 //     ListOfHypothesis GetHypothesisList(in SMESH_subMesh aSubMesh)
 481 //       raises (SALOME::SALOME_Exception);
 482
 483     /*!
 484      * Get the log of nodes and elements added or removed since previous
 485      * clear of the log.
 486      * @params
 487      * - clearAfterGet : log is emptied after Get (safe if concurrents access)
 488      */
 489     //    string_array GetLog(in boolean clearAfterGet)
 490     //      raises (SALOME::SALOME_Exception);
 491     log_array GetLog(in boolean clearAfterGet)
 492       raises (SALOME::SALOME_Exception);
 493
 494     /*!
 495      * Clear the log of nodes and elements added or removed since previous
 496      * clear. Must be used immediately after GetLog if clearAfterGet is false.
 497      */
 498     void ClearLog()
 499       raises (SALOME::SALOME_Exception);
 500
 501     /*!
 502      * Toggle auto color mode on the object.
 503      * @params
 504      * - theAutoColor : flag which toggles auto color mode.
 505      */
 506     void SetAutoColor(in boolean theAutoColor)
 507       raises (SALOME::SALOME_Exception);
 508
 509     /*!
 510      * Get flag of object's auto color mode.
 511      */
 512     boolean GetAutoColor()
 513       raises (SALOME::SALOME_Exception);
 514
 515     /*!
 516      * Get the internal Id
 517      */
 518     long GetId();
 519
 520     /*!
 521      * Get the study Id
 522      */
 523     long GetStudyId();
 524
 525     /*!
 526      * Obtain instance of SMESH_MeshEditor
 527      */
 528     SMESH_MeshEditor GetMeshEditor()
 529       raises (SALOME::SALOME_Exception);
 530
 531     /*!
 532      * Return SMESH_MeshEditor that would not modify the mesh but
 533      * fill MeshPreviewStruct
 534      */
 535     SMESH_MeshEditor GetMeshEditPreviewer()
 536       raises (SALOME::SALOME_Exception);
 537
 538     /*!
 539      * Return true if the mesh has been edited since a total re-compute
 540      * and those modifications may prevent successful partial re-compute
 541      */
 542     boolean HasModificationsToDiscard()
 543       raises (SALOME::SALOME_Exception);
 544
 545     /*! Check group names for duplications.
 546      *  Consider maximum group name length stored in MED file.
 547      */
 548     boolean HasDuplicatedGroupNamesMED();
 549
 550     /*!
 551      * Export Mesh to different MED Formats
 552      * @params
 553      * - file : name of the MED file
 554      * - auto_groups : boolean parameter for creating/not creating
 555      *   the groups Group_On_All_Nodes, Group_On_All_Faces, ... ;
 556      *   the typical use is auto_groups=false.
 557      * - version : define the version of format of MED file, that will be created
 558      * - overwrite : boolean parameter for overwriting/not overwriting the file, if it exists
 559      */
 560     void ExportToMEDX( in string      file,
 561                        in boolean     auto_groups,
 562                        in MED_VERSION version,
 563                        in boolean     overwrite ) raises (SALOME::SALOME_Exception);
 564
 565     /*!
 566      * Export a part of Mesh into a MED file
 567      * @params
 568      * - meshPart : a part of mesh to store
 569      * - file : name of the MED file
 570      * - version : define the version of format of MED file, that will be created
 571      * - overwrite : boolean parameter for overwriting/not overwriting the file, if it exists
 572      */
 573     void ExportPartToMED( in SMESH_IDSource meshPart,
 574                           in string         file,
 575                           in boolean        auto_groups,
 576                           in MED_VERSION    version,
 577                           in boolean        overwrite ) raises (SALOME::SALOME_Exception);
 578
 579     /*!
 580      * Export Mesh to different MED Formats
 581      * Works, just the same as ExportToMEDX, with overwrite parameter equal to true.
 582      * The method is kept in order to support old functionality
 583      */
 584     void ExportToMED( in string file, in boolean auto_groups, in MED_VERSION theVersion )
 585       raises (SALOME::SALOME_Exception);
 586
 587     /*!
 588      * Export Mesh to MED_V2_1 MED format
 589      * Works, just the same as ExportToMEDX with MED_VERSION parameter equal to MED_V2_1
 590      * and overwrite parameter equal to true
 591      * The method is kept in order to support old functionality
 592      */
 593     void ExportMED( in string file, in boolean auto_groups )
 594       raises (SALOME::SALOME_Exception);
 595
 596     /*!
 597      * Return string representation of a MED file version comprising nbDigits
 598      */
 599     string GetVersionString(in MED_VERSION version, in short nbDigits);
 600
 601     /*!
 602      * Export Mesh to DAT, UNV and STL Formats
 603      * (UNV supported version is I-DEAS 10)
 604      */
 605     void ExportDAT( in string file ) raises (SALOME::SALOME_Exception);
 606     void ExportUNV( in string file ) raises (SALOME::SALOME_Exception);
 607     void ExportSTL( in string  file,
 608                     in boolean isascii ) raises (SALOME::SALOME_Exception);
 609     void ExportPartToDAT( in SMESH_IDSource meshPart,
 610                           in string         file ) raises (SALOME::SALOME_Exception);
 611     void ExportPartToUNV( in SMESH_IDSource meshPart,
 612                           in string         file ) raises (SALOME::SALOME_Exception);
 613     void ExportPartToSTL( in SMESH_IDSource meshPart,
 614                           in string         file,
 615                           in boolean        isascii ) raises (SALOME::SALOME_Exception);
 616
 617     /*!
 618      * Get MED Mesh
 619      */
 620     SALOME_MED::MESH GetMEDMesh()
 621       raises (SALOME::SALOME_Exception);
 622
 623     /*!
 624      * Get informations about mesh contents
 625      */
 626     long NbNodes()
 627       raises (SALOME::SALOME_Exception);
 628
 629     long NbElements()
 630       raises (SALOME::SALOME_Exception);
 631
 632     long Nb0DElements()
 633       raises (SALOME::SALOME_Exception);
 634
 635     long NbEdges()
 636       raises (SALOME::SALOME_Exception);
 637
 638     long NbEdgesOfOrder(in ElementOrder order)
 639       raises (SALOME::SALOME_Exception);
 640
 641     long NbFaces()
 642       raises (SALOME::SALOME_Exception);
 643
 644     long NbFacesOfOrder(in ElementOrder order)
 645       raises (SALOME::SALOME_Exception);
 646
 647     long NbTriangles()
 648       raises (SALOME::SALOME_Exception);
 649
 650     long NbTrianglesOfOrder(in ElementOrder order)
 651       raises (SALOME::SALOME_Exception);
 652
 653     long NbQuadrangles()
 654       raises (SALOME::SALOME_Exception);
 655
 656     long NbQuadranglesOfOrder(in ElementOrder order)
 657       raises (SALOME::SALOME_Exception);
 658
 659     long NbPolygons()
 660       raises (SALOME::SALOME_Exception);
 661
 662     long NbVolumes()
 663       raises (SALOME::SALOME_Exception);
 664
 665     long NbVolumesOfOrder(in ElementOrder order)
 666       raises (SALOME::SALOME_Exception);
 667
 668     long NbTetras()
 669       raises (SALOME::SALOME_Exception);
 670
 671     long NbTetrasOfOrder(in ElementOrder order)
 672       raises (SALOME::SALOME_Exception);
 673
 674     long NbHexas()
 675       raises (SALOME::SALOME_Exception);
 676
 677     long NbHexasOfOrder(in ElementOrder order)
 678       raises (SALOME::SALOME_Exception);
 679
 680     long NbPyramids()
 681       raises (SALOME::SALOME_Exception);
 682
 683     long NbPyramidsOfOrder(in ElementOrder order)
 684       raises (SALOME::SALOME_Exception);
 685
 686     long NbPrisms()
 687       raises (SALOME::SALOME_Exception);
 688
 689     long NbPrismsOfOrder(in ElementOrder order)
 690       raises (SALOME::SALOME_Exception);
 691
 692     long NbPolyhedrons()
 693       raises (SALOME::SALOME_Exception);
 694
 695     long NbSubMesh()
 696       raises (SALOME::SALOME_Exception);
 697
 698     long_array GetElementsId()
 699       raises (SALOME::SALOME_Exception);
 700
 701     long_array GetElementsByType( in ElementType theType )
 702       raises (SALOME::SALOME_Exception);
 703
 704     long_array GetNodesId()
 705       raises (SALOME::SALOME_Exception);
 706
 707     /*!
 708      * Returns type of mesh element
 709      */
 710     ElementType GetElementType( in long id, in boolean iselem )
 711       raises (SALOME::SALOME_Exception);
 712
 713     EntityType GetElementGeomType( in long id )
 714       raises (SALOME::SALOME_Exception);
 715
 716     long_array GetSubMeshElementsId(in long ShapeID)
 717       raises (SALOME::SALOME_Exception);
 718
 719     long_array GetSubMeshNodesId(in long ShapeID, in boolean all )
 720       raises (SALOME::SALOME_Exception);
 721
 722     ElementType GetSubMeshElementType(in long ShapeID)
 723       raises (SALOME::SALOME_Exception);
 724
 725
 726     /*!
 727      * Methods to set meshing order of submeshes
 728      */
 729
 730     /*!
 731      * \brief Return submesh objects list in meshing order
 732      */
 733     submesh_array_array GetMeshOrder();
 734
 735     /*!
 736      * \brief Set submesh object order
 737      */
 738     boolean SetMeshOrder(in submesh_array_array theSubMeshArray);
 739
 740
 741     /*!
 742      * Get mesh description
 743      */
 744     string Dump();
 745
 746     /*!
 747      * Get mesh pointer
 748      */
 749     long long GetMeshPtr();
 750
 751     /*!
 752      * Get XYZ coordinates of node as list of double
 753      * If there is not node for given ID - returns empty list
 754      */
 755     double_array GetNodeXYZ(in long id);
 756
 757     /*!
 758      * For given node returns list of IDs of inverse elements
 759      * If there is not node for given ID - returns empty list
 760      */
 761     long_array GetNodeInverseElements(in long id);
 762
 763     /*!
 764      * \brief Return position of a node on shape
 765      */
 766     NodePosition GetNodePosition(in long NodeID);
 767
 768     /*!
 769      * If given element is node returns IDs of shape from position
 770      * If there is not node for given ID - returns -1
 771      */
 772     long GetShapeID(in long id);
 773
 774     /*!
 775      * For given element returns ID of result shape after
 776      * ::FindShape() from SMESH_MeshEditor
 777      * If there is not element for given ID - returns -1
 778      */
 779     long GetShapeIDForElem(in long id);
 780
 781     /*!
 782      * Returns number of nodes for given element
 783      * If there is not element for given ID - returns -1
 784      */
 785     long GetElemNbNodes(in long id);
 786
 787     /*!
 788      * Returns IDs of nodes of given element
 789      */
 790     long_array GetElemNodes(in long id);
 791
 792     /*!
 793      * Returns ID of node by given index for given element
 794      * If there is not element for given ID - returns -1
 795      * If there is not node for given index - returns -2
 796      */
 797     long GetElemNode(in long id, in long index);
 798
 799     /*!
 800      * Returns true if given node is medium node
 801      * in given quadratic element
 802      */
 803     boolean IsMediumNode(in long ide, in long idn);
 804
 805     /*!
 806      * Returns true if given node is medium node
 807      * in one of quadratic elements
 808      */
 809     boolean IsMediumNodeOfAnyElem(in long idn, in ElementType elem_type);
 810
 811     /*!
 812      * Returns number of edges for given element
 813      */
 814     long ElemNbEdges(in long id);
 815
 816     /*!
 817      * Returns number of faces for given element
 818      */
 819     long ElemNbFaces(in long id);
 820
 821     /*!
 822      * Returns nodes of given face (counted from zero) for given volumic element.
 823      */
 824     long_array GetElemFaceNodes(in long elemId, in short faceIndex);
 825
 826     /*!
 827      * Returns an element based on all given nodes.
 828      */
 829     long FindElementByNodes(in long_array nodes);
 830
 831     /*!
 832      * Returns true if given element is polygon
 833      */
 834     boolean IsPoly(in long id);
 835
 836     /*!
 837      * Returns true if given element is quadratic
 838      */
 839     boolean IsQuadratic(in long id);
 840
 841     /*!
 842      * Returns XYZ coordinates of bary center for given element
 843      * as list of double
 844      * If there is not element for given ID - returns empty list
 845      */
 846     double_array BaryCenter(in long id);
 847
 848     /*! Gets information about imported MED file */
 849     SALOME_MED::MedFileInfo GetMEDFileInfo();
 850
 851     /*!
 852      *  Sets list of notebook variables used for Mesh operations separated by ":" symbol
 853      *  \param theParameters is a string containing the notebook variables
 854      */
 855     void SetParameters (in string theParameters);
 856
 857     /*!
 858      *  Returns list of notebook variables used for Mesh operations separated by ":" symbol
 859      */
 860     string GetParameters();
 861
 862     /*!
 863      *  Returns list of notebook variables used for last Mesh operation
 864      */
 865     string_array GetLastParameters();
 866   };
 867
 868   interface SMESH_subMesh : SALOME::GenericObj, SMESH_IDSource
 869   {
 870     /*!
 871      *
 872      */
 873     long GetNumberOfElements()
 874       raises (SALOME::SALOME_Exception);
 875
 876     /*!
 877      *
 878      */
 879     long GetNumberOfNodes( in boolean all )
 880       raises (SALOME::SALOME_Exception);
 881
 882     /*!
 883      *
 884      */
 885     long_array GetElementsId()
 886       raises (SALOME::SALOME_Exception);
 887
 888     /*!
 889      *
 890      */
 891     long_array GetElementsByType( in ElementType theType )
 892       raises (SALOME::SALOME_Exception);
 893
 894     /*!
 895      * Return type of submesh element
 896      */
 897     ElementType GetElementType( in long id, in boolean iselem )
 898       raises (SALOME::SALOME_Exception);
 899
 900     /*!
 901      *
 902      */
 903     long_array GetNodesId()
 904       raises (SALOME::SALOME_Exception);
 905
 906     /*!
 907      * Get geom shape the submesh is dedicated to
 908      */
 909     GEOM::GEOM_Object GetSubShape()
 910       raises (SALOME::SALOME_Exception);
 911
 912     /*!
 913      * Get SMESH_Mesh which stores nodes coordinates & elements definition
 914      */
 915     SMESH_Mesh GetFather()
 916       raises (SALOME::SALOME_Exception);
 917
 918     /*!
 919      * Get the internal Id
 920      */
 921     long GetId();
 922
 923     /*!
 924      * Get MED subMesh
 925      */
 926     SALOME_MED::FAMILY GetFamily()
 927       raises (SALOME::SALOME_Exception);
 928   };
 929
 930 };
 931
 932 #endif