idl/SMESH_Mesh.idl

   1 // Copyright (C) 2007-2016  CEA/DEN, EDF R&D, OPEN CASCADE
   2 //
   3 // Copyright (C) 2003-2007  OPEN CASCADE, EADS/CCR, LIP6, CEA/DEN,
   4 // CEDRAT, EDF R&D, LEG, PRINCIPIA R&D, BUREAU VERITAS
   5 //
   6 // This library is free software; you can redistribute it and/or
   7 // modify it under the terms of the GNU Lesser General Public
   8 // License as published by the Free Software Foundation; either
   9 // version 2.1 of the License, or (at your option) any later version.
  10 //
  11 // This library is distributed in the hope that it will be useful,
  12 // but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 // MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14 // Lesser General Public License for more details.
  15 //
  16 // You should have received a copy of the GNU Lesser General Public
  17 // License along with this library; if not, write to the Free Software
  18 // Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
  19 //
  20 // See http://www.salome-platform.org/ or email : webmaster.salome@opencascade.com
  21 //
  22
  23 //  File   : SMESH_Mesh.idl
  24 //  Author : Paul RASCLE, EDF
  25 //
  26 #ifndef _SMESH_MESH_IDL_
  27 #define _SMESH_MESH_IDL_
  28
  29 #include "SALOME_Exception.idl"
  30 #include "SALOME_GenericObj.idl"
  31 #include "GEOM_Gen.idl"
  32
  33 module SMESH
  34 {
  35   interface SMESH_Hypothesis;
  36   typedef sequence<SMESH_Hypothesis> ListOfHypothesis;
  37   interface SMESH_GroupBase;
  38   typedef sequence<SMESH_GroupBase> ListOfGroups;
  39   interface SMESH_IDSource;
  40   typedef sequence<SMESH_IDSource> ListOfIDSources;
  41
  42   typedef sequence<double    > double_array ;
  43   typedef sequence<long      > long_array ;
  44   typedef sequence<string    > string_array ;
  45   typedef sequence<long_array> array_of_long_array ;
  46
  47   enum log_command
  48     {
  49       ADD_NODE,
  50       ADD_EDGE,
  51       ADD_TRIANGLE,
  52       ADD_QUADRANGLE,
  53       ADD_POLYGON,
  54       ADD_TETRAHEDRON,
  55       ADD_PYRAMID,
  56       ADD_PRISM,
  57       ADD_HEXAHEDRON,
  58       ADD_POLYHEDRON,
  59       REMOVE_NODE,
  60       REMOVE_ELEMENT,
  61       MOVE_NODE,
  62       CHANGE_ELEMENT_NODES,
  63       CHANGE_POLYHEDRON_NODES,
  64       RENUMBER,
  65       CLEAR_MESH,
  66       ADD_QUADEDGE,
  67       ADD_QUADTRIANGLE,
  68       ADD_QUADQUADRANGLE,
  69       ADD_QUADPOLYGON,
  70       ADD_QUADTETRAHEDRON,
  71       ADD_QUADPYRAMID,
  72       ADD_QUADPENTAHEDRON,
  73       ADD_QUADHEXAHEDRON,
  74       ADD_ELEM0D,
  75       ADD_BIQUAD_TRIANGLE,
  76       ADD_BIQUAD_QUADRANGLE,
  77       ADD_TRIQUAD_HEXA,
  78       ADD_HEXAGONAL_PRISM,
  79       ADD_BALL
  80     };
  81
  82   struct log_block
  83   {
  84     long commandType;
  85     long number;
  86     double_array coords;
  87     long_array indexes;
  88   };
  89   typedef sequence<log_block> log_array;
  90
  91   struct PointStruct { double x;
  92                        double y;
  93                        double z; };
  94
  95   typedef sequence<PointStruct> nodes_array;
  96
  97   struct DirStruct   { PointStruct PS; };          // analog to OCCT gp_Vec
  98
  99   struct AxisStruct  { double x;
 100                        double y;
 101                        double z;
 102                        double vx;
 103                        double vy;
 104                        double vz; };
 105   /*!
 106    * Node location on a shape
 107    */
 108   struct NodePosition {
 109     long             shapeID;
 110     GEOM::shape_type shapeType;
 111     double_array     params; // [U] on EDGE, [U,V] on FACE, [] on the rest shapes
 112   };
 113
 114   /*!
 115    * Element location on a shape
 116    */
 117   struct ElementPosition {
 118     long             shapeID;
 119     GEOM::shape_type shapeType;
 120   };
 121
 122   /*!
 123    * Enumeration for element type, like in SMDS
 124    */
 125   enum ElementType
 126   {
 127     ALL,
 128     NODE,
 129     EDGE,
 130     FACE,
 131     VOLUME,
 132     ELEM0D,
 133     BALL,
 134     NB_ELEMENT_TYPES
 135   };
 136   typedef sequence<ElementType> array_of_ElementType;
 137
 138   /*!
 139    * Enumeration for element geometry type, like SMDSAbs_GeometryType in SMDSAbs_ElementType.hxx
 140    */
 141   enum GeometryType
 142   {
 143     Geom_POINT,
 144     Geom_EDGE,
 145     Geom_TRIANGLE,
 146     Geom_QUADRANGLE, // when a new GeometryType is added, please
 147     Geom_POLYGON,    // update a corresponding list in SMESH_2smeshpy.cxx, ln 665
 148     Geom_TETRA,
 149     Geom_PYRAMID,
 150     Geom_HEXA,
 151     Geom_PENTA,
 152     Geom_HEXAGONAL_PRISM,
 153     Geom_POLYHEDRA,
 154     Geom_BALL,
 155     Geom_LAST
 156   };
 157
 158   /*!
 159    * ElementOrder points out entities of what order are requested
 160    */
 161   enum ElementOrder {
 162     ORDER_ANY,          /*! entities of any order */
 163     ORDER_LINEAR,       /*! entities of 1st order */
 164     ORDER_QUADRATIC     /*! entities of 2nd order */
 165   };
 166
 167   /*!
 168    * Enumeration of entity type used in mesh info array,
 169    * it should be synchronised with enum SMDSAbs_EntityType
 170    */
 171   enum EntityType
 172   {
 173     Entity_Node,
 174     Entity_0D,
 175     Entity_Edge,
 176     Entity_Quad_Edge,
 177     Entity_Triangle,
 178     Entity_Quad_Triangle,
 179     Entity_BiQuad_Triangle,
 180     Entity_Quadrangle,
 181     Entity_Quad_Quadrangle,
 182     Entity_BiQuad_Quadrangle,
 183     Entity_Polygon,
 184     Entity_Quad_Polygon,
 185     Entity_Tetra,
 186     Entity_Quad_Tetra,
 187     Entity_Pyramid,
 188     Entity_Quad_Pyramid,
 189     Entity_Hexa,
 190     Entity_Quad_Hexa,
 191     Entity_TriQuad_Hexa,
 192     Entity_Penta,
 193     Entity_Quad_Penta,
 194     Entity_BiQuad_Penta,
 195     Entity_Hexagonal_Prism,
 196     Entity_Polyhedra,
 197     Entity_Quad_Polyhedra,
 198     Entity_Ball,
 199     Entity_Last
 200   };
 201
 202   /*!
 203    * Enumeration for hypothesis status (used by AddHypothesis() and RemoveHypothesis() methods)
 204    */
 205   enum Hypothesis_Status // in the order of severity
 206   {
 207     HYP_OK,
 208     HYP_MISSING,      // algo misses a hypothesis
 209     HYP_CONCURRENT,   // several applicable hypotheses
 210     HYP_BAD_PARAMETER,// hypothesis has a bad parameter value
 211     HYP_HIDDEN_ALGO,  // an algo is hidden by an upper dim algo generating all-dim elements
 212     HYP_HIDING_ALGO,  // an algo hides lower dim algos by generating all-dim elements
 213     HYP_UNKNOWN_FATAL,//  --- all statuses below should be considered as fatal
 214                       //      for Add/RemoveHypothesis operations
 215     HYP_INCOMPATIBLE, // hypothesis does not fit algo
 216     HYP_NOTCONFORM,   // not conform mesh is produced applying a hypothesis
 217     HYP_ALREADY_EXIST,// such hypothesis already exist
 218     HYP_BAD_DIM,      // bad dimension
 219     HYP_BAD_SUBSHAPE, // shape is neither the main one, nor its sub-shape, nor a group
 220     HYP_BAD_GEOMETRY, // geometry mismatches algorithm's expectation
 221     HYP_NEED_SHAPE,   // algorithm can work on shape only
 222     HYP_INCOMPAT_HYPS // several additional hypotheses are incompatible one with other
 223   };
 224
 225   /*!
 226    * Enumeration for mesh read status (used by SMESH_Gen::CreateMeshesFrom*() methods)
 227    */
 228   enum DriverMED_ReadStatus // in the order of severity
 229   {
 230     DRS_OK,
 231     DRS_EMPTY,          // a file contains no mesh with the given name
 232     DRS_WARN_RENUMBER,  // a MED file has overlapped ranges of element numbers,
 233                         // so the numbers from the file are ignored
 234     DRS_WARN_SKIP_ELEM, // some elements were skipped due to incorrect file data
 235     DRS_WARN_DESCENDING, // some elements were skipped due to descending connectivity
 236     DRS_FAIL            // general failure (exception etc.)
 237   };
 238
 239   /*!
 240    * \brief A structure containing information about MED file
 241    */
 242   struct MedFileInfo
 243   {
 244     string fileName; //!< name of file
 245     long   fileSize; //!< size of file
 246     long   major, minor, release; //!< MED file version
 247   };
 248
 249   /*!
 250    * Enumeration for CreateDimGroup()
 251    */
 252   enum NB_COMMON_NODES_ENUM
 253   {
 254     ALL_NODES, MAIN, AT_LEAST_ONE, MAJORITY
 255   };
 256
 257   /*!
 258    * Auxiliary flags for advanced extrusion.
 259    * BOUNDARY: create or not boundary for result of extrusion
 260    * SEW:      try to use existing nodes or create new nodes in any case
 261    */
 262   const long EXTRUSION_FLAG_BOUNDARY = 1;
 263   const long EXTRUSION_FLAG_SEW = 2;
 264
 265   /*!
 266    * Structure used in mesh edit preview data (MeshPreviewStruct)
 267    */
 268   struct ElementSubType { ElementType SMDS_ElementType;
 269                           boolean     isPoly;
 270                           long        nbNodesInElement; };
 271
 272   typedef sequence<ElementSubType> types_array;
 273
 274   /*!
 275    * Structure containing mesh edit preview data
 276    */
 277   struct MeshPreviewStruct { nodes_array nodesXYZ;
 278                              long_array  elementConnectivities;
 279                              types_array elementTypes; };
 280
 281   interface SMESH_Mesh;
 282
 283   interface SMESH_IDSource : SALOME::GenericObj
 284   {
 285     /*!
 286      * Returns a sequence of all element IDs
 287      */
 288     long_array GetIDs();
 289
 290     /*!
 291      * Returns number of mesh elements of each \a EntityType
 292      * @return array of number of elements per \a EntityType
 293      */
 294     long_array GetMeshInfo();
 295
 296     /*!
 297      * Returns number of mesh elements of each \a ElementType
 298      * @return array of number of elements per \a ElementType
 299      */
 300     long_array GetNbElementsByType();
 301
 302     /*!
 303      * Returns types of elements it contains.
 304      * It's empty if the SMESH_IDSource contains no IDs
 305      */
 306     array_of_ElementType GetTypes();
 307
 308     /*!
 309      * Returns the mesh
 310      */
 311     SMESH_Mesh GetMesh();
 312
 313     /*!
 314      * Returns false if GetMeshInfo() returns incorrect information that may
 315      * happen if mesh data is not yet fully loaded from the file of study.
 316      */
 317     boolean IsMeshInfoCorrect();
 318
 319     /*!
 320      * Returns mesh unstructed grid information.
 321      */
 322     SALOMEDS::TMPFile GetVtkUgStream();
 323   };
 324
 325   interface SMESH_Group;
 326   interface SMESH_GroupOnGeom;
 327   interface Filter;
 328   interface SMESH_GroupOnFilter;
 329   interface SMESH_subMesh;
 330   interface SMESH_MeshEditor;
 331
 332   typedef sequence<SMESH_subMesh>     submesh_array;
 333   typedef sequence<submesh_array>     submesh_array_array;
 334
 335   interface SMESH_Mesh : SMESH_IDSource
 336   {
 337     /*!
 338      * Return true if there is a geometry to be meshed
 339      */
 340     boolean HasShapeToMesh()
 341       raises (SALOME::SALOME_Exception);
 342
 343     /*!
 344      * Get geom shape to mesh. A result should not be nil. Use HasShapeToMesh()
 345      * to know if a returned shape
 346      */
 347     GEOM::GEOM_Object GetShapeToMesh()
 348       raises (SALOME::SALOME_Exception);
 349
 350     /*!
 351      * Return false if the mesh is not yet fully loaded from the study file
 352      */
 353     boolean IsLoaded()
 354       raises (SALOME::SALOME_Exception);
 355
 356     /*!
 357      * Load full mesh data from the study file
 358      */
 359     void Load()
 360       raises (SALOME::SALOME_Exception);
 361
 362     /*!
 363      * Remove all nodes and elements
 364      */
 365     void Clear()
 366       raises (SALOME::SALOME_Exception);
 367
 368     /*!
 369      *  Get the list of sub-meshes existing in the mesh
 370      */
 371     submesh_array GetSubMeshes()
 372       raises (SALOME::SALOME_Exception);
 373
 374     /*!
 375      * Remove all nodes and elements of submesh
 376      */
 377     void ClearSubMesh(in long ShapeID)
 378       raises (SALOME::SALOME_Exception);
 379
 380     /*!
 381      * Get the subMesh object associated to a Sub-shape. The subMesh object
 382      * gives access to nodes and elements IDs.
 383      * SubMesh will be used instead of Sub-shape in a next idl version to
 384      * address a specific subMesh...
 385      */
 386     SMESH_subMesh GetSubMesh(in GEOM::GEOM_Object aSubObject, in string name)
 387       raises (SALOME::SALOME_Exception);
 388
 389     /*!
 390      * Remove a submesh
 391      */
 392     void RemoveSubMesh(in SMESH_subMesh aSubMesh)
 393       raises (SALOME::SALOME_Exception);
 394
 395
 396     /*!
 397      * Create a group
 398      */
 399     SMESH_Group CreateGroup( in ElementType elem_type,
 400                              in string      name )
 401       raises (SALOME::SALOME_Exception);
 402
 403     /*!
 404      * Create a group from geometry
 405      */
 406     SMESH_GroupOnGeom CreateGroupFromGEOM( in ElementType       elemType,
 407                                            in string            name,
 408                                            in GEOM::GEOM_Object geomObject )
 409       raises (SALOME::SALOME_Exception);
 410
 411     /*!
 412      * Create a group from filter
 413      */
 414     SMESH_GroupOnFilter CreateGroupFromFilter( in ElementType   elemType,
 415                                                in string        name,
 416                                                in SMESH::Filter filter )
 417       raises (SALOME::SALOME_Exception);
 418
 419     /*!
 420      * Remove a group
 421      */
 422     void RemoveGroup(in SMESH_GroupBase aGroup)
 423       raises (SALOME::SALOME_Exception);
 424
 425     /*!
 426      *  Remove group with its contents
 427      */
 428     void RemoveGroupWithContents( in SMESH_GroupBase aGroup )
 429       raises (SALOME::SALOME_Exception);
 430
 431     /*!
 432      *  Get the list of groups existing in the mesh
 433      */
 434     ListOfGroups GetGroups()
 435       raises (SALOME::SALOME_Exception);
 436
 437     /*!
 438      *  Get number of groups existing in the mesh
 439      */
 440     long NbGroups()
 441       raises (SALOME::SALOME_Exception);
 442
 443     /*!
 444      * Union of two groups
 445      *    New group is created. All mesh elements that are
 446      *    present in initial groups are added to the new one
 447      */
 448     SMESH_Group UnionGroups (in SMESH_GroupBase aGroup1,
 449                              in SMESH_GroupBase aGroup2,
 450                              in string          name )
 451       raises (SALOME::SALOME_Exception);
 452
 453     /*!
 454      * Union of list of groups
 455      * New group is created. All mesh elements that are
 456      * present in initial groups are added to the new one
 457      */
 458     SMESH_Group UnionListOfGroups (in ListOfGroups aListOfGroups,
 459                                    in string       name )
 460       raises (SALOME::SALOME_Exception);
 461
 462     /*!
 463      *  Intersection of two groups
 464      *  New group is created. All mesh elements that are
 465      *  present in both initial groups are added to the new one.
 466      */
 467     SMESH_Group IntersectGroups (in SMESH_GroupBase aGroup1,
 468                                  in SMESH_GroupBase aGroup2,
 469                                  in string          name )
 470       raises (SALOME::SALOME_Exception);
 471
 472     /*!
 473      *  Intersection of list of groups
 474      *  New group is created. All mesh elements that are
 475      *  present in all initial groups simultaneously are added to the new one.
 476      */
 477     SMESH_Group IntersectListOfGroups (in ListOfGroups aListOfGroups,
 478                                        in string       name)
 479       raises (SALOME::SALOME_Exception);
 480
 481     /*!
 482      *  Cut of two groups
 483      *  New group is created. All mesh elements that are present in
 484      *  main group but do not present in tool group are added to the new one
 485      */
 486     SMESH_Group CutGroups (in SMESH_GroupBase aMainGroup,
 487                            in SMESH_GroupBase aToolGroup,
 488                            in string          name )
 489       raises (SALOME::SALOME_Exception);
 490
 491     /*!
 492      *  Cut of lists of groups
 493      *  New group is created. All mesh elements that are present in
 494      *  main groups but do not present in tool groups are added to the new one
 495      */
 496     SMESH_Group CutListOfGroups (in ListOfGroups aMainGroups,
 497                                  in ListOfGroups aToolGroups,
 498                                  in string       name)
 499       raises (SALOME::SALOME_Exception);
 500
 501     /*!
 502      *  Create a group of entities basing on nodes of other groups.
 503      *  \param [in] aListOfGroups - list of either groups, sub-meshes or filters.
 504      *  \param [in] anElemType - a type of elements to include to the new group.
 505      *  \param [in] name - a name of the new group.
 506      *  \param [in] nbCommonNodes - criterion of inclusion of an element to the new group.
 507      *  \param [in] underlyingOnly - if \c True, an element is included to the
 508      *         new group provided that it is based on nodes of an element of
 509      *         \a aListOfGroups
 510      *  \return SMESH_Group - the created group
 511      */
 512     SMESH_Group CreateDimGroup( in ListOfIDSources      aListOfGroups,
 513                                 in ElementType          anElemType,
 514                                 in string               name,
 515                                 in NB_COMMON_NODES_ENUM nbCommonNodes,
 516                                 in boolean              underlyingOnly )
 517       raises (SALOME::SALOME_Exception);
 518
 519     /*!
 520      * Convert group on geometry or on filter into standalone group
 521      */
 522     SMESH_Group ConvertToStandalone( in SMESH_GroupBase theGroupOn )
 523       raises (SALOME::SALOME_Exception);
 524
 525     /*!
 526      * Add hypothesis to the mesh, under a particular sub-shape
 527      * (or the main shape itself)
 528      * This method is only used to prepare the build of the mesh and store
 529      * the algorithms and associated parameters.
 530      * Actual job of meshing the shape is done by SMESH_Gen::Compute()
 531      * @params
 532      * - aSubObject : sub-shape obtained by a shape explode in GEOM
 533      *   (or main shape)
 534      * - anHyp : an hypothesis object
 535      * @return
 536      * - An enum item explaining what's up
 537      * - anErrorText: an optional textual description of a problem (if any)
 538      */
 539     Hypothesis_Status AddHypothesis(in GEOM::GEOM_Object aSubObject,
 540                                     in SMESH_Hypothesis  anHyp,
 541                                     out string           anErrorText)
 542       raises (SALOME::SALOME_Exception);
 543
 544     /*!
 545      * Remove an hypothesis previously added with AddHypothesis.
 546      */
 547     Hypothesis_Status RemoveHypothesis(in GEOM::GEOM_Object aSubObject,
 548                                        in SMESH_Hypothesis anHyp)
 549       raises (SALOME::SALOME_Exception);
 550
 551     /*!
 552      * Get the list of hypothesis added on a sub-shape
 553      */
 554     ListOfHypothesis GetHypothesisList(in GEOM::GEOM_Object aSubObject)
 555       raises (SALOME::SALOME_Exception);
 556
 557     /*!
 558      * Get the log of nodes and elements added or removed since previous
 559      * clear of the log.
 560      * @params
 561      * - clearAfterGet : log is emptied after Get (safe if concurrents access)
 562      */
 563     log_array GetLog(in boolean clearAfterGet)
 564       raises (SALOME::SALOME_Exception);
 565
 566     /*!
 567      * Clear the log of nodes and elements added or removed since previous
 568      * clear. Must be used immediately after GetLog if clearAfterGet is false.
 569      */
 570     void ClearLog()
 571       raises (SALOME::SALOME_Exception);
 572
 573     /*!
 574      * Toggle auto color mode on the object.
 575      * @params
 576      * - theAutoColor : flag which toggles auto color mode.
 577      */
 578     void SetAutoColor(in boolean theAutoColor)
 579       raises (SALOME::SALOME_Exception);
 580
 581     /*!
 582      * Get flag of object's auto color mode.
 583      */
 584     boolean GetAutoColor()
 585       raises (SALOME::SALOME_Exception);
 586
 587     /*!
 588      * Get the internal Id
 589      */
 590     long GetId();
 591
 592     /*!
 593      * Obtain instance of SMESH_MeshEditor
 594      */
 595     SMESH_MeshEditor GetMeshEditor()
 596       raises (SALOME::SALOME_Exception);
 597
 598     /*!
 599      * Return SMESH_MeshEditor that would not modify the mesh but
 600      * fill MeshPreviewStruct
 601      */
 602     SMESH_MeshEditor GetMeshEditPreviewer()
 603       raises (SALOME::SALOME_Exception);
 604
 605     /*!
 606      * Return true if the mesh has been edited since a total re-compute
 607      * and those modifications may prevent successful partial re-compute
 608      */
 609     boolean HasModificationsToDiscard()
 610       raises (SALOME::SALOME_Exception);
 611
 612     /*! Check group names for duplications.
 613      *  Consider maximum group name length stored in MED file.
 614      */
 615     boolean HasDuplicatedGroupNamesMED();
 616
 617     /*!
 618      * Export a Mesh to MED file.
 619      * @params
 620      * - fileName : name of the MED file
 621      * - auto_groups : boolean parameter for creating/not creating
 622      *                 the groups Group_On_All_Nodes, Group_On_All_Faces, ... ;
 623      *                 the typical use is auto_groups=false.
 624      * - overwrite : boolean parameter for overwriting/not overwriting the file, if it exists
 625      * - minor : define the minor version of MED file format.
 626      *           The minor must be between 0 and the current minor version of MED file library.
 627      *           If minor is equal to -1, the minor version is not changed (default).
 628      *           The major version cannot be changed.
 629      * - autoDimension : if @c true, a space dimension of a MED mesh can be either
 630      *         - 1D if all mesh nodes lie on OX coordinate axis, or
 631      *         - 2D if all mesh nodes lie on XOY coordinate plane, or
 632      *         - 3D in the rest cases.
 633      *         If @a autoDimension is @c false, the space dimension is always 3.
 634      */
 635     void ExportMED( in string      fileName,
 636                     in boolean     auto_groups,
 637                     in long        minor,
 638                     in boolean     overwrite,
 639                     in boolean     autoDimension) raises (SALOME::SALOME_Exception);
 640
 641     /*!
 642      * Export a [part of] Mesh into a MED file
 643      * @params
 644      * - meshPart : a part of mesh to store
 645      * - fileName : name of the MED file
 646      * - overwrite : boolean parameter for overwriting/not overwriting the file, if it exists
 647      * - minor : define the minor version (y, where version is x.y.z) of MED file format.
 648      *           The minor must be between 0 and the current minor version of MED file library.
 649      *           If minor is equal to -1, the minor version is not changed (default).
 650      *           The major version (x, where version is x.y.z) cannot be changed.
 651      * - autoDimension : if @c True, a space dimension for export is defined by mesh
 652      *                 configuration; for example a planar mesh lying on XOY plane
 653      *                 will be exported as a mesh in 2D space.
 654      *                 If @a autoDimension == @c False, the space dimension is 3.
 655      * - fields : list of GEOM fields defined on the shape to mesh.
 656      * - geomAssocFields : each character of this string means a need to export a
 657      *         corresponding field; correspondence between fields and characters is following:
 658      *         - 'v' stands for _vertices_ field;
 659      *         - 'e' stands for _edges_ field;
 660      *         - 'f' stands for _faces_ field;
 661      *         - 's' stands for _solids_ field.
 662      */
 663     void ExportPartToMED( in SMESH_IDSource     meshPart,
 664                           in string             fileName,
 665                           in boolean            auto_groups,
 666                           in long               minor,
 667                           in boolean            overwrite,
 668                           in boolean            autoDimension,
 669                           in GEOM::ListOfFields fields,
 670                           in string             geomAssocFields ) raises (SALOME::SALOME_Exception);
 671
 672     /*!
 673      * Export Mesh to SAUV formatted file
 674      * Write a temporary med file and use med2sauv
 675      */
 676     void ExportSAUV( in string file, in boolean auto_groups )
 677       raises (SALOME::SALOME_Exception);
 678
 679     /*!
 680      * Return string representation of a MED file version comprising nbDigits
 681      */
 682     string GetVersionString(in long minor, in short nbDigits);
 683
 684     /*!
 685      * Export Mesh to different Formats
 686      * (UNV supported version is I-DEAS 10)
 687      */
 688     void ExportDAT( in string file ) raises (SALOME::SALOME_Exception);
 689     void ExportUNV( in string file ) raises (SALOME::SALOME_Exception);
 690     void ExportSTL( in string  file,
 691                     in boolean isascii ) raises (SALOME::SALOME_Exception);
 692     void ExportCGNS( in SMESH_IDSource meshPart,
 693                      in string         file,
 694                      in boolean        overwrite,
 695                      in boolean        groupElemsByType) raises (SALOME::SALOME_Exception);
 696     void ExportGMF( in SMESH_IDSource  meshPart,
 697                     in string          file,
 698                     in boolean         withRequiredGroups) raises (SALOME::SALOME_Exception);
 699     void ExportPartToDAT( in SMESH_IDSource meshPart,
 700                           in string         file ) raises (SALOME::SALOME_Exception);
 701     void ExportPartToUNV( in SMESH_IDSource meshPart,
 702                           in string         file ) raises (SALOME::SALOME_Exception);
 703     void ExportPartToSTL( in SMESH_IDSource meshPart,
 704                           in string         file,
 705                           in boolean        isascii ) raises (SALOME::SALOME_Exception);
 706     /*!
 707      * Return computation progress [0.,1]
 708      */
 709     double GetComputeProgress();
 710
 711     /*!
 712      * Get information about mesh contents
 713      */
 714     long NbNodes()
 715       raises (SALOME::SALOME_Exception);
 716
 717     long NbElements()
 718       raises (SALOME::SALOME_Exception);
 719
 720     long Nb0DElements()
 721       raises (SALOME::SALOME_Exception);
 722
 723     long NbBalls()
 724       raises (SALOME::SALOME_Exception);
 725
 726     long NbEdges()
 727       raises (SALOME::SALOME_Exception);
 728
 729     long NbEdgesOfOrder(in ElementOrder order)
 730       raises (SALOME::SALOME_Exception);
 731
 732     long NbFaces()
 733       raises (SALOME::SALOME_Exception);
 734
 735     long NbFacesOfOrder(in ElementOrder order)
 736       raises (SALOME::SALOME_Exception);
 737
 738     long NbTriangles()
 739       raises (SALOME::SALOME_Exception);
 740
 741     long NbTrianglesOfOrder(in ElementOrder order)
 742       raises (SALOME::SALOME_Exception);
 743
 744     long NbBiQuadTriangles()
 745       raises (SALOME::SALOME_Exception);
 746
 747     long NbQuadrangles()
 748       raises (SALOME::SALOME_Exception);
 749
 750     long NbQuadranglesOfOrder(in ElementOrder order)
 751       raises (SALOME::SALOME_Exception);
 752
 753     long NbBiQuadQuadrangles()
 754       raises (SALOME::SALOME_Exception);
 755
 756     long NbPolygons()
 757       raises (SALOME::SALOME_Exception);
 758
 759     long NbPolygonsOfOrder(in ElementOrder order)
 760       raises (SALOME::SALOME_Exception);
 761
 762     long NbVolumes()
 763       raises (SALOME::SALOME_Exception);
 764
 765     long NbVolumesOfOrder(in ElementOrder order)
 766       raises (SALOME::SALOME_Exception);
 767
 768     long NbTetras()
 769       raises (SALOME::SALOME_Exception);
 770
 771     long NbTetrasOfOrder(in ElementOrder order)
 772       raises (SALOME::SALOME_Exception);
 773
 774     long NbHexas()
 775       raises (SALOME::SALOME_Exception);
 776
 777     long NbHexasOfOrder(in ElementOrder order)
 778       raises (SALOME::SALOME_Exception);
 779
 780     long NbTriQuadraticHexas()
 781       raises (SALOME::SALOME_Exception);
 782
 783     long NbPyramids()
 784       raises (SALOME::SALOME_Exception);
 785
 786     long NbPyramidsOfOrder(in ElementOrder order)
 787       raises (SALOME::SALOME_Exception);
 788
 789     long NbPrisms()
 790       raises (SALOME::SALOME_Exception);
 791
 792     long NbPrismsOfOrder(in ElementOrder order)
 793       raises (SALOME::SALOME_Exception);
 794
 795     long NbHexagonalPrisms()
 796       raises (SALOME::SALOME_Exception);
 797
 798     long NbPolyhedrons()
 799       raises (SALOME::SALOME_Exception);
 800
 801     long NbSubMesh()
 802       raises (SALOME::SALOME_Exception);
 803
 804     long_array GetElementsId()
 805       raises (SALOME::SALOME_Exception);
 806
 807     long_array GetElementsByType( in ElementType theType )
 808       raises (SALOME::SALOME_Exception);
 809
 810     long_array GetNodesId()
 811       raises (SALOME::SALOME_Exception);
 812
 813     /*!
 814      * Returns type of mesh element
 815      */
 816     ElementType GetElementType( in long id, in boolean iselem )
 817       raises (SALOME::SALOME_Exception);
 818
 819     EntityType GetElementGeomType( in long id )
 820       raises (SALOME::SALOME_Exception);
 821
 822     GeometryType GetElementShape( in long id )
 823       raises (SALOME::SALOME_Exception);
 824
 825     long_array GetSubMeshElementsId(in long ShapeID)
 826       raises (SALOME::SALOME_Exception);
 827
 828     long_array GetSubMeshNodesId(in long ShapeID, in boolean all )
 829       raises (SALOME::SALOME_Exception);
 830
 831     ElementType GetSubMeshElementType(in long ShapeID)
 832       raises (SALOME::SALOME_Exception);
 833
 834
 835     /*!
 836      * Methods to set meshing order of submeshes
 837      */
 838
 839     /*!
 840      * \brief Return \c true if a meshing order not yet set for a concurrent sub-mesh
 841      */
 842     boolean IsUnorderedSubMesh(in long submeshID);
 843
 844     /*!
 845      * \brief Return submesh objects list in meshing order
 846      */
 847     submesh_array_array GetMeshOrder();
 848
 849     /*!
 850      * \brief Set submesh object order
 851      */
 852     boolean SetMeshOrder(in submesh_array_array theSubMeshArray);
 853
 854
 855     /*!
 856      * Get mesh description
 857      */
 858     string Dump();
 859
 860     /*!
 861      * Get mesh pointer
 862      */
 863     long long GetMeshPtr();
 864
 865     /*!
 866      * Get XYZ coordinates of node as list of double
 867      * If there is not node for given ID - returns empty list
 868      */
 869     double_array GetNodeXYZ(in long id);
 870
 871     /*!
 872      * For given node returns list of IDs of inverse elements
 873      * If there is not node for given ID - returns empty list
 874      */
 875     long_array GetNodeInverseElements(in long id);
 876
 877     /*!
 878      * \brief Return position of a node on shape
 879      */
 880     NodePosition GetNodePosition(in long NodeID);
 881
 882     /*!
 883      * \brief Return position of an element on shape
 884      */
 885     ElementPosition GetElementPosition(in long ElemID);
 886
 887     /*!
 888      * If given element is node returns IDs of shape from position
 889      * If there is not node for given ID - returns -1
 890      */
 891     long GetShapeID(in long id);
 892
 893     /*!
 894      * For given element returns ID of result shape after
 895      * ::FindShape() from SMESH_MeshEditor
 896      * If there is not element for given ID - returns -1
 897      */
 898     long GetShapeIDForElem(in long id);
 899
 900     /*!
 901      * Returns number of nodes for given element
 902      * If there is not element for given ID - returns -1
 903      */
 904     long GetElemNbNodes(in long id);
 905
 906     /*!
 907      * Returns IDs of nodes of given element
 908      */
 909     long_array GetElemNodes(in long id);
 910
 911     /*!
 912      * Returns ID of node by given index for given element
 913      * If there is not element for given ID - returns -1
 914      * If there is not node for given index - returns -2
 915      */
 916     long GetElemNode(in long id, in long index);
 917
 918     /*!
 919      * Returns true if given node is medium node
 920      * in given quadratic element
 921      */
 922     boolean IsMediumNode(in long ide, in long idn);
 923
 924     /*!
 925      * Returns true if given node is medium node
 926      * in one of quadratic elements
 927      */
 928     boolean IsMediumNodeOfAnyElem(in long idn, in ElementType elem_type);
 929
 930     /*!
 931      * Returns number of edges for given element
 932      */
 933     long ElemNbEdges(in long id);
 934
 935     /*!
 936      * Returns number of faces for given element
 937      */
 938     long ElemNbFaces(in long id);
 939
 940     /*!
 941      * Returns nodes of given face (counted from zero) for given volumic element.
 942      */
 943     long_array GetElemFaceNodes(in long elemId, in short faceIndex);
 944
 945     /*!
 946      * Returns three components of normal of given mesh face (or an empty array in KO case)
 947      */
 948     double_array GetFaceNormal(in long faceId, in boolean normalized);
 949
 950     /*!
 951      * Returns an element based on all given nodes.
 952      */
 953     long FindElementByNodes(in long_array nodes);
 954
 955     /*!
 956      * Return elements including all given nodes.
 957      */
 958     long_array GetElementsByNodes(in long_array nodes, in ElementType elem_type);
 959
 960     /*!
 961      * Returns true if given element is polygon
 962      */
 963     boolean IsPoly(in long id);
 964
 965     /*!
 966      * Returns true if given element is quadratic
 967      */
 968     boolean IsQuadratic(in long id);
 969
 970     /*!
 971      * Returns diameter of a ball discrete element or zero in case of an invalid \a id
 972      */
 973     double GetBallDiameter(in long id);
 974
 975     /*!
 976      * Returns XYZ coordinates of bary center for given element
 977      * as list of double
 978      * If there is not element for given ID - returns empty list
 979      */
 980     double_array BaryCenter(in long id);
 981
 982     /*! Gets information about imported MED file */
 983     MedFileInfo GetMEDFileInfo();
 984
 985     /*!
 986      *  Sets list of notebook variables used for Mesh operations separated by ":" symbol
 987      *  \param theParameters is a string containing the notebook variables
 988      */
 989     void SetParameters (in string theParameters);
 990
 991     /*!
 992      *  Returns list of notebook variables used for Mesh operations separated by ":" symbol
 993      */
 994     string GetParameters();
 995
 996     /*!
 997      *  Returns list of notebook variables used for last Mesh operation
 998      */
 999     string_array GetLastParameters();
1000   };
1001
1002   interface SMESH_subMesh : SMESH_IDSource
1003   {
1004     /*!
1005      *
1006      */
1007     long GetNumberOfElements()
1008       raises (SALOME::SALOME_Exception);
1009
1010     /*!
1011      *
1012      */
1013     long GetNumberOfNodes( in boolean all )
1014       raises (SALOME::SALOME_Exception);
1015
1016     /*!
1017      *
1018      */
1019     long_array GetElementsId()
1020       raises (SALOME::SALOME_Exception);
1021
1022     /*!
1023      *
1024      */
1025     long_array GetElementsByType( in ElementType theType )
1026       raises (SALOME::SALOME_Exception);
1027
1028     /*!
1029      * Returns type of mesh element (same as SMESH_Mesh::GetElementType() )
1030      */
1031     ElementType GetElementType( in long id, in boolean iselem )
1032       raises (SALOME::SALOME_Exception);
1033
1034     /*!
1035      *
1036      */
1037     long_array GetNodesId()
1038       raises (SALOME::SALOME_Exception);
1039
1040     /*!
1041      * Get geom shape the submesh is dedicated to
1042      */
1043     GEOM::GEOM_Object GetSubShape()
1044       raises (SALOME::SALOME_Exception);
1045
1046     /*!
1047      * Get SMESH_Mesh which stores nodes coordinates & elements definition
1048      */
1049     SMESH_Mesh GetFather()
1050       raises (SALOME::SALOME_Exception);
1051
1052     /*!
1053      * Get the internal Id
1054      */
1055     long GetId();
1056   };
1057
1058 };
1059
1060 #endif