idl/SMESH_Mesh.idl

   1 // Copyright (C) 2007-2014  CEA/DEN, EDF R&D, OPEN CASCADE
   2 //
   3 // Copyright (C) 2003-2007  OPEN CASCADE, EADS/CCR, LIP6, CEA/DEN,
   4 // CEDRAT, EDF R&D, LEG, PRINCIPIA R&D, BUREAU VERITAS
   5 //
   6 // This library is free software; you can redistribute it and/or
   7 // modify it under the terms of the GNU Lesser General Public
   8 // License as published by the Free Software Foundation; either
   9 // version 2.1 of the License, or (at your option) any later version.
  10 //
  11 // This library is distributed in the hope that it will be useful,
  12 // but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 // MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14 // Lesser General Public License for more details.
  15 //
  16 // You should have received a copy of the GNU Lesser General Public
  17 // License along with this library; if not, write to the Free Software
  18 // Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
  19 //
  20 // See http://www.salome-platform.org/ or email : webmaster.salome@opencascade.com
  21 //
  22
  23 //  File   : SMESH_Mesh.idl
  24 //  Author : Paul RASCLE, EDF
  25 //
  26 #ifndef _SMESH_MESH_IDL_
  27 #define _SMESH_MESH_IDL_
  28
  29 #include "SALOME_Exception.idl"
  30 #include "SALOME_GenericObj.idl"
  31 #include "GEOM_Gen.idl"
  32
  33 module SMESH
  34 {
  35   interface SMESH_Hypothesis;
  36   typedef sequence<SMESH_Hypothesis> ListOfHypothesis;
  37   interface SMESH_GroupBase;
  38   typedef sequence<SMESH_GroupBase> ListOfGroups;
  39   interface SMESH_IDSource;
  40   typedef sequence<SMESH_IDSource> ListOfIDSources;
  41
  42   typedef sequence<double    > double_array ;
  43   typedef sequence<long      > long_array ;
  44   typedef sequence<string    > string_array ;
  45   typedef sequence<long_array> array_of_long_array ;
  46
  47   enum log_command
  48     {
  49       ADD_NODE,
  50       ADD_EDGE,
  51       ADD_TRIANGLE,
  52       ADD_QUADRANGLE,
  53       ADD_POLYGON,
  54       ADD_TETRAHEDRON,
  55       ADD_PYRAMID,
  56       ADD_PRISM,
  57       ADD_HEXAHEDRON,
  58       ADD_POLYHEDRON,
  59       REMOVE_NODE,
  60       REMOVE_ELEMENT,
  61       MOVE_NODE,
  62       CHANGE_ELEMENT_NODES,
  63       CHANGE_POLYHEDRON_NODES,
  64       RENUMBER,
  65       CLEAR_MESH,
  66       ADD_QUADEDGE,
  67       ADD_QUADTRIANGLE,
  68       ADD_QUADQUADRANGLE,
  69       ADD_QUADTETRAHEDRON,
  70       ADD_QUADPYRAMID,
  71       ADD_QUADPENTAHEDRON,
  72       ADD_QUADHEXAHEDRON,
  73       ADD_ELEM0D,
  74       ADD_BIQUAD_TRIANGLE,
  75       ADD_BIQUAD_QUADRANGLE,
  76       ADD_TRIQUAD_HEXA,
  77       ADD_HEXAGONAL_PRISM,
  78       ADD_BALL
  79     };
  80
  81   struct log_block
  82   {
  83     long commandType;
  84     long number;
  85     double_array coords;
  86     long_array indexes;
  87   };
  88   typedef sequence<log_block> log_array;
  89
  90   struct PointStruct { double x;
  91                        double y;
  92                        double z; } ;
  93
  94   typedef sequence<PointStruct> nodes_array;
  95
  96   struct DirStruct   { PointStruct PS ; } ;          // analog to OCCT gp_Vec
  97
  98   struct AxisStruct  { double x;
  99                        double y;
 100                        double z;
 101                        double vx;
 102                        double vy;
 103                        double vz; } ;
 104   /*!
 105    * Node location on a shape
 106    */
 107   struct NodePosition {
 108     long             shapeID;
 109     GEOM::shape_type shapeType;
 110     double_array     params; // [U] on EDGE, [U,V] on FACE, [] on the rest shapes
 111   };
 112
 113   /*!
 114    * Element location on a shape
 115    */
 116   struct ElementPosition {
 117     long             shapeID;
 118     GEOM::shape_type shapeType;
 119   };
 120
 121   /*!
 122    * Enumeration for element type, like in SMDS
 123    */
 124   enum ElementType
 125   {
 126     ALL,
 127     NODE,
 128     EDGE,
 129     FACE,
 130     VOLUME,
 131     ELEM0D,
 132     BALL,
 133     NB_ELEMENT_TYPES
 134   };
 135   typedef sequence<ElementType> array_of_ElementType ;
 136
 137   /*!
 138    * Enumeration for element geometry type, like SMDSAbs_GeometryType in SMDSAbs_ElementType.hxx
 139    */
 140   enum GeometryType
 141   {
 142     Geom_POINT,
 143     Geom_EDGE,
 144     Geom_TRIANGLE,
 145     Geom_QUADRANGLE, // when a new GeometryType is added, please
 146     Geom_POLYGON,    // update a corresponding list in SMESH_2smeshpy.cxx, ln 665
 147     Geom_TETRA,
 148     Geom_PYRAMID,
 149     Geom_HEXA,
 150     Geom_PENTA,
 151     Geom_HEXAGONAL_PRISM,
 152     Geom_POLYHEDRA,
 153     Geom_BALL
 154   };
 155
 156   /*!
 157    * ElementOrder points out entities of what order are requested
 158    */
 159   enum ElementOrder {
 160     ORDER_ANY,          /*! entities of any order */
 161     ORDER_LINEAR,       /*! entities of 1st order */
 162     ORDER_QUADRATIC     /*! entities of 2nd order */
 163   };
 164
 165   /*!
 166    * Enumeration of entity type used in mesh info array,
 167    * it should be synchronised with enum SMDSAbs_EntityType
 168    */
 169   enum EntityType
 170   {
 171     Entity_Node,
 172     Entity_0D,
 173     Entity_Edge,
 174     Entity_Quad_Edge,
 175     Entity_Triangle,
 176     Entity_Quad_Triangle,
 177     Entity_BiQuad_Triangle,
 178     Entity_Quadrangle,
 179     Entity_Quad_Quadrangle,
 180     Entity_BiQuad_Quadrangle,
 181     Entity_Polygon,
 182     Entity_Quad_Polygon,
 183     Entity_Tetra,
 184     Entity_Quad_Tetra,
 185     Entity_Pyramid,
 186     Entity_Quad_Pyramid,
 187     Entity_Hexa,
 188     Entity_Quad_Hexa,
 189     Entity_TriQuad_Hexa,
 190     Entity_Penta,
 191     Entity_Quad_Penta,
 192     Entity_Hexagonal_Prism,
 193     Entity_Polyhedra,
 194     Entity_Quad_Polyhedra,
 195     Entity_Ball,
 196     Entity_Last
 197   };
 198
 199   /*!
 200    * Enumeration for hypothesis status (used by AddHypothesis() and RemoveHypothesis() methods)
 201    */
 202   enum Hypothesis_Status // in the order of severity
 203   {
 204     HYP_OK,
 205     HYP_MISSING,      // algo misses a hypothesis
 206     HYP_CONCURENT,    // several applicable hypotheses
 207     HYP_BAD_PARAMETER,// hypothesis has a bad parameter value
 208     HYP_HIDDEN_ALGO,  // an algo is hidden by an upper dim algo generating all-dim elements
 209     HYP_HIDING_ALGO,  // an algo hides lower dim algos by generating all-dim elements
 210     HYP_UNKNOWN_FATAL,//  --- all statuses below should be considered as fatal
 211                       //      for Add/RemoveHypothesis operations
 212     HYP_INCOMPATIBLE, // hypothesis does not fit algo
 213     HYP_NOTCONFORM,   // not conform mesh is produced appling a hypothesis
 214     HYP_ALREADY_EXIST,// such hypothesis already exist
 215     HYP_BAD_DIM,      // bad dimension
 216     HYP_BAD_SUBSHAPE, // shape is neither the main one, nor its sub-shape, nor a group
 217     HYP_BAD_GEOMETRY, // geometry mismatches algorithm's expectation
 218     HYP_NEED_SHAPE,   // algorithm can work on shape only
 219     HYP_INCOMPAT_HYPS // several additional hypotheses are incompatible one with other
 220   };
 221
 222   /*!
 223    * Enumeration for mesh read status (used by SMESH_Gen::CreateMeshesFrom*() methods)
 224    */
 225   enum DriverMED_ReadStatus // in the order of severity
 226   {
 227     DRS_OK,
 228     DRS_EMPTY,          // a file contains no mesh with the given name
 229     DRS_WARN_RENUMBER,  // a MED file has overlapped ranges of element numbers,
 230                         // so the numbers from the file are ignored
 231     DRS_WARN_SKIP_ELEM, // some elements were skipped due to incorrect file data
 232     DRS_WARN_DESCENDING, // some elements were skipped due to descending connectivity
 233     DRS_FAIL            // general failure (exception etc.)
 234   };
 235
 236   /*!
 237    * Enumeration for ExportToMED*()
 238    */
 239   enum MED_VERSION
 240   {
 241     MED_V2_1,
 242     MED_V2_2
 243   };
 244
 245   /*!
 246    * \brief A structure containing information about MED file
 247    */
 248   struct MedFileInfo
 249   {
 250     string fileName; //!< name of file
 251     long   fileSize; //!< size of file
 252     long   major, minor, release; //!< MED file version
 253   };
 254
 255   /*!
 256    * Auxilary flags for advanced extrusion.
 257    * BOUNDARY: create or not boundary for result of extrusion
 258    * SEW:      try to use existing nodes or create new nodes in any case
 259    */
 260   const long EXTRUSION_FLAG_BOUNDARY = 1;
 261   const long EXTRUSION_FLAG_SEW = 2;
 262
 263   /*!
 264    * Structure used in mesh edit preview data (MeshPreviewStruct)
 265    */
 266   struct ElementSubType { ElementType SMDS_ElementType;
 267                           boolean     isPoly;
 268                           long        nbNodesInElement; };
 269
 270   typedef sequence<ElementSubType> types_array;
 271
 272   /*!
 273    * Structure containing mesh edit preview data
 274    */
 275   struct MeshPreviewStruct { nodes_array nodesXYZ;
 276                              long_array  elementConnectivities;
 277                              types_array elementTypes; };
 278
 279   interface SMESH_Mesh;
 280
 281   interface SMESH_IDSource : SALOME::GenericObj
 282   {
 283     /*!
 284      * Returns a sequence of all element IDs
 285      */
 286     long_array GetIDs();
 287
 288     /*!
 289      * Returns number of mesh elements of each \a EntityType
 290      * @return array of number of elements per \a EntityType
 291      */
 292     long_array GetMeshInfo();
 293
 294     /*!
 295      * Returns number of mesh elements of each \a ElementType
 296      * @return array of number of elements per \a ElementType
 297      */
 298     long_array GetNbElementsByType();
 299
 300     /*!
 301      * Returns types of elements it contains.
 302      * It's empty if the SMESH_IDSource contains no IDs
 303      */
 304     array_of_ElementType GetTypes();
 305
 306     /*!
 307      * Returns the mesh
 308      */
 309     SMESH_Mesh GetMesh();
 310
 311     /*!
 312      * Returns false if GetMeshInfo() returns incorrect information that may
 313      * happen if mesh data is not yet fully loaded from the file of study.
 314      */
 315     boolean IsMeshInfoCorrect();
 316
 317     /*!
 318      * Returns mesh unstructed grid information.
 319      */
 320     SALOMEDS::TMPFile GetVtkUgStream();
 321   };
 322
 323   interface SMESH_Group;
 324   interface SMESH_GroupOnGeom;
 325   interface Filter;
 326   interface SMESH_GroupOnFilter;
 327   interface SMESH_subMesh;
 328   interface SMESH_MeshEditor;
 329
 330   typedef sequence<SMESH_subMesh>     submesh_array;
 331   typedef sequence<submesh_array>     submesh_array_array;
 332
 333   interface SMESH_Mesh : SALOME::GenericObj, SMESH_IDSource
 334   {
 335     /*!
 336      * Return true if there is a geometry to be meshed
 337      */
 338     boolean HasShapeToMesh()
 339       raises (SALOME::SALOME_Exception);
 340
 341     /*!
 342      * Get geom shape to mesh. A result sould not be nil. Use HasShapeToMesh()
 343      * to know if a returned shape
 344      */
 345     GEOM::GEOM_Object GetShapeToMesh()
 346       raises (SALOME::SALOME_Exception);
 347
 348     /*!
 349      * Return false if the mesh is not yet fully loaded from the study file
 350      */
 351     boolean IsLoaded()
 352       raises (SALOME::SALOME_Exception);
 353
 354     /*!
 355      * Load full mesh data from the study file
 356      */
 357     void Load()
 358       raises (SALOME::SALOME_Exception);
 359
 360     /*!
 361      * Remove all nodes and elements
 362      */
 363     void Clear()
 364       raises (SALOME::SALOME_Exception);
 365
 366     /*!
 367      *  Get the list of sub-meshes existing in the mesh
 368      */
 369     submesh_array GetSubMeshes()
 370       raises (SALOME::SALOME_Exception);
 371
 372     /*!
 373      * Remove all nodes and elements of submesh
 374      */
 375     void ClearSubMesh(in long ShapeID)
 376       raises (SALOME::SALOME_Exception);
 377
 378     /*!
 379      * Get the subMesh object associated to a Sub-shape. The subMesh object
 380      * gives access to nodes and elements IDs.
 381      * SubMesh will be used instead of Sub-shape in a next idl version to
 382      * adress a specific subMesh...
 383      */
 384     SMESH_subMesh GetSubMesh(in GEOM::GEOM_Object aSubObject, in string name)
 385       raises (SALOME::SALOME_Exception);
 386
 387     /*!
 388      * Remove a submesh
 389      */
 390     void RemoveSubMesh(in SMESH_subMesh aSubMesh)
 391       raises (SALOME::SALOME_Exception);
 392
 393
 394     /*!
 395      * Create a group
 396      */
 397     SMESH_Group CreateGroup( in ElementType elem_type,
 398                              in string      name )
 399       raises (SALOME::SALOME_Exception);
 400
 401     /*!
 402      * Create a group from geometry
 403      */
 404     SMESH_GroupOnGeom CreateGroupFromGEOM( in ElementType       elemType,
 405                                            in string            name,
 406                                            in GEOM::GEOM_Object geomObject )
 407       raises (SALOME::SALOME_Exception);
 408
 409     /*!
 410      * Create a group from filter
 411      */
 412     SMESH_GroupOnFilter CreateGroupFromFilter( in ElementType   elemType,
 413                                                in string        name,
 414                                                in SMESH::Filter filter )
 415       raises (SALOME::SALOME_Exception);
 416
 417     /*!
 418      * Remove a group
 419      */
 420     void RemoveGroup(in SMESH_GroupBase aGroup)
 421       raises (SALOME::SALOME_Exception);
 422
 423     /*!
 424      *  Remove group with its contents
 425      */
 426     void RemoveGroupWithContents( in SMESH_GroupBase aGroup )
 427       raises (SALOME::SALOME_Exception);
 428
 429     /*!
 430      *  Get the list of groups existing in the mesh
 431      */
 432     ListOfGroups GetGroups()
 433       raises (SALOME::SALOME_Exception);
 434
 435     /*!
 436      *  Get number of groups existing in the mesh
 437      */
 438     long NbGroups()
 439       raises (SALOME::SALOME_Exception);
 440
 441     /*!
 442      * Union of two groups
 443      *    New group is created. All mesh elements that are
 444      *    present in initial groups are added to the new one
 445      */
 446     SMESH_Group UnionGroups (in SMESH_GroupBase aGroup1,
 447                              in SMESH_GroupBase aGroup2,
 448                              in string          name )
 449       raises (SALOME::SALOME_Exception);
 450
 451     /*!
 452      * Union of list of groups
 453      * New group is created. All mesh elements that are
 454      * present in initial groups are added to the new one
 455      */
 456     SMESH_Group UnionListOfGroups (in ListOfGroups aListOfGroups,
 457                                    in string       name )
 458       raises (SALOME::SALOME_Exception);
 459
 460     /*!
 461      *  Intersection of two groups
 462      *  New group is created. All mesh elements that are
 463      *  present in both initial groups are added to the new one.
 464      */
 465     SMESH_Group IntersectGroups (in SMESH_GroupBase aGroup1,
 466                                  in SMESH_GroupBase aGroup2,
 467                                  in string          name )
 468       raises (SALOME::SALOME_Exception);
 469
 470     /*!
 471      *  Intersection of list of groups
 472      *  New group is created. All mesh elements that are
 473      *  present in all initial groups simultaneously are added to the new one.
 474      */
 475     SMESH_Group IntersectListOfGroups (in ListOfGroups aListOfGroups,
 476                                        in string       name)
 477       raises (SALOME::SALOME_Exception);
 478
 479     /*!
 480      *  Cut of two groups
 481      *  New group is created. All mesh elements that are present in
 482      *  main group but do not present in tool group are added to the new one
 483      */
 484     SMESH_Group CutGroups (in SMESH_GroupBase aMainGroup,
 485                            in SMESH_GroupBase aToolGroup,
 486                            in string          name )
 487       raises (SALOME::SALOME_Exception);
 488
 489     /*!
 490      *  Cut of lists of groups
 491      *  New group is created. All mesh elements that are present in
 492      *  main groups but do not present in tool groups are added to the new one
 493      */
 494     SMESH_Group CutListOfGroups (in ListOfGroups aMainGroups,
 495                                  in ListOfGroups aToolGroups,
 496                                  in string       name)
 497       raises (SALOME::SALOME_Exception);
 498
 499     /*!
 500      *  Create groups of entities from existing groups of superior dimensions
 501      *  New group is created. System
 502      *  1) extracts all nodes from each group,
 503      *  2) combines all elements of specified dimension laying on these nodes.
 504      */
 505     SMESH_Group CreateDimGroup( in ListOfGroups aListOfGroups,
 506                                 in ElementType  anElemType,
 507                                 in string       name )
 508       raises (SALOME::SALOME_Exception);
 509
 510     /*!
 511      * Convert group on geometry or on filter into standalone group
 512      */
 513     SMESH_Group ConvertToStandalone( in SMESH_GroupBase theGroupOn )
 514       raises (SALOME::SALOME_Exception);
 515
 516     /*!
 517      * Add hypothesis to the mesh, under a particular sub-shape
 518      * (or the main shape itself)
 519      * This method is only used to prepare the build of the mesh and store
 520      * the algorithms and associated parameters.
 521      * Actual job of meshing the shape is done by SMESH_Gen::Compute()
 522      * @params
 523      * - aSubObject : sub-shape obtained by a shape explode in GEOM
 524      *   (or main shape)
 525      * - anHyp : an hypothesis object
 526      * @return
 527      * - An enum item explaining what's up
 528      * - anErrorText: an optional textual description of a problem (if any)
 529      */
 530     Hypothesis_Status AddHypothesis(in GEOM::GEOM_Object aSubObject,
 531                                     in SMESH_Hypothesis  anHyp,
 532                                     out string           anErrorText)
 533       raises (SALOME::SALOME_Exception);
 534
 535     /*!
 536      * Remove an hypothesis previouly added with AddHypothesis.
 537      */
 538     Hypothesis_Status RemoveHypothesis(in GEOM::GEOM_Object aSubObject,
 539                                        in SMESH_Hypothesis anHyp)
 540       raises (SALOME::SALOME_Exception);
 541
 542     /*!
 543      * Get the list of hypothesis added on a sub-shape
 544      */
 545     ListOfHypothesis GetHypothesisList(in GEOM::GEOM_Object aSubObject)
 546       raises (SALOME::SALOME_Exception);
 547
 548     /*!
 549      * Get the log of nodes and elements added or removed since previous
 550      * clear of the log.
 551      * @params
 552      * - clearAfterGet : log is emptied after Get (safe if concurrents access)
 553      */
 554     log_array GetLog(in boolean clearAfterGet)
 555       raises (SALOME::SALOME_Exception);
 556
 557     /*!
 558      * Clear the log of nodes and elements added or removed since previous
 559      * clear. Must be used immediately after GetLog if clearAfterGet is false.
 560      */
 561     void ClearLog()
 562       raises (SALOME::SALOME_Exception);
 563
 564     /*!
 565      * Toggle auto color mode on the object.
 566      * @params
 567      * - theAutoColor : flag which toggles auto color mode.
 568      */
 569     void SetAutoColor(in boolean theAutoColor)
 570       raises (SALOME::SALOME_Exception);
 571
 572     /*!
 573      * Get flag of object's auto color mode.
 574      */
 575     boolean GetAutoColor()
 576       raises (SALOME::SALOME_Exception);
 577
 578     /*!
 579      * Get the internal Id
 580      */
 581     long GetId();
 582
 583     /*!
 584      * Get the study Id
 585      */
 586     long GetStudyId();
 587
 588     /*!
 589      * Obtain instance of SMESH_MeshEditor
 590      */
 591     SMESH_MeshEditor GetMeshEditor()
 592       raises (SALOME::SALOME_Exception);
 593
 594     /*!
 595      * Return SMESH_MeshEditor that would not modify the mesh but
 596      * fill MeshPreviewStruct
 597      */
 598     SMESH_MeshEditor GetMeshEditPreviewer()
 599       raises (SALOME::SALOME_Exception);
 600
 601     /*!
 602      * Return true if the mesh has been edited since a total re-compute
 603      * and those modifications may prevent successful partial re-compute
 604      */
 605     boolean HasModificationsToDiscard()
 606       raises (SALOME::SALOME_Exception);
 607
 608     /*! Check group names for duplications.
 609      *  Consider maximum group name length stored in MED file.
 610      */
 611     boolean HasDuplicatedGroupNamesMED();
 612
 613     /*!
 614      * Export Mesh to a MED Format file
 615      * @params
 616      * - file : name of the MED file
 617      * - auto_groups : boolean parameter for creating/not creating
 618      *                 the groups Group_On_All_Nodes, Group_On_All_Faces, ... ;
 619      *                 the typical use is auto_groups=false.
 620      * - version : defines the version of format of MED file, that will be created
 621      * - overwrite : boolean parameter for overwriting/not overwriting the file, if it exists
 622      * - autoDimension : if @c true, a space dimension of a MED mesh can be either
 623      *         - 1D if all mesh nodes lie on OX coordinate axis, or
 624      *         - 2D if all mesh nodes lie on XOY coordinate plane, or
 625      *         - 3D in the rest cases.
 626      *         If @a autoDimension is @c false, the space dimension is always 3.
 627      */
 628     void ExportToMEDX( in string      file,
 629                        in boolean     auto_groups,
 630                        in MED_VERSION version,
 631                        in boolean     overwrite,
 632                        in boolean     autoDimension) raises (SALOME::SALOME_Exception);
 633
 634     /*!
 635      * Export a [part of] Mesh into a MED file
 636      * @params
 637      * - meshPart : a part of mesh to store
 638      * - file : name of the MED file
 639      * - version : define the version of format of MED file, that will be created
 640      * - overwrite : boolean parameter for overwriting/not overwriting the file, if it exists
 641      * - autoDimension : if @c True, a space dimension for export is defined by mesh
 642      *                 configuration; for example a planar mesh lying on XOY plane
 643      *                 will be exported as a mesh in 2D space.
 644      *                 If @a autoDimension == @c False, the space dimension is 3.
 645      * - fields : list of GEOM fields defined on the shape to mesh.
 646      * - geomAssocFields : each character of this string means a need to export a
 647      *         corresponding field; correspondence between fields and characters is following:
 648      *         - 'v' stands for _vertices_ field;
 649      *         - 'e' stands for _edges_ field;
 650      *         - 'f' stands for _faces_ field;
 651      *         - 's' stands for _solids_ field.
 652      */
 653     void ExportPartToMED( in SMESH_IDSource     meshPart,
 654                           in string             file,
 655                           in boolean            auto_groups,
 656                           in MED_VERSION        version,
 657                           in boolean            overwrite,
 658                           in boolean            autoDimension,
 659                           in GEOM::ListOfFields fields,
 660                           in string             geomAssocFields ) raises (SALOME::SALOME_Exception);
 661
 662     /*!
 663      * Export Mesh to a MED Format file
 664      * Works, just the same as ExportToMEDX, with overwrite parameter equal to true.
 665      * The method is kept in order to support old functionality
 666      */
 667     void ExportToMED( in string file, in boolean auto_groups, in MED_VERSION theVersion )
 668       raises (SALOME::SALOME_Exception);
 669
 670     /*!
 671      * Export Mesh to MED_V2_1 MED format
 672      * Works, just the same as ExportToMEDX with MED_VERSION parameter equal to MED_V2_1
 673      * and overwrite parameter equal to true
 674      * The method is kept in order to support old functionality
 675      */
 676     void ExportMED( in string file, in boolean auto_groups )
 677       raises (SALOME::SALOME_Exception);
 678
 679     /*!
 680      * Export Mesh to SAUV formatted file
 681      * Write a temporary med file and use med2sauv
 682      */
 683     void ExportSAUV( in string file, in boolean auto_groups )
 684       raises (SALOME::SALOME_Exception);
 685
 686     /*!
 687      * Return string representation of a MED file version comprising nbDigits
 688      */
 689     string GetVersionString(in MED_VERSION version, in short nbDigits);
 690
 691     /*!
 692      * Export Mesh to different Formats
 693      * (UNV supported version is I-DEAS 10)
 694      */
 695     void ExportDAT( in string file ) raises (SALOME::SALOME_Exception);
 696     void ExportUNV( in string file ) raises (SALOME::SALOME_Exception);
 697     void ExportSTL( in string  file,
 698                     in boolean isascii ) raises (SALOME::SALOME_Exception);
 699     void ExportCGNS( in SMESH_IDSource meshPart,
 700                      in string         file,
 701                      in boolean        overwrite ) raises (SALOME::SALOME_Exception);
 702     void ExportGMF( in SMESH_IDSource  meshPart,
 703                     in string          file,
 704                     in boolean         withRequiredGroups) raises (SALOME::SALOME_Exception);
 705     void ExportPartToDAT( in SMESH_IDSource meshPart,
 706                           in string         file ) raises (SALOME::SALOME_Exception);
 707     void ExportPartToUNV( in SMESH_IDSource meshPart,
 708                           in string         file ) raises (SALOME::SALOME_Exception);
 709     void ExportPartToSTL( in SMESH_IDSource meshPart,
 710                           in string         file,
 711                           in boolean        isascii ) raises (SALOME::SALOME_Exception);
 712     /*!
 713      * Return computation progress [0.,1]
 714      */
 715     double GetComputeProgress();
 716
 717     /*!
 718      * Get informations about mesh contents
 719      */
 720     long NbNodes()
 721       raises (SALOME::SALOME_Exception);
 722
 723     long NbElements()
 724       raises (SALOME::SALOME_Exception);
 725
 726     long Nb0DElements()
 727       raises (SALOME::SALOME_Exception);
 728
 729     long NbBalls()
 730       raises (SALOME::SALOME_Exception);
 731
 732     long NbEdges()
 733       raises (SALOME::SALOME_Exception);
 734
 735     long NbEdgesOfOrder(in ElementOrder order)
 736       raises (SALOME::SALOME_Exception);
 737
 738     long NbFaces()
 739       raises (SALOME::SALOME_Exception);
 740
 741     long NbFacesOfOrder(in ElementOrder order)
 742       raises (SALOME::SALOME_Exception);
 743
 744     long NbTriangles()
 745       raises (SALOME::SALOME_Exception);
 746
 747     long NbTrianglesOfOrder(in ElementOrder order)
 748       raises (SALOME::SALOME_Exception);
 749
 750     long NbBiQuadTriangles()
 751       raises (SALOME::SALOME_Exception);
 752
 753     long NbQuadrangles()
 754       raises (SALOME::SALOME_Exception);
 755
 756     long NbQuadranglesOfOrder(in ElementOrder order)
 757       raises (SALOME::SALOME_Exception);
 758
 759     long NbBiQuadQuadrangles()
 760       raises (SALOME::SALOME_Exception);
 761
 762     long NbPolygons()
 763       raises (SALOME::SALOME_Exception);
 764
 765     long NbVolumes()
 766       raises (SALOME::SALOME_Exception);
 767
 768     long NbVolumesOfOrder(in ElementOrder order)
 769       raises (SALOME::SALOME_Exception);
 770
 771     long NbTetras()
 772       raises (SALOME::SALOME_Exception);
 773
 774     long NbTetrasOfOrder(in ElementOrder order)
 775       raises (SALOME::SALOME_Exception);
 776
 777     long NbHexas()
 778       raises (SALOME::SALOME_Exception);
 779
 780     long NbHexasOfOrder(in ElementOrder order)
 781       raises (SALOME::SALOME_Exception);
 782
 783     long NbTriQuadraticHexas()
 784       raises (SALOME::SALOME_Exception);
 785
 786     long NbPyramids()
 787       raises (SALOME::SALOME_Exception);
 788
 789     long NbPyramidsOfOrder(in ElementOrder order)
 790       raises (SALOME::SALOME_Exception);
 791
 792     long NbPrisms()
 793       raises (SALOME::SALOME_Exception);
 794
 795     long NbPrismsOfOrder(in ElementOrder order)
 796       raises (SALOME::SALOME_Exception);
 797
 798     long NbHexagonalPrisms()
 799       raises (SALOME::SALOME_Exception);
 800
 801     long NbPolyhedrons()
 802       raises (SALOME::SALOME_Exception);
 803
 804     long NbSubMesh()
 805       raises (SALOME::SALOME_Exception);
 806
 807     long_array GetElementsId()
 808       raises (SALOME::SALOME_Exception);
 809
 810     long_array GetElementsByType( in ElementType theType )
 811       raises (SALOME::SALOME_Exception);
 812
 813     long_array GetNodesId()
 814       raises (SALOME::SALOME_Exception);
 815
 816     /*!
 817      * Returns type of mesh element
 818      */
 819     ElementType GetElementType( in long id, in boolean iselem )
 820       raises (SALOME::SALOME_Exception);
 821
 822     EntityType GetElementGeomType( in long id )
 823       raises (SALOME::SALOME_Exception);
 824
 825     GeometryType GetElementShape( in long id )
 826       raises (SALOME::SALOME_Exception);
 827
 828     long_array GetSubMeshElementsId(in long ShapeID)
 829       raises (SALOME::SALOME_Exception);
 830
 831     long_array GetSubMeshNodesId(in long ShapeID, in boolean all )
 832       raises (SALOME::SALOME_Exception);
 833
 834     ElementType GetSubMeshElementType(in long ShapeID)
 835       raises (SALOME::SALOME_Exception);
 836
 837
 838     /*!
 839      * Methods to set meshing order of submeshes
 840      */
 841
 842     /*!
 843      * \brief Return \c true if a meshing order not yet set for a concurrent sub-mesh
 844      */
 845     boolean IsUnorderedSubMesh(in long submeshID);
 846
 847     /*!
 848      * \brief Return submesh objects list in meshing order
 849      */
 850     submesh_array_array GetMeshOrder();
 851
 852     /*!
 853      * \brief Set submesh object order
 854      */
 855     boolean SetMeshOrder(in submesh_array_array theSubMeshArray);
 856
 857
 858     /*!
 859      * Get mesh description
 860      */
 861     string Dump();
 862
 863     /*!
 864      * Get mesh pointer
 865      */
 866     long long GetMeshPtr();
 867
 868     /*!
 869      * Get XYZ coordinates of node as list of double
 870      * If there is not node for given ID - returns empty list
 871      */
 872     double_array GetNodeXYZ(in long id);
 873
 874     /*!
 875      * For given node returns list of IDs of inverse elements
 876      * If there is not node for given ID - returns empty list
 877      */
 878     long_array GetNodeInverseElements(in long id);
 879
 880     /*!
 881      * \brief Return position of a node on shape
 882      */
 883     NodePosition GetNodePosition(in long NodeID);
 884
 885     /*!
 886      * \brief Return position of an element on shape
 887      */
 888     ElementPosition GetElementPosition(in long ElemID);
 889
 890     /*!
 891      * If given element is node returns IDs of shape from position
 892      * If there is not node for given ID - returns -1
 893      */
 894     long GetShapeID(in long id);
 895
 896     /*!
 897      * For given element returns ID of result shape after
 898      * ::FindShape() from SMESH_MeshEditor
 899      * If there is not element for given ID - returns -1
 900      */
 901     long GetShapeIDForElem(in long id);
 902
 903     /*!
 904      * Returns number of nodes for given element
 905      * If there is not element for given ID - returns -1
 906      */
 907     long GetElemNbNodes(in long id);
 908
 909     /*!
 910      * Returns IDs of nodes of given element
 911      */
 912     long_array GetElemNodes(in long id);
 913
 914     /*!
 915      * Returns ID of node by given index for given element
 916      * If there is not element for given ID - returns -1
 917      * If there is not node for given index - returns -2
 918      */
 919     long GetElemNode(in long id, in long index);
 920
 921     /*!
 922      * Returns true if given node is medium node
 923      * in given quadratic element
 924      */
 925     boolean IsMediumNode(in long ide, in long idn);
 926
 927     /*!
 928      * Returns true if given node is medium node
 929      * in one of quadratic elements
 930      */
 931     boolean IsMediumNodeOfAnyElem(in long idn, in ElementType elem_type);
 932
 933     /*!
 934      * Returns number of edges for given element
 935      */
 936     long ElemNbEdges(in long id);
 937
 938     /*!
 939      * Returns number of faces for given element
 940      */
 941     long ElemNbFaces(in long id);
 942
 943     /*!
 944      * Returns nodes of given face (counted from zero) for given volumic element.
 945      */
 946     long_array GetElemFaceNodes(in long elemId, in short faceIndex);
 947
 948     /*!
 949      * Returns three components of normal of given mesh face (or an empty array in KO case)
 950      */
 951     double_array GetFaceNormal(in long faceId, in boolean normalized);
 952
 953     /*!
 954      * Returns an element based on all given nodes.
 955      */
 956     long FindElementByNodes(in long_array nodes);
 957
 958     /*!
 959      * Returns true if given element is polygon
 960      */
 961     boolean IsPoly(in long id);
 962
 963     /*!
 964      * Returns true if given element is quadratic
 965      */
 966     boolean IsQuadratic(in long id);
 967
 968     /*!
 969      * Returns diameter of a ball discrete element or zero in case of an invalid \a id
 970      */
 971     double GetBallDiameter(in long id);
 972
 973     /*!
 974      * Returns XYZ coordinates of bary center for given element
 975      * as list of double
 976      * If there is not element for given ID - returns empty list
 977      */
 978     double_array BaryCenter(in long id);
 979
 980     /*! Gets information about imported MED file */
 981     MedFileInfo GetMEDFileInfo();
 982
 983     /*!
 984      *  Sets list of notebook variables used for Mesh operations separated by ":" symbol
 985      *  \param theParameters is a string containing the notebook variables
 986      */
 987     void SetParameters (in string theParameters);
 988
 989     /*!
 990      *  Returns list of notebook variables used for Mesh operations separated by ":" symbol
 991      */
 992     string GetParameters();
 993
 994     /*!
 995      *  Returns list of notebook variables used for last Mesh operation
 996      */
 997     string_array GetLastParameters();
 998   };
 999
1000   interface SMESH_subMesh : SALOME::GenericObj, SMESH_IDSource
1001   {
1002     /*!
1003      *
1004      */
1005     long GetNumberOfElements()
1006       raises (SALOME::SALOME_Exception);
1007
1008     /*!
1009      *
1010      */
1011     long GetNumberOfNodes( in boolean all )
1012       raises (SALOME::SALOME_Exception);
1013
1014     /*!
1015      *
1016      */
1017     long_array GetElementsId()
1018       raises (SALOME::SALOME_Exception);
1019
1020     /*!
1021      *
1022      */
1023     long_array GetElementsByType( in ElementType theType )
1024       raises (SALOME::SALOME_Exception);
1025
1026     /*!
1027      * Return type of submesh element
1028      */
1029     ElementType GetElementType( in long id, in boolean iselem )
1030       raises (SALOME::SALOME_Exception);
1031
1032     /*!
1033      *
1034      */
1035     long_array GetNodesId()
1036       raises (SALOME::SALOME_Exception);
1037
1038     /*!
1039      * Get geom shape the submesh is dedicated to
1040      */
1041     GEOM::GEOM_Object GetSubShape()
1042       raises (SALOME::SALOME_Exception);
1043
1044     /*!
1045      * Get SMESH_Mesh which stores nodes coordinates & elements definition
1046      */
1047     SMESH_Mesh GetFather()
1048       raises (SALOME::SALOME_Exception);
1049
1050     /*!
1051      * Get the internal Id
1052      */
1053     long GetId();
1054   };
1055
1056 };
1057
1058 #endif