idl/SMESH_Mesh.idl

   1 //  Copyright (C) 2003  OPEN CASCADE, EADS/CCR, LIP6, CEA/DEN,
   2 //  CEDRAT, EDF R&D, LEG, PRINCIPIA R&D, BUREAU VERITAS
   3 //
   4 //  This library is free software; you can redistribute it and/or
   5 //  modify it under the terms of the GNU Lesser General Public
   6 //  License as published by the Free Software Foundation; either
   7 //  version 2.1 of the License.
   8 //
   9 //  This library is distributed in the hope that it will be useful,
  10 //  but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 //  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 //  Lesser General Public License for more details.
  13 //
  14 //  You should have received a copy of the GNU Lesser General Public
  15 //  License along with this library; if not, write to the Free Software
  16 //  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
  17 //
  18 // See http://www.salome-platform.org/ or email : webmaster.salome@opencascade.com
  19 //
  20 //
  21 //
  22 //  File   : SMESH_Mesh.idl
  23 //  Author : Paul RASCLE, EDF
  24 //  $Header$
  25
  26 #ifndef _SMESH_MESH_IDL_
  27 #define _SMESH_MESH_IDL_
  28
  29 #include "SALOME_Exception.idl"
  30 #include "SALOME_GenericObj.idl"
  31 #include "GEOM_Gen.idl"
  32 #include "MED.idl"
  33
  34 module SMESH
  35 {
  36   interface SMESH_Hypothesis;
  37   typedef sequence<SMESH_Hypothesis> ListOfHypothesis;
  38   interface SMESH_GroupBase;
  39   typedef sequence<SMESH_GroupBase> ListOfGroups;
  40
  41   typedef sequence<double    > double_array ;
  42   typedef sequence<long      > long_array ;
  43   typedef sequence<string    > string_array ;
  44   typedef sequence<long_array> array_of_long_array ;
  45
  46   enum log_command
  47     {
  48       ADD_NODE,
  49       ADD_EDGE,
  50       ADD_TRIANGLE,
  51       ADD_QUADRANGLE,
  52       ADD_POLYGON,
  53       ADD_TETRAHEDRON,
  54       ADD_PYRAMID,
  55       ADD_PRISM,
  56       ADD_HEXAHEDRON,
  57       ADD_POLYHEDRON,
  58       REMOVE_NODE,
  59       REMOVE_ELEMENT,
  60       MOVE_NODE,
  61       CHANGE_ELEMENT_NODES,
  62       CHANGE_POLYHEDRON_NODES,
  63       RENUMBER,
  64       ADD_QUADEDGE,
  65       ADD_QUADTRIANGLE,
  66       ADD_QUADQUADRANGLE,
  67       ADD_QUADTETRAHEDRON,
  68       ADD_QUADPYRAMID,
  69       ADD_QUADPENTAHEDRON,
  70       ADD_QUADHEXAHEDRON
  71     };
  72
  73   struct log_block
  74   {
  75     long commandType;
  76     long number;
  77     double_array coords;
  78     long_array indexes;
  79   };
  80
  81   struct PointStruct { double x;
  82                        double y;
  83                        double z; } ;
  84
  85   typedef sequence<PointStruct> nodes_array;
  86
  87   struct DirStruct   { PointStruct PS ; } ;          // analog to Occ Direction
  88
  89   struct AxisStruct  { double x;
  90                        double y;
  91                        double z;
  92                        double vx;
  93                        double vy;
  94                        double vz; } ;
  95
  96
  97   /*!
  98    * Enumeration for element type, like in SMDS
  99    */
 100   enum ElementType
 101   {
 102     ALL,
 103     NODE,
 104     EDGE,
 105     FACE,
 106     VOLUME
 107   };
 108
 109   /*!
 110    * ElementOrder points out entities of what order are requested
 111    */
 112   enum ElementOrder {
 113     ORDER_ANY,          /*! entities of any order */
 114     ORDER_LINEAR,       /*! entities of 1st order */
 115     ORDER_QUADRATIC     /*! entities of 2nd order */
 116   };
 117
 118   /*!
 119    * Enumeration for hypothesis status (used by AddHypothesis() and RemoveHypothesis() methods)
 120    */
 121   enum Hypothesis_Status // in the order of severity
 122   {
 123     HYP_OK,
 124     HYP_MISSING,      // algo misses a hypothesis
 125     HYP_CONCURENT,    // several applicable hypotheses
 126     HYP_BAD_PARAMETER,// hypothesis has a bad parameter value
 127     HYP_HIDDEN_ALGO,  // an algo is hidden by an upper dim algo generating all-dim elements
 128     HYP_HIDING_ALGO,  // an algo hides lower dim algos by generating all-dim elements
 129     HYP_UNKNOWN_FATAL,//  --- all statuses below should be considered as fatal
 130                       //      for Add/RemoveHypothesis operations
 131     HYP_INCOMPATIBLE, // hypothesis does not fit algo
 132     HYP_NOTCONFORM,   // not conform mesh is produced appling a hypothesis
 133     HYP_ALREADY_EXIST,// such hypothesis already exist
 134     HYP_BAD_DIM,      // bad dimension
 135     HYP_BAD_SUBSHAPE, // shape is neither the main one, nor its subshape, nor a group
 136     HYP_BAD_GEOMETRY  // geometry mismatches algorithm's expectation
 137   };
 138
 139   /*!
 140    * Enumeration for DriverMED read status (used by ImportMEDFile() method)
 141    */
 142   enum DriverMED_ReadStatus // in the order of severity
 143   {
 144     DRS_OK,
 145     DRS_EMPTY,          // a MED file contains no mesh with the given name
 146     DRS_WARN_RENUMBER,  // a MED file has overlapped ranges of element numbers,
 147                         // so the numbers from the file are ignored
 148     DRS_WARN_SKIP_ELEM, // some elements were skipped due to incorrect file data
 149     DRS_FAIL            // general failure (exception etc.)
 150   };
 151
 152   /*!
 153    * Enumeration for DriverMED (used by Perform() method)
 154    */
 155   enum MED_VERSION // in the order of severity
 156   {
 157     MED_V2_1,
 158     MED_V2_2
 159   };
 160
 161   typedef sequence<log_block> log_array;
 162
 163
 164   /*!
 165    * Auxilary flags for advanced extrusion.
 166    * BOUNDARY: create or not boundary for result of extrusion
 167    * SEW:      try to use existing nodes or create new nodes in any case
 168    */
 169   const long EXTRUSION_FLAG_BOUNDARY = 1;
 170   const long EXTRUSION_FLAG_SEW = 2;
 171
 172   interface SMESH_IDSource
 173   {
 174     /*!
 175      * Returns a sequence of all element IDs
 176      */
 177     long_array GetIDs();
 178   };
 179
 180   interface SMESH_Group;
 181   interface SMESH_GroupOnGeom;
 182   interface SMESH_subMesh;
 183   interface SMESH_MeshEditor;
 184   interface SMESH_Mesh : SALOME::GenericObj, SMESH_IDSource
 185   {
 186     /*!
 187      * Return true if there is a geometry to be meshed
 188      */
 189     boolean HasShapeToMesh()
 190       raises (SALOME::SALOME_Exception);
 191
 192     /*!
 193      * Get geom shape to mesh. A result sould not be nil. Use HasShapeToMesh()
 194      * to know if a returned shape
 195      */
 196     GEOM::GEOM_Object GetShapeToMesh()
 197       raises (SALOME::SALOME_Exception);
 198
 199
 200     /*!
 201      * Get the subMesh object associated to a subShape. The subMesh object
 202      * gives access to nodes and elements IDs.
 203      * SubMesh will be used instead of SubShape in a next idl version to
 204      * adress a specific subMesh...
 205      */
 206     SMESH_subMesh GetSubMesh(in GEOM::GEOM_Object aSubObject, in string name)
 207       raises (SALOME::SALOME_Exception);
 208
 209     /*!
 210      * Remove a submesh
 211      */
 212     void RemoveSubMesh(in SMESH_subMesh aSubMesh)
 213       raises (SALOME::SALOME_Exception);
 214
 215
 216     /*!
 217      * Create a group
 218      */
 219     SMESH_Group CreateGroup( in ElementType elem_type,
 220                              in string name )
 221       raises (SALOME::SALOME_Exception);
 222
 223     /*!
 224      * Create a group from geometry group
 225      */
 226     SMESH_GroupOnGeom CreateGroupFromGEOM( in ElementType elem_type,
 227                                           in string name,
 228                                           in GEOM::GEOM_Object theGeomObject )
 229       raises (SALOME::SALOME_Exception);
 230
 231     /*!
 232      * Remove a group
 233      */
 234     void RemoveGroup(in SMESH_GroupBase aGroup)
 235       raises (SALOME::SALOME_Exception);
 236
 237     /*!
 238      *  Remove group with its contents
 239      */
 240     void RemoveGroupWithContents( in SMESH_GroupBase aGroup )
 241       raises (SALOME::SALOME_Exception);
 242
 243     /*!
 244      *  Get the list of groups existing in the mesh
 245      */
 246     ListOfGroups GetGroups()
 247       raises (SALOME::SALOME_Exception);
 248
 249     /*!
 250      * Union of two groups
 251      *    New group is created. All mesh elements that are
 252      *    present in initial groups are added to the new one
 253      */
 254     SMESH_Group UnionGroups (in SMESH_GroupBase aGroup1,
 255                              in SMESH_GroupBase aGroup2,
 256                              in string          name )
 257       raises (SALOME::SALOME_Exception);
 258
 259     /*!
 260      *  Intersection of two groups
 261      *  New group is created. All mesh elements that are
 262      *  present in both initial groups are added to the new one.
 263      */
 264     SMESH_Group IntersectGroups (in SMESH_GroupBase aGroup1,
 265                                  in SMESH_GroupBase aGroup2,
 266                                  in string          name )
 267       raises (SALOME::SALOME_Exception);
 268
 269     /*!
 270      *  Cut of two groups
 271      *  New group is created. All mesh elements that are present in
 272      *  main group but do not present in tool group are added to the new one
 273      */
 274     SMESH_Group CutGroups (in SMESH_GroupBase aMainGroup,
 275                            in SMESH_GroupBase aToolGroup,
 276                            in string          name )
 277       raises (SALOME::SALOME_Exception);
 278
 279     /*!
 280      * Add hypothesis to the mesh, under a particular subShape
 281      * (or the main shape itself)
 282      * The Add method is only used to prepare the build of the mesh and store
 283      * the algorithms and associated parameters.
 284      * Actual job of mesh the shape is done by MESH_Gen.
 285      * @params
 286      * - aSubShape : subShape obtained by a shape explode in GEOM
 287      *   (or main shape)
 288      * - anHyp : hypothesis object
 289      * @return
 290      * - OK if the hypothesis is compatible with the subShape
 291      *   (and all previous hypothesis on the subShape)
 292      * - NOK if the hypothesis is not compatible with the subShape
 293      *   (or one previous hypothesis on the subShape)
 294      * raises exception if hypothesis has not been created
 295      */
 296     Hypothesis_Status AddHypothesis(in GEOM::GEOM_Object aSubObject,
 297                                     in SMESH_Hypothesis anHyp)
 298       raises (SALOME::SALOME_Exception);
 299 //     boolean AddHypothesis(in SMESH_subMesh aSubMesh, in SMESH_Hypothesis anHyp)
 300 //       raises (SALOME::SALOME_Exception);
 301
 302     /*!
 303      * Remove an hypothesis previouly added with AddHypothesis.
 304      */
 305     Hypothesis_Status RemoveHypothesis(in GEOM::GEOM_Object aSubObject,
 306                                        in SMESH_Hypothesis anHyp)
 307       raises (SALOME::SALOME_Exception);
 308 //     boolean RemoveHypothesis(in SMESH_subMesh aSubMesh,
 309 //                           in SMESH_Hypothesis anHyp)
 310 //       raises (SALOME::SALOME_Exception);
 311
 312     /*!
 313      * Get the list of hypothesis added on a subShape
 314      */
 315     ListOfHypothesis GetHypothesisList(in GEOM::GEOM_Object aSubObject)
 316       raises (SALOME::SALOME_Exception);
 317 //     ListOfHypothesis GetHypothesisList(in SMESH_subMesh aSubMesh)
 318 //       raises (SALOME::SALOME_Exception);
 319
 320     /*!
 321      * Get the log of nodes and elements added or removed since previous
 322      * clear of the log.
 323      * @params
 324      * - clearAfterGet : log is emptied after Get (safe if concurrents access)
 325      */
 326     //    string_array GetLog(in boolean clearAfterGet)
 327     //      raises (SALOME::SALOME_Exception);
 328     log_array GetLog(in boolean clearAfterGet)
 329       raises (SALOME::SALOME_Exception);
 330
 331     /*!
 332      * Clear the log of nodes and elements added or removed since previous
 333      * clear. Must be used immediately after GetLog if clearAfterGet is false.
 334      */
 335     void ClearLog()
 336       raises (SALOME::SALOME_Exception);
 337
 338     /*!
 339      * Toggle auto color mode on the object.
 340      * @params
 341      * - theAutoColor : flag which toggles auto color mode.
 342      */
 343     void SetAutoColor(in boolean theAutoColor)
 344       raises (SALOME::SALOME_Exception);
 345
 346     /*!
 347      * Get flag of object's auto color mode.
 348      */
 349     boolean GetAutoColor()
 350       raises (SALOME::SALOME_Exception);
 351
 352     /*!
 353      * Get the internal Id
 354      */
 355     long GetId();
 356
 357     /*!
 358      * Get the study Id
 359      */
 360     long GetStudyId();
 361
 362     /*!
 363      * Obtain instance of SMESH_MeshEditor
 364      */
 365     SMESH_MeshEditor GetMeshEditor()
 366       raises (SALOME::SALOME_Exception);
 367
 368     /*!
 369      * Return SMESH_MeshEditor that would not modify the mesh but
 370      * fill MeshPreviewStruct
 371      */
 372     SMESH_MeshEditor GetMeshEditPreviewer()
 373       raises (SALOME::SALOME_Exception);
 374
 375     /*! Check group names for duplications.
 376      *  Consider maximum group name length stored in MED file.
 377      */
 378     boolean HasDuplicatedGroupNamesMED();
 379
 380     /*!
 381      * Export Mesh to different MED Formats
 382      * @params
 383      * - auto_groups : boolean parameter for creating/not creating
 384      *   the groups Group_On_All_Nodes, Group_On_All_Faces, ... ;
 385      *   the typical use is auto_groups=false.
 386      * - theVersion : define the version of format of MED file, that will be created
 387      */
 388     void ExportToMED( in string file, in boolean auto_groups, in MED_VERSION theVersion )
 389       raises (SALOME::SALOME_Exception);
 390
 391     /*!
 392      * Export Mesh to MED_V2_1 MED format
 393      * Works, just the same as ExportToMED, with MED_VERSION parameter equal to MED_V2_1.
 394      * The method is kept in order to support old functionality
 395      */
 396     void ExportMED( in string file, in boolean auto_groups )
 397       raises (SALOME::SALOME_Exception);
 398
 399     /*!
 400      * Export Mesh to DAT, UNV and STL Formats
 401      * (UNV supported version is I-DEAS 10)
 402      */
 403     void ExportDAT( in string file )
 404       raises (SALOME::SALOME_Exception);
 405     void ExportUNV( in string file )
 406       raises (SALOME::SALOME_Exception);
 407     void ExportSTL( in string file, in boolean isascii )
 408       raises (SALOME::SALOME_Exception);
 409
 410     /*!
 411      * Get MED Mesh
 412      */
 413     SALOME_MED::MESH GetMEDMesh()
 414       raises (SALOME::SALOME_Exception);
 415
 416     /*!
 417      * Get informations about mesh contents
 418      */
 419     long NbNodes()
 420       raises (SALOME::SALOME_Exception);
 421
 422     long NbElements()
 423       raises (SALOME::SALOME_Exception);
 424
 425     long NbEdges()
 426       raises (SALOME::SALOME_Exception);
 427
 428     long NbEdgesOfOrder(in ElementOrder order)
 429       raises (SALOME::SALOME_Exception);
 430
 431     long NbFaces()
 432       raises (SALOME::SALOME_Exception);
 433
 434     long NbFacesOfOrder(in ElementOrder order)
 435       raises (SALOME::SALOME_Exception);
 436
 437     long NbTriangles()
 438       raises (SALOME::SALOME_Exception);
 439
 440     long NbTrianglesOfOrder(in ElementOrder order)
 441       raises (SALOME::SALOME_Exception);
 442
 443     long NbQuadrangles()
 444       raises (SALOME::SALOME_Exception);
 445
 446     long NbQuadranglesOfOrder(in ElementOrder order)
 447       raises (SALOME::SALOME_Exception);
 448
 449     long NbPolygons()
 450       raises (SALOME::SALOME_Exception);
 451
 452     long NbVolumes()
 453       raises (SALOME::SALOME_Exception);
 454
 455     long NbVolumesOfOrder(in ElementOrder order)
 456       raises (SALOME::SALOME_Exception);
 457
 458     long NbTetras()
 459       raises (SALOME::SALOME_Exception);
 460
 461     long NbTetrasOfOrder(in ElementOrder order)
 462       raises (SALOME::SALOME_Exception);
 463
 464     long NbHexas()
 465       raises (SALOME::SALOME_Exception);
 466
 467     long NbHexasOfOrder(in ElementOrder order)
 468       raises (SALOME::SALOME_Exception);
 469
 470     long NbPyramids()
 471       raises (SALOME::SALOME_Exception);
 472
 473     long NbPyramidsOfOrder(in ElementOrder order)
 474       raises (SALOME::SALOME_Exception);
 475
 476     long NbPrisms()
 477       raises (SALOME::SALOME_Exception);
 478
 479     long NbPrismsOfOrder(in ElementOrder order)
 480       raises (SALOME::SALOME_Exception);
 481
 482     long NbPolyhedrons()
 483       raises (SALOME::SALOME_Exception);
 484
 485     long NbSubMesh()
 486       raises (SALOME::SALOME_Exception);
 487
 488     long_array GetElementsId()
 489       raises (SALOME::SALOME_Exception);
 490
 491     long_array GetElementsByType( in ElementType theType )
 492       raises (SALOME::SALOME_Exception);
 493
 494     long_array GetNodesId()
 495       raises (SALOME::SALOME_Exception);
 496
 497     /*!
 498      * Returns type of mesh element
 499      */
 500     ElementType GetElementType( in long id, in boolean iselem )
 501       raises (SALOME::SALOME_Exception);
 502
 503     long_array GetSubMeshElementsId(in long ShapeID)
 504       raises (SALOME::SALOME_Exception);
 505
 506     long_array GetSubMeshNodesId(in long ShapeID, in boolean all )
 507       raises (SALOME::SALOME_Exception);
 508
 509     ElementType GetSubMeshElementType(in long ShapeID)
 510       raises (SALOME::SALOME_Exception);
 511
 512     /*!
 513      * Get mesh description
 514      */
 515     string Dump();
 516
 517     /*!
 518      * Get mesh pointer
 519      */
 520     long long GetMeshPtr();
 521
 522     /*!
 523      * Get XYZ coordinates of node as list of double
 524      * If there is not node for given ID - returns empty list
 525      */
 526     double_array GetNodeXYZ(in long id);
 527
 528     /*!
 529      * For given node returns list of IDs of inverse elements
 530      * If there is not node for given ID - returns empty list
 531      */
 532     long_array GetNodeInverseElements(in long id);
 533
 534     /*!
 535      * If given element is node returns IDs of shape from position
 536      * If there is not node for given ID - returns -1
 537      */
 538     long GetShapeID(in long id);
 539
 540     /*!
 541      * For given element returns ID of result shape after
 542      * ::FindShape() from SMESH_MeshEditor
 543      * If there is not element for given ID - returns -1
 544      */
 545     long GetShapeIDForElem(in long id);
 546
 547     /*!
 548      * Returns number of nodes for given element
 549      * If there is not element for given ID - returns -1
 550      */
 551     long GetElemNbNodes(in long id);
 552
 553     /*!
 554      * Returns IDs of nodes of given element
 555      */
 556     long_array GetElemNodes(in long id);
 557
 558     /*!
 559      * Returns ID of node by given index for given element
 560      * If there is not element for given ID - returns -1
 561      * If there is not node for given index - returns -2
 562      */
 563     long GetElemNode(in long id, in long index);
 564
 565     /*!
 566      * Returns true if given node is medium node
 567      * in given quadratic element
 568      */
 569     boolean IsMediumNode(in long ide, in long idn);
 570
 571     /*!
 572      * Returns true if given node is medium node
 573      * in one of quadratic elements
 574      */
 575     boolean IsMediumNodeOfAnyElem(in long idn, in ElementType elem_type);
 576
 577     /*!
 578      * Returns number of edges for given element
 579      */
 580     long ElemNbEdges(in long id);
 581
 582     /*!
 583      * Returns number of faces for given element
 584      */
 585     long ElemNbFaces(in long id);
 586
 587     /*!
 588      * Returns true if given element is polygon
 589      */
 590     boolean IsPoly(in long id);
 591
 592     /*!
 593      * Returns true if given element is quadratic
 594      */
 595     boolean IsQuadratic(in long id);
 596
 597     /*!
 598      * Returns XYZ coordinates of bary center for given element
 599      * as list of double
 600      * If there is not element for given ID - returns empty list
 601      */
 602     double_array BaryCenter(in long id);
 603
 604   };
 605
 606   interface SMESH_subMesh : SALOME::GenericObj, SMESH_IDSource
 607   {
 608     /*!
 609      *
 610      */
 611     long GetNumberOfElements()
 612       raises (SALOME::SALOME_Exception);
 613
 614     /*!
 615      *
 616      */
 617     long GetNumberOfNodes( in boolean all )
 618       raises (SALOME::SALOME_Exception);
 619
 620     /*!
 621      *
 622      */
 623     long_array GetElementsId()
 624       raises (SALOME::SALOME_Exception);
 625
 626     /*!
 627      *
 628      */
 629     long_array GetElementsByType( in ElementType theType )
 630       raises (SALOME::SALOME_Exception);
 631
 632     /*!
 633      * Return type of submesh element
 634      */
 635     ElementType GetElementType( in long id, in boolean iselem )
 636       raises (SALOME::SALOME_Exception);
 637
 638     /*!
 639      *
 640      */
 641     long_array GetNodesId()
 642       raises (SALOME::SALOME_Exception);
 643
 644     /*!
 645      * Get geom shape the submesh is dedicated to
 646      */
 647     GEOM::GEOM_Object GetSubShape()
 648       raises (SALOME::SALOME_Exception);
 649
 650     /*!
 651      * Get SMESH_Mesh which stores nodes coordinates & elements definition
 652      */
 653     SMESH_Mesh GetFather()
 654       raises (SALOME::SALOME_Exception);
 655
 656     /*!
 657      * Get the internal Id
 658      */
 659     long GetId();
 660
 661     /*!
 662      * Get MED subMesh
 663      */
 664     SALOME_MED::FAMILY GetFamily()
 665       raises (SALOME::SALOME_Exception);
 666   };
 667
 668 };
 669
 670 #endif