idl/SMESH_Mesh.idl

   1 // Copyright (C) 2007-2016  CEA/DEN, EDF R&D, OPEN CASCADE
   2 //
   3 // Copyright (C) 2003-2007  OPEN CASCADE, EADS/CCR, LIP6, CEA/DEN,
   4 // CEDRAT, EDF R&D, LEG, PRINCIPIA R&D, BUREAU VERITAS
   5 //
   6 // This library is free software; you can redistribute it and/or
   7 // modify it under the terms of the GNU Lesser General Public
   8 // License as published by the Free Software Foundation; either
   9 // version 2.1 of the License, or (at your option) any later version.
  10 //
  11 // This library is distributed in the hope that it will be useful,
  12 // but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 // MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14 // Lesser General Public License for more details.
  15 //
  16 // You should have received a copy of the GNU Lesser General Public
  17 // License along with this library; if not, write to the Free Software
  18 // Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
  19 //
  20 // See http://www.salome-platform.org/ or email : webmaster.salome@opencascade.com
  21 //
  22
  23 //  File   : SMESH_Mesh.idl
  24 //  Author : Paul RASCLE, EDF
  25 //
  26 #ifndef _SMESH_MESH_IDL_
  27 #define _SMESH_MESH_IDL_
  28
  29 #include "SALOME_Exception.idl"
  30 #include "SALOME_GenericObj.idl"
  31 #include "GEOM_Gen.idl"
  32
  33 module SMESH
  34 {
  35   interface SMESH_Hypothesis;
  36   typedef sequence<SMESH_Hypothesis> ListOfHypothesis;
  37   interface SMESH_GroupBase;
  38   typedef sequence<SMESH_GroupBase> ListOfGroups;
  39   interface SMESH_IDSource;
  40   typedef sequence<SMESH_IDSource> ListOfIDSources;
  41
  42   typedef sequence<double    > double_array ;
  43   typedef sequence<long      > long_array ;
  44   typedef sequence<string    > string_array ;
  45   typedef sequence<long_array> array_of_long_array ;
  46
  47   enum log_command
  48     {
  49       ADD_NODE,
  50       ADD_EDGE,
  51       ADD_TRIANGLE,
  52       ADD_QUADRANGLE,
  53       ADD_POLYGON,
  54       ADD_TETRAHEDRON,
  55       ADD_PYRAMID,
  56       ADD_PRISM,
  57       ADD_HEXAHEDRON,
  58       ADD_POLYHEDRON,
  59       REMOVE_NODE,
  60       REMOVE_ELEMENT,
  61       MOVE_NODE,
  62       CHANGE_ELEMENT_NODES,
  63       CHANGE_POLYHEDRON_NODES,
  64       RENUMBER,
  65       CLEAR_MESH,
  66       ADD_QUADEDGE,
  67       ADD_QUADTRIANGLE,
  68       ADD_QUADQUADRANGLE,
  69       ADD_QUADPOLYGON,
  70       ADD_QUADTETRAHEDRON,
  71       ADD_QUADPYRAMID,
  72       ADD_QUADPENTAHEDRON,
  73       ADD_QUADHEXAHEDRON,
  74       ADD_ELEM0D,
  75       ADD_BIQUAD_TRIANGLE,
  76       ADD_BIQUAD_QUADRANGLE,
  77       ADD_TRIQUAD_HEXA,
  78       ADD_HEXAGONAL_PRISM,
  79       ADD_BALL
  80     };
  81
  82   struct log_block
  83   {
  84     long commandType;
  85     long number;
  86     double_array coords;
  87     long_array indexes;
  88   };
  89   typedef sequence<log_block> log_array;
  90
  91   struct PointStruct { double x;
  92                        double y;
  93                        double z; };
  94
  95   typedef sequence<PointStruct> nodes_array;
  96
  97   struct DirStruct   { PointStruct PS; };          // analog to OCCT gp_Vec
  98
  99   struct AxisStruct  { double x;
 100                        double y;
 101                        double z;
 102                        double vx;
 103                        double vy;
 104                        double vz; };
 105   /*!
 106    * Node location on a shape
 107    */
 108   struct NodePosition {
 109     long             shapeID;
 110     GEOM::shape_type shapeType;
 111     double_array     params; // [U] on EDGE, [U,V] on FACE, [] on the rest shapes
 112   };
 113
 114   /*!
 115    * Element location on a shape
 116    */
 117   struct ElementPosition {
 118     long             shapeID;
 119     GEOM::shape_type shapeType;
 120   };
 121
 122   /*!
 123    * Enumeration for element type, like in SMDS
 124    */
 125   enum ElementType
 126   {
 127     ALL,
 128     NODE,
 129     EDGE,
 130     FACE,
 131     VOLUME,
 132     ELEM0D,
 133     BALL,
 134     NB_ELEMENT_TYPES
 135   };
 136   typedef sequence<ElementType> array_of_ElementType;
 137
 138   /*!
 139    * Enumeration for element geometry type, like SMDSAbs_GeometryType in SMDSAbs_ElementType.hxx
 140    */
 141   enum GeometryType
 142   {
 143     Geom_POINT,
 144     Geom_EDGE,
 145     Geom_TRIANGLE,
 146     Geom_QUADRANGLE, // when a new GeometryType is added, please
 147     Geom_POLYGON,    // update a corresponding list in SMESH_2smeshpy.cxx, ln 665
 148     Geom_TETRA,
 149     Geom_PYRAMID,
 150     Geom_HEXA,
 151     Geom_PENTA,
 152     Geom_HEXAGONAL_PRISM,
 153     Geom_POLYHEDRA,
 154     Geom_BALL,
 155     Geom_LAST
 156   };
 157
 158   /*!
 159    * ElementOrder points out entities of what order are requested
 160    */
 161   enum ElementOrder {
 162     ORDER_ANY,          /*! entities of any order */
 163     ORDER_LINEAR,       /*! entities of 1st order */
 164     ORDER_QUADRATIC     /*! entities of 2nd order */
 165   };
 166
 167   /*!
 168    * Enumeration of entity type used in mesh info array,
 169    * it should be synchronised with enum SMDSAbs_EntityType
 170    */
 171   enum EntityType
 172   {
 173     Entity_Node,
 174     Entity_0D,
 175     Entity_Edge,
 176     Entity_Quad_Edge,
 177     Entity_Triangle,
 178     Entity_Quad_Triangle,
 179     Entity_BiQuad_Triangle,
 180     Entity_Quadrangle,
 181     Entity_Quad_Quadrangle,
 182     Entity_BiQuad_Quadrangle,
 183     Entity_Polygon,
 184     Entity_Quad_Polygon,
 185     Entity_Tetra,
 186     Entity_Quad_Tetra,
 187     Entity_Pyramid,
 188     Entity_Quad_Pyramid,
 189     Entity_Hexa,
 190     Entity_Quad_Hexa,
 191     Entity_TriQuad_Hexa,
 192     Entity_Penta,
 193     Entity_Quad_Penta,
 194     Entity_BiQuad_Penta,
 195     Entity_Hexagonal_Prism,
 196     Entity_Polyhedra,
 197     Entity_Quad_Polyhedra,
 198     Entity_Ball,
 199     Entity_Last
 200   };
 201
 202   /*!
 203    * Enumeration for hypothesis status (used by AddHypothesis() and RemoveHypothesis() methods)
 204    */
 205   enum Hypothesis_Status // in the order of severity
 206   {
 207     HYP_OK,
 208     HYP_MISSING,      // algo misses a hypothesis
 209     HYP_CONCURENT,    // several applicable hypotheses
 210     HYP_BAD_PARAMETER,// hypothesis has a bad parameter value
 211     HYP_HIDDEN_ALGO,  // an algo is hidden by an upper dim algo generating all-dim elements
 212     HYP_HIDING_ALGO,  // an algo hides lower dim algos by generating all-dim elements
 213     HYP_UNKNOWN_FATAL,//  --- all statuses below should be considered as fatal
 214                       //      for Add/RemoveHypothesis operations
 215     HYP_INCOMPATIBLE, // hypothesis does not fit algo
 216     HYP_NOTCONFORM,   // not conform mesh is produced appling a hypothesis
 217     HYP_ALREADY_EXIST,// such hypothesis already exist
 218     HYP_BAD_DIM,      // bad dimension
 219     HYP_BAD_SUBSHAPE, // shape is neither the main one, nor its sub-shape, nor a group
 220     HYP_BAD_GEOMETRY, // geometry mismatches algorithm's expectation
 221     HYP_NEED_SHAPE,   // algorithm can work on shape only
 222     HYP_INCOMPAT_HYPS // several additional hypotheses are incompatible one with other
 223   };
 224
 225   /*!
 226    * Enumeration for mesh read status (used by SMESH_Gen::CreateMeshesFrom*() methods)
 227    */
 228   enum DriverMED_ReadStatus // in the order of severity
 229   {
 230     DRS_OK,
 231     DRS_EMPTY,          // a file contains no mesh with the given name
 232     DRS_WARN_RENUMBER,  // a MED file has overlapped ranges of element numbers,
 233                         // so the numbers from the file are ignored
 234     DRS_WARN_SKIP_ELEM, // some elements were skipped due to incorrect file data
 235     DRS_WARN_DESCENDING, // some elements were skipped due to descending connectivity
 236     DRS_FAIL            // general failure (exception etc.)
 237   };
 238
 239   /*!
 240    * Enumeration for ExportToMED*()
 241    */
 242   enum MED_VERSION
 243   {
 244     MED_V2_1,
 245     MED_V2_2
 246   };
 247
 248   /*!
 249    * \brief A structure containing information about MED file
 250    */
 251   struct MedFileInfo
 252   {
 253     string fileName; //!< name of file
 254     long   fileSize; //!< size of file
 255     long   major, minor, release; //!< MED file version
 256   };
 257
 258   /*!
 259    * Enumeration for CreateDimGroup()
 260    */
 261   enum NB_COMMON_NODES_ENUM
 262   {
 263     ALL_NODES, MAIN, AT_LEAST_ONE, MAJORITY
 264   };
 265
 266   /*!
 267    * Auxiliary flags for advanced extrusion.
 268    * BOUNDARY: create or not boundary for result of extrusion
 269    * SEW:      try to use existing nodes or create new nodes in any case
 270    */
 271   const long EXTRUSION_FLAG_BOUNDARY = 1;
 272   const long EXTRUSION_FLAG_SEW = 2;
 273
 274   /*!
 275    * Structure used in mesh edit preview data (MeshPreviewStruct)
 276    */
 277   struct ElementSubType { ElementType SMDS_ElementType;
 278                           boolean     isPoly;
 279                           long        nbNodesInElement; };
 280
 281   typedef sequence<ElementSubType> types_array;
 282
 283   /*!
 284    * Structure containing mesh edit preview data
 285    */
 286   struct MeshPreviewStruct { nodes_array nodesXYZ;
 287                              long_array  elementConnectivities;
 288                              types_array elementTypes; };
 289
 290   interface SMESH_Mesh;
 291
 292   interface SMESH_IDSource : SALOME::GenericObj
 293   {
 294     /*!
 295      * Returns a sequence of all element IDs
 296      */
 297     long_array GetIDs();
 298
 299     /*!
 300      * Returns number of mesh elements of each \a EntityType
 301      * @return array of number of elements per \a EntityType
 302      */
 303     long_array GetMeshInfo();
 304
 305     /*!
 306      * Returns number of mesh elements of each \a ElementType
 307      * @return array of number of elements per \a ElementType
 308      */
 309     long_array GetNbElementsByType();
 310
 311     /*!
 312      * Returns types of elements it contains.
 313      * It's empty if the SMESH_IDSource contains no IDs
 314      */
 315     array_of_ElementType GetTypes();
 316
 317     /*!
 318      * Returns the mesh
 319      */
 320     SMESH_Mesh GetMesh();
 321
 322     /*!
 323      * Returns false if GetMeshInfo() returns incorrect information that may
 324      * happen if mesh data is not yet fully loaded from the file of study.
 325      */
 326     boolean IsMeshInfoCorrect();
 327
 328     /*!
 329      * Returns mesh unstructed grid information.
 330      */
 331     SALOMEDS::TMPFile GetVtkUgStream();
 332   };
 333
 334   interface SMESH_Group;
 335   interface SMESH_GroupOnGeom;
 336   interface Filter;
 337   interface SMESH_GroupOnFilter;
 338   interface SMESH_subMesh;
 339   interface SMESH_MeshEditor;
 340
 341   typedef sequence<SMESH_subMesh>     submesh_array;
 342   typedef sequence<submesh_array>     submesh_array_array;
 343
 344   interface SMESH_Mesh : SALOME::GenericObj, SMESH_IDSource
 345   {
 346     /*!
 347      * Return true if there is a geometry to be meshed
 348      */
 349     boolean HasShapeToMesh()
 350       raises (SALOME::SALOME_Exception);
 351
 352     /*!
 353      * Get geom shape to mesh. A result should not be nil. Use HasShapeToMesh()
 354      * to know if a returned shape
 355      */
 356     GEOM::GEOM_Object GetShapeToMesh()
 357       raises (SALOME::SALOME_Exception);
 358
 359     /*!
 360      * Return false if the mesh is not yet fully loaded from the study file
 361      */
 362     boolean IsLoaded()
 363       raises (SALOME::SALOME_Exception);
 364
 365     /*!
 366      * Load full mesh data from the study file
 367      */
 368     void Load()
 369       raises (SALOME::SALOME_Exception);
 370
 371     /*!
 372      * Remove all nodes and elements
 373      */
 374     void Clear()
 375       raises (SALOME::SALOME_Exception);
 376
 377     /*!
 378      *  Get the list of sub-meshes existing in the mesh
 379      */
 380     submesh_array GetSubMeshes()
 381       raises (SALOME::SALOME_Exception);
 382
 383     /*!
 384      * Remove all nodes and elements of submesh
 385      */
 386     void ClearSubMesh(in long ShapeID)
 387       raises (SALOME::SALOME_Exception);
 388
 389     /*!
 390      * Get the subMesh object associated to a Sub-shape. The subMesh object
 391      * gives access to nodes and elements IDs.
 392      * SubMesh will be used instead of Sub-shape in a next idl version to
 393      * address a specific subMesh...
 394      */
 395     SMESH_subMesh GetSubMesh(in GEOM::GEOM_Object aSubObject, in string name)
 396       raises (SALOME::SALOME_Exception);
 397
 398     /*!
 399      * Remove a submesh
 400      */
 401     void RemoveSubMesh(in SMESH_subMesh aSubMesh)
 402       raises (SALOME::SALOME_Exception);
 403
 404
 405     /*!
 406      * Create a group
 407      */
 408     SMESH_Group CreateGroup( in ElementType elem_type,
 409                              in string      name )
 410       raises (SALOME::SALOME_Exception);
 411
 412     /*!
 413      * Create a group from geometry
 414      */
 415     SMESH_GroupOnGeom CreateGroupFromGEOM( in ElementType       elemType,
 416                                            in string            name,
 417                                            in GEOM::GEOM_Object geomObject )
 418       raises (SALOME::SALOME_Exception);
 419
 420     /*!
 421      * Create a group from filter
 422      */
 423     SMESH_GroupOnFilter CreateGroupFromFilter( in ElementType   elemType,
 424                                                in string        name,
 425                                                in SMESH::Filter filter )
 426       raises (SALOME::SALOME_Exception);
 427
 428     /*!
 429      * Remove a group
 430      */
 431     void RemoveGroup(in SMESH_GroupBase aGroup)
 432       raises (SALOME::SALOME_Exception);
 433
 434     /*!
 435      *  Remove group with its contents
 436      */
 437     void RemoveGroupWithContents( in SMESH_GroupBase aGroup )
 438       raises (SALOME::SALOME_Exception);
 439
 440     /*!
 441      *  Get the list of groups existing in the mesh
 442      */
 443     ListOfGroups GetGroups()
 444       raises (SALOME::SALOME_Exception);
 445
 446     /*!
 447      *  Get number of groups existing in the mesh
 448      */
 449     long NbGroups()
 450       raises (SALOME::SALOME_Exception);
 451
 452     /*!
 453      * Union of two groups
 454      *    New group is created. All mesh elements that are
 455      *    present in initial groups are added to the new one
 456      */
 457     SMESH_Group UnionGroups (in SMESH_GroupBase aGroup1,
 458                              in SMESH_GroupBase aGroup2,
 459                              in string          name )
 460       raises (SALOME::SALOME_Exception);
 461
 462     /*!
 463      * Union of list of groups
 464      * New group is created. All mesh elements that are
 465      * present in initial groups are added to the new one
 466      */
 467     SMESH_Group UnionListOfGroups (in ListOfGroups aListOfGroups,
 468                                    in string       name )
 469       raises (SALOME::SALOME_Exception);
 470
 471     /*!
 472      *  Intersection of two groups
 473      *  New group is created. All mesh elements that are
 474      *  present in both initial groups are added to the new one.
 475      */
 476     SMESH_Group IntersectGroups (in SMESH_GroupBase aGroup1,
 477                                  in SMESH_GroupBase aGroup2,
 478                                  in string          name )
 479       raises (SALOME::SALOME_Exception);
 480
 481     /*!
 482      *  Intersection of list of groups
 483      *  New group is created. All mesh elements that are
 484      *  present in all initial groups simultaneously are added to the new one.
 485      */
 486     SMESH_Group IntersectListOfGroups (in ListOfGroups aListOfGroups,
 487                                        in string       name)
 488       raises (SALOME::SALOME_Exception);
 489
 490     /*!
 491      *  Cut of two groups
 492      *  New group is created. All mesh elements that are present in
 493      *  main group but do not present in tool group are added to the new one
 494      */
 495     SMESH_Group CutGroups (in SMESH_GroupBase aMainGroup,
 496                            in SMESH_GroupBase aToolGroup,
 497                            in string          name )
 498       raises (SALOME::SALOME_Exception);
 499
 500     /*!
 501      *  Cut of lists of groups
 502      *  New group is created. All mesh elements that are present in
 503      *  main groups but do not present in tool groups are added to the new one
 504      */
 505     SMESH_Group CutListOfGroups (in ListOfGroups aMainGroups,
 506                                  in ListOfGroups aToolGroups,
 507                                  in string       name)
 508       raises (SALOME::SALOME_Exception);
 509
 510     /*!
 511      *  Create a group of entities basing on nodes of other groups.
 512      *  \param [in] aListOfGroups - list of either groups, sub-meshes or filters.
 513      *  \param [in] anElemType - a type of elements to include to the new group.
 514      *  \param [in] name - a name of the new group.
 515      *  \param [in] nbCommonNodes - criterion of inclusion of an element to the new group.
 516      *  \param [in] underlyingOnly - if \c True, an element is included to the
 517      *         new group provided that it is based on nodes of an element of
 518      *         \a aListOfGroups
 519      *  \return SMESH_Group - the created group
 520      */
 521     SMESH_Group CreateDimGroup( in ListOfIDSources      aListOfGroups,
 522                                 in ElementType          anElemType,
 523                                 in string               name,
 524                                 in NB_COMMON_NODES_ENUM nbCommonNodes,
 525                                 in boolean              underlyingOnly )
 526       raises (SALOME::SALOME_Exception);
 527
 528     /*!
 529      * Convert group on geometry or on filter into standalone group
 530      */
 531     SMESH_Group ConvertToStandalone( in SMESH_GroupBase theGroupOn )
 532       raises (SALOME::SALOME_Exception);
 533
 534     /*!
 535      * Add hypothesis to the mesh, under a particular sub-shape
 536      * (or the main shape itself)
 537      * This method is only used to prepare the build of the mesh and store
 538      * the algorithms and associated parameters.
 539      * Actual job of meshing the shape is done by SMESH_Gen::Compute()
 540      * @params
 541      * - aSubObject : sub-shape obtained by a shape explode in GEOM
 542      *   (or main shape)
 543      * - anHyp : an hypothesis object
 544      * @return
 545      * - An enum item explaining what's up
 546      * - anErrorText: an optional textual description of a problem (if any)
 547      */
 548     Hypothesis_Status AddHypothesis(in GEOM::GEOM_Object aSubObject,
 549                                     in SMESH_Hypothesis  anHyp,
 550                                     out string           anErrorText)
 551       raises (SALOME::SALOME_Exception);
 552
 553     /*!
 554      * Remove an hypothesis previouly added with AddHypothesis.
 555      */
 556     Hypothesis_Status RemoveHypothesis(in GEOM::GEOM_Object aSubObject,
 557                                        in SMESH_Hypothesis anHyp)
 558       raises (SALOME::SALOME_Exception);
 559
 560     /*!
 561      * Get the list of hypothesis added on a sub-shape
 562      */
 563     ListOfHypothesis GetHypothesisList(in GEOM::GEOM_Object aSubObject)
 564       raises (SALOME::SALOME_Exception);
 565
 566     /*!
 567      * Get the log of nodes and elements added or removed since previous
 568      * clear of the log.
 569      * @params
 570      * - clearAfterGet : log is emptied after Get (safe if concurrents access)
 571      */
 572     log_array GetLog(in boolean clearAfterGet)
 573       raises (SALOME::SALOME_Exception);
 574
 575     /*!
 576      * Clear the log of nodes and elements added or removed since previous
 577      * clear. Must be used immediately after GetLog if clearAfterGet is false.
 578      */
 579     void ClearLog()
 580       raises (SALOME::SALOME_Exception);
 581
 582     /*!
 583      * Toggle auto color mode on the object.
 584      * @params
 585      * - theAutoColor : flag which toggles auto color mode.
 586      */
 587     void SetAutoColor(in boolean theAutoColor)
 588       raises (SALOME::SALOME_Exception);
 589
 590     /*!
 591      * Get flag of object's auto color mode.
 592      */
 593     boolean GetAutoColor()
 594       raises (SALOME::SALOME_Exception);
 595
 596     /*!
 597      * Get the internal Id
 598      */
 599     long GetId();
 600
 601     /*!
 602      * Get the study Id
 603      */
 604     long GetStudyId();
 605
 606     /*!
 607      * Obtain instance of SMESH_MeshEditor
 608      */
 609     SMESH_MeshEditor GetMeshEditor()
 610       raises (SALOME::SALOME_Exception);
 611
 612     /*!
 613      * Return SMESH_MeshEditor that would not modify the mesh but
 614      * fill MeshPreviewStruct
 615      */
 616     SMESH_MeshEditor GetMeshEditPreviewer()
 617       raises (SALOME::SALOME_Exception);
 618
 619     /*!
 620      * Return true if the mesh has been edited since a total re-compute
 621      * and those modifications may prevent successful partial re-compute
 622      */
 623     boolean HasModificationsToDiscard()
 624       raises (SALOME::SALOME_Exception);
 625
 626     /*! Check group names for duplications.
 627      *  Consider maximum group name length stored in MED file.
 628      */
 629     boolean HasDuplicatedGroupNamesMED();
 630
 631     /*!
 632      * Export Mesh to a MED Format file
 633      * @params
 634      * - file : name of the MED file
 635      * - auto_groups : boolean parameter for creating/not creating
 636      *                 the groups Group_On_All_Nodes, Group_On_All_Faces, ... ;
 637      *                 the typical use is auto_groups=false.
 638      * - version : defines the version of format of MED file, that will be created
 639      * - overwrite : boolean parameter for overwriting/not overwriting the file, if it exists
 640      * - autoDimension : if @c true, a space dimension of a MED mesh can be either
 641      *         - 1D if all mesh nodes lie on OX coordinate axis, or
 642      *         - 2D if all mesh nodes lie on XOY coordinate plane, or
 643      *         - 3D in the rest cases.
 644      *         If @a autoDimension is @c false, the space dimension is always 3.
 645      */
 646     void ExportToMEDX( in string      file,
 647                        in boolean     auto_groups,
 648                        in MED_VERSION version,
 649                        in boolean     overwrite,
 650                        in boolean     autoDimension) raises (SALOME::SALOME_Exception);
 651
 652     /*!
 653      * Export a [part of] Mesh into a MED file
 654      * @params
 655      * - meshPart : a part of mesh to store
 656      * - file : name of the MED file
 657      * - version : define the version of format of MED file, that will be created
 658      * - overwrite : boolean parameter for overwriting/not overwriting the file, if it exists
 659      * - autoDimension : if @c True, a space dimension for export is defined by mesh
 660      *                 configuration; for example a planar mesh lying on XOY plane
 661      *                 will be exported as a mesh in 2D space.
 662      *                 If @a autoDimension == @c False, the space dimension is 3.
 663      * - fields : list of GEOM fields defined on the shape to mesh.
 664      * - geomAssocFields : each character of this string means a need to export a
 665      *         corresponding field; correspondence between fields and characters is following:
 666      *         - 'v' stands for _vertices_ field;
 667      *         - 'e' stands for _edges_ field;
 668      *         - 'f' stands for _faces_ field;
 669      *         - 's' stands for _solids_ field.
 670      */
 671     void ExportPartToMED( in SMESH_IDSource     meshPart,
 672                           in string             file,
 673                           in boolean            auto_groups,
 674                           in MED_VERSION        version,
 675                           in boolean            overwrite,
 676                           in boolean            autoDimension,
 677                           in GEOM::ListOfFields fields,
 678                           in string             geomAssocFields ) raises (SALOME::SALOME_Exception);
 679
 680     /*!
 681      * Export Mesh to a MED Format file
 682      * Works, just the same as ExportToMEDX, with overwrite parameter equal to true.
 683      * The method is kept in order to support old functionality
 684      */
 685     void ExportToMED( in string file, in boolean auto_groups, in MED_VERSION theVersion )
 686       raises (SALOME::SALOME_Exception);
 687
 688     /*!
 689      * Export Mesh to MED_V2_1 MED format
 690      * Works, just the same as ExportToMEDX with MED_VERSION parameter equal to MED_V2_1
 691      * and overwrite parameter equal to true
 692      * The method is kept in order to support old functionality
 693      */
 694     void ExportMED( in string file, in boolean auto_groups )
 695       raises (SALOME::SALOME_Exception);
 696
 697     /*!
 698      * Export Mesh to SAUV formatted file
 699      * Write a temporary med file and use med2sauv
 700      */
 701     void ExportSAUV( in string file, in boolean auto_groups )
 702       raises (SALOME::SALOME_Exception);
 703
 704     /*!
 705      * Return string representation of a MED file version comprising nbDigits
 706      */
 707     string GetVersionString(in MED_VERSION version, in short nbDigits);
 708
 709     /*!
 710      * Export Mesh to different Formats
 711      * (UNV supported version is I-DEAS 10)
 712      */
 713     void ExportDAT( in string file ) raises (SALOME::SALOME_Exception);
 714     void ExportUNV( in string file ) raises (SALOME::SALOME_Exception);
 715     void ExportSTL( in string  file,
 716                     in boolean isascii ) raises (SALOME::SALOME_Exception);
 717     void ExportCGNS( in SMESH_IDSource meshPart,
 718                      in string         file,
 719                      in boolean        overwrite,
 720                      in boolean        groupElemsByType) raises (SALOME::SALOME_Exception);
 721     void ExportGMF( in SMESH_IDSource  meshPart,
 722                     in string          file,
 723                     in boolean         withRequiredGroups) raises (SALOME::SALOME_Exception);
 724     void ExportPartToDAT( in SMESH_IDSource meshPart,
 725                           in string         file ) raises (SALOME::SALOME_Exception);
 726     void ExportPartToUNV( in SMESH_IDSource meshPart,
 727                           in string         file ) raises (SALOME::SALOME_Exception);
 728     void ExportPartToSTL( in SMESH_IDSource meshPart,
 729                           in string         file,
 730                           in boolean        isascii ) raises (SALOME::SALOME_Exception);
 731     /*!
 732      * Return computation progress [0.,1]
 733      */
 734     double GetComputeProgress();
 735
 736     /*!
 737      * Get informations about mesh contents
 738      */
 739     long NbNodes()
 740       raises (SALOME::SALOME_Exception);
 741
 742     long NbElements()
 743       raises (SALOME::SALOME_Exception);
 744
 745     long Nb0DElements()
 746       raises (SALOME::SALOME_Exception);
 747
 748     long NbBalls()
 749       raises (SALOME::SALOME_Exception);
 750
 751     long NbEdges()
 752       raises (SALOME::SALOME_Exception);
 753
 754     long NbEdgesOfOrder(in ElementOrder order)
 755       raises (SALOME::SALOME_Exception);
 756
 757     long NbFaces()
 758       raises (SALOME::SALOME_Exception);
 759
 760     long NbFacesOfOrder(in ElementOrder order)
 761       raises (SALOME::SALOME_Exception);
 762
 763     long NbTriangles()
 764       raises (SALOME::SALOME_Exception);
 765
 766     long NbTrianglesOfOrder(in ElementOrder order)
 767       raises (SALOME::SALOME_Exception);
 768
 769     long NbBiQuadTriangles()
 770       raises (SALOME::SALOME_Exception);
 771
 772     long NbQuadrangles()
 773       raises (SALOME::SALOME_Exception);
 774
 775     long NbQuadranglesOfOrder(in ElementOrder order)
 776       raises (SALOME::SALOME_Exception);
 777
 778     long NbBiQuadQuadrangles()
 779       raises (SALOME::SALOME_Exception);
 780
 781     long NbPolygons()
 782       raises (SALOME::SALOME_Exception);
 783
 784     long NbPolygonsOfOrder(in ElementOrder order)
 785       raises (SALOME::SALOME_Exception);
 786
 787     long NbVolumes()
 788       raises (SALOME::SALOME_Exception);
 789
 790     long NbVolumesOfOrder(in ElementOrder order)
 791       raises (SALOME::SALOME_Exception);
 792
 793     long NbTetras()
 794       raises (SALOME::SALOME_Exception);
 795
 796     long NbTetrasOfOrder(in ElementOrder order)
 797       raises (SALOME::SALOME_Exception);
 798
 799     long NbHexas()
 800       raises (SALOME::SALOME_Exception);
 801
 802     long NbHexasOfOrder(in ElementOrder order)
 803       raises (SALOME::SALOME_Exception);
 804
 805     long NbTriQuadraticHexas()
 806       raises (SALOME::SALOME_Exception);
 807
 808     long NbPyramids()
 809       raises (SALOME::SALOME_Exception);
 810
 811     long NbPyramidsOfOrder(in ElementOrder order)
 812       raises (SALOME::SALOME_Exception);
 813
 814     long NbPrisms()
 815       raises (SALOME::SALOME_Exception);
 816
 817     long NbPrismsOfOrder(in ElementOrder order)
 818       raises (SALOME::SALOME_Exception);
 819
 820     long NbHexagonalPrisms()
 821       raises (SALOME::SALOME_Exception);
 822
 823     long NbPolyhedrons()
 824       raises (SALOME::SALOME_Exception);
 825
 826     long NbSubMesh()
 827       raises (SALOME::SALOME_Exception);
 828
 829     long_array GetElementsId()
 830       raises (SALOME::SALOME_Exception);
 831
 832     long_array GetElementsByType( in ElementType theType )
 833       raises (SALOME::SALOME_Exception);
 834
 835     long_array GetNodesId()
 836       raises (SALOME::SALOME_Exception);
 837
 838     /*!
 839      * Returns type of mesh element
 840      */
 841     ElementType GetElementType( in long id, in boolean iselem )
 842       raises (SALOME::SALOME_Exception);
 843
 844     EntityType GetElementGeomType( in long id )
 845       raises (SALOME::SALOME_Exception);
 846
 847     GeometryType GetElementShape( in long id )
 848       raises (SALOME::SALOME_Exception);
 849
 850     long_array GetSubMeshElementsId(in long ShapeID)
 851       raises (SALOME::SALOME_Exception);
 852
 853     long_array GetSubMeshNodesId(in long ShapeID, in boolean all )
 854       raises (SALOME::SALOME_Exception);
 855
 856     ElementType GetSubMeshElementType(in long ShapeID)
 857       raises (SALOME::SALOME_Exception);
 858
 859
 860     /*!
 861      * Methods to set meshing order of submeshes
 862      */
 863
 864     /*!
 865      * \brief Return \c true if a meshing order not yet set for a concurrent sub-mesh
 866      */
 867     boolean IsUnorderedSubMesh(in long submeshID);
 868
 869     /*!
 870      * \brief Return submesh objects list in meshing order
 871      */
 872     submesh_array_array GetMeshOrder();
 873
 874     /*!
 875      * \brief Set submesh object order
 876      */
 877     boolean SetMeshOrder(in submesh_array_array theSubMeshArray);
 878
 879
 880     /*!
 881      * Get mesh description
 882      */
 883     string Dump();
 884
 885     /*!
 886      * Get mesh pointer
 887      */
 888     long long GetMeshPtr();
 889
 890     /*!
 891      * Get XYZ coordinates of node as list of double
 892      * If there is not node for given ID - returns empty list
 893      */
 894     double_array GetNodeXYZ(in long id);
 895
 896     /*!
 897      * For given node returns list of IDs of inverse elements
 898      * If there is not node for given ID - returns empty list
 899      */
 900     long_array GetNodeInverseElements(in long id);
 901
 902     /*!
 903      * \brief Return position of a node on shape
 904      */
 905     NodePosition GetNodePosition(in long NodeID);
 906
 907     /*!
 908      * \brief Return position of an element on shape
 909      */
 910     ElementPosition GetElementPosition(in long ElemID);
 911
 912     /*!
 913      * If given element is node returns IDs of shape from position
 914      * If there is not node for given ID - returns -1
 915      */
 916     long GetShapeID(in long id);
 917
 918     /*!
 919      * For given element returns ID of result shape after
 920      * ::FindShape() from SMESH_MeshEditor
 921      * If there is not element for given ID - returns -1
 922      */
 923     long GetShapeIDForElem(in long id);
 924
 925     /*!
 926      * Returns number of nodes for given element
 927      * If there is not element for given ID - returns -1
 928      */
 929     long GetElemNbNodes(in long id);
 930
 931     /*!
 932      * Returns IDs of nodes of given element
 933      */
 934     long_array GetElemNodes(in long id);
 935
 936     /*!
 937      * Returns ID of node by given index for given element
 938      * If there is not element for given ID - returns -1
 939      * If there is not node for given index - returns -2
 940      */
 941     long GetElemNode(in long id, in long index);
 942
 943     /*!
 944      * Returns true if given node is medium node
 945      * in given quadratic element
 946      */
 947     boolean IsMediumNode(in long ide, in long idn);
 948
 949     /*!
 950      * Returns true if given node is medium node
 951      * in one of quadratic elements
 952      */
 953     boolean IsMediumNodeOfAnyElem(in long idn, in ElementType elem_type);
 954
 955     /*!
 956      * Returns number of edges for given element
 957      */
 958     long ElemNbEdges(in long id);
 959
 960     /*!
 961      * Returns number of faces for given element
 962      */
 963     long ElemNbFaces(in long id);
 964
 965     /*!
 966      * Returns nodes of given face (counted from zero) for given volumic element.
 967      */
 968     long_array GetElemFaceNodes(in long elemId, in short faceIndex);
 969
 970     /*!
 971      * Returns three components of normal of given mesh face (or an empty array in KO case)
 972      */
 973     double_array GetFaceNormal(in long faceId, in boolean normalized);
 974
 975     /*!
 976      * Returns an element based on all given nodes.
 977      */
 978     long FindElementByNodes(in long_array nodes);
 979
 980     /*!
 981      * Return elements including all given nodes.
 982      */
 983     long_array GetElementsByNodes(in long_array nodes, in ElementType elem_type);
 984
 985     /*!
 986      * Returns true if given element is polygon
 987      */
 988     boolean IsPoly(in long id);
 989
 990     /*!
 991      * Returns true if given element is quadratic
 992      */
 993     boolean IsQuadratic(in long id);
 994
 995     /*!
 996      * Returns diameter of a ball discrete element or zero in case of an invalid \a id
 997      */
 998     double GetBallDiameter(in long id);
 999
1000     /*!
1001      * Returns XYZ coordinates of bary center for given element
1002      * as list of double
1003      * If there is not element for given ID - returns empty list
1004      */
1005     double_array BaryCenter(in long id);
1006
1007     /*! Gets information about imported MED file */
1008     MedFileInfo GetMEDFileInfo();
1009
1010     /*!
1011      *  Sets list of notebook variables used for Mesh operations separated by ":" symbol
1012      *  \param theParameters is a string containing the notebook variables
1013      */
1014     void SetParameters (in string theParameters);
1015
1016     /*!
1017      *  Returns list of notebook variables used for Mesh operations separated by ":" symbol
1018      */
1019     string GetParameters();
1020
1021     /*!
1022      *  Returns list of notebook variables used for last Mesh operation
1023      */
1024     string_array GetLastParameters();
1025   };
1026
1027   interface SMESH_subMesh : SALOME::GenericObj, SMESH_IDSource
1028   {
1029     /*!
1030      *
1031      */
1032     long GetNumberOfElements()
1033       raises (SALOME::SALOME_Exception);
1034
1035     /*!
1036      *
1037      */
1038     long GetNumberOfNodes( in boolean all )
1039       raises (SALOME::SALOME_Exception);
1040
1041     /*!
1042      *
1043      */
1044     long_array GetElementsId()
1045       raises (SALOME::SALOME_Exception);
1046
1047     /*!
1048      *
1049      */
1050     long_array GetElementsByType( in ElementType theType )
1051       raises (SALOME::SALOME_Exception);
1052
1053     /*!
1054      * Returns type of mesh element (same as SMESH_Mesh::GetElementType() )
1055      */
1056     ElementType GetElementType( in long id, in boolean iselem )
1057       raises (SALOME::SALOME_Exception);
1058
1059     /*!
1060      *
1061      */
1062     long_array GetNodesId()
1063       raises (SALOME::SALOME_Exception);
1064
1065     /*!
1066      * Get geom shape the submesh is dedicated to
1067      */
1068     GEOM::GEOM_Object GetSubShape()
1069       raises (SALOME::SALOME_Exception);
1070
1071     /*!
1072      * Get SMESH_Mesh which stores nodes coordinates & elements definition
1073      */
1074     SMESH_Mesh GetFather()
1075       raises (SALOME::SALOME_Exception);
1076
1077     /*!
1078      * Get the internal Id
1079      */
1080     long GetId();
1081   };
1082
1083 };
1084
1085 #endif