idl/SMESH_Mesh.idl

   1 // Copyright (C) 2007-2016  CEA/DEN, EDF R&D, OPEN CASCADE
   2 //
   3 // Copyright (C) 2003-2007  OPEN CASCADE, EADS/CCR, LIP6, CEA/DEN,
   4 // CEDRAT, EDF R&D, LEG, PRINCIPIA R&D, BUREAU VERITAS
   5 //
   6 // This library is free software; you can redistribute it and/or
   7 // modify it under the terms of the GNU Lesser General Public
   8 // License as published by the Free Software Foundation; either
   9 // version 2.1 of the License, or (at your option) any later version.
  10 //
  11 // This library is distributed in the hope that it will be useful,
  12 // but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 // MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14 // Lesser General Public License for more details.
  15 //
  16 // You should have received a copy of the GNU Lesser General Public
  17 // License along with this library; if not, write to the Free Software
  18 // Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
  19 //
  20 // See http://www.salome-platform.org/ or email : webmaster.salome@opencascade.com
  21 //
  22
  23 //  File   : SMESH_Mesh.idl
  24 //  Author : Paul RASCLE, EDF
  25 //
  26 #ifndef _SMESH_MESH_IDL_
  27 #define _SMESH_MESH_IDL_
  28
  29 #include "SALOME_Exception.idl"
  30 #include "SALOME_GenericObj.idl"
  31 #include "GEOM_Gen.idl"
  32
  33 module SMESH
  34 {
  35   interface SMESH_Hypothesis;
  36   typedef sequence<SMESH_Hypothesis> ListOfHypothesis;
  37   interface SMESH_GroupBase;
  38   typedef sequence<SMESH_GroupBase> ListOfGroups;
  39   interface SMESH_IDSource;
  40   typedef sequence<SMESH_IDSource> ListOfIDSources;
  41
  42   typedef sequence<double    > double_array ;
  43   typedef sequence<long      > long_array ;
  44   typedef sequence<string    > string_array ;
  45   typedef sequence<long_array> array_of_long_array ;
  46
  47   enum log_command
  48     {
  49       ADD_NODE,
  50       ADD_EDGE,
  51       ADD_TRIANGLE,
  52       ADD_QUADRANGLE,
  53       ADD_POLYGON,
  54       ADD_TETRAHEDRON,
  55       ADD_PYRAMID,
  56       ADD_PRISM,
  57       ADD_HEXAHEDRON,
  58       ADD_POLYHEDRON,
  59       REMOVE_NODE,
  60       REMOVE_ELEMENT,
  61       MOVE_NODE,
  62       CHANGE_ELEMENT_NODES,
  63       CHANGE_POLYHEDRON_NODES,
  64       RENUMBER,
  65       CLEAR_MESH,
  66       ADD_QUADEDGE,
  67       ADD_QUADTRIANGLE,
  68       ADD_QUADQUADRANGLE,
  69       ADD_QUADPOLYGON,
  70       ADD_QUADTETRAHEDRON,
  71       ADD_QUADPYRAMID,
  72       ADD_QUADPENTAHEDRON,
  73       ADD_QUADHEXAHEDRON,
  74       ADD_ELEM0D,
  75       ADD_BIQUAD_TRIANGLE,
  76       ADD_BIQUAD_QUADRANGLE,
  77       ADD_TRIQUAD_HEXA,
  78       ADD_HEXAGONAL_PRISM,
  79       ADD_BALL
  80     };
  81
  82   struct log_block
  83   {
  84     long commandType;
  85     long number;
  86     double_array coords;
  87     long_array indexes;
  88   };
  89   typedef sequence<log_block> log_array;
  90
  91   struct PointStruct { double x;
  92                        double y;
  93                        double z; };
  94
  95   typedef sequence<PointStruct> nodes_array;
  96
  97   struct DirStruct   { PointStruct PS; };          // analog to OCCT gp_Vec
  98
  99   struct AxisStruct  { double x;
 100                        double y;
 101                        double z;
 102                        double vx;
 103                        double vy;
 104                        double vz; };
 105   /*!
 106    * Node location on a shape
 107    */
 108   struct NodePosition {
 109     long             shapeID;
 110     GEOM::shape_type shapeType;
 111     double_array     params; // [U] on EDGE, [U,V] on FACE, [] on the rest shapes
 112   };
 113
 114   /*!
 115    * Element location on a shape
 116    */
 117   struct ElementPosition {
 118     long             shapeID;
 119     GEOM::shape_type shapeType;
 120   };
 121
 122   /*!
 123    * Enumeration for element type, like in SMDS
 124    */
 125   enum ElementType
 126   {
 127     ALL,
 128     NODE,
 129     EDGE,
 130     FACE,
 131     VOLUME,
 132     ELEM0D,
 133     BALL,
 134     NB_ELEMENT_TYPES
 135   };
 136   typedef sequence<ElementType> array_of_ElementType;
 137
 138   /*!
 139    * Enumeration for element geometry type, like SMDSAbs_GeometryType in SMDSAbs_ElementType.hxx
 140    */
 141   enum GeometryType
 142   {
 143     Geom_POINT,
 144     Geom_EDGE,
 145     Geom_TRIANGLE,
 146     Geom_QUADRANGLE, // when a new GeometryType is added, please
 147     Geom_POLYGON,    // update a corresponding list in SMESH_2smeshpy.cxx, ln 665
 148     Geom_TETRA,
 149     Geom_PYRAMID,
 150     Geom_HEXA,
 151     Geom_PENTA,
 152     Geom_HEXAGONAL_PRISM,
 153     Geom_POLYHEDRA,
 154     Geom_BALL,
 155     Geom_LAST
 156   };
 157
 158   /*!
 159    * ElementOrder points out entities of what order are requested
 160    */
 161   enum ElementOrder {
 162     ORDER_ANY,          /*! entities of any order */
 163     ORDER_LINEAR,       /*! entities of 1st order */
 164     ORDER_QUADRATIC     /*! entities of 2nd order */
 165   };
 166
 167   /*!
 168    * Enumeration of entity type used in mesh info array,
 169    * it should be synchronised with enum SMDSAbs_EntityType
 170    */
 171   enum EntityType
 172   {
 173     Entity_Node,
 174     Entity_0D,
 175     Entity_Edge,
 176     Entity_Quad_Edge,
 177     Entity_Triangle,
 178     Entity_Quad_Triangle,
 179     Entity_BiQuad_Triangle,
 180     Entity_Quadrangle,
 181     Entity_Quad_Quadrangle,
 182     Entity_BiQuad_Quadrangle,
 183     Entity_Polygon,
 184     Entity_Quad_Polygon,
 185     Entity_Tetra,
 186     Entity_Quad_Tetra,
 187     Entity_Pyramid,
 188     Entity_Quad_Pyramid,
 189     Entity_Hexa,
 190     Entity_Quad_Hexa,
 191     Entity_TriQuad_Hexa,
 192     Entity_Penta,
 193     Entity_Quad_Penta,
 194     Entity_Hexagonal_Prism,
 195     Entity_Polyhedra,
 196     Entity_Quad_Polyhedra,
 197     Entity_Ball,
 198     Entity_Last
 199   };
 200
 201   /*!
 202    * Enumeration for hypothesis status (used by AddHypothesis() and RemoveHypothesis() methods)
 203    */
 204   enum Hypothesis_Status // in the order of severity
 205   {
 206     HYP_OK,
 207     HYP_MISSING,      // algo misses a hypothesis
 208     HYP_CONCURENT,    // several applicable hypotheses
 209     HYP_BAD_PARAMETER,// hypothesis has a bad parameter value
 210     HYP_HIDDEN_ALGO,  // an algo is hidden by an upper dim algo generating all-dim elements
 211     HYP_HIDING_ALGO,  // an algo hides lower dim algos by generating all-dim elements
 212     HYP_UNKNOWN_FATAL,//  --- all statuses below should be considered as fatal
 213                       //      for Add/RemoveHypothesis operations
 214     HYP_INCOMPATIBLE, // hypothesis does not fit algo
 215     HYP_NOTCONFORM,   // not conform mesh is produced appling a hypothesis
 216     HYP_ALREADY_EXIST,// such hypothesis already exist
 217     HYP_BAD_DIM,      // bad dimension
 218     HYP_BAD_SUBSHAPE, // shape is neither the main one, nor its sub-shape, nor a group
 219     HYP_BAD_GEOMETRY, // geometry mismatches algorithm's expectation
 220     HYP_NEED_SHAPE,   // algorithm can work on shape only
 221     HYP_INCOMPAT_HYPS // several additional hypotheses are incompatible one with other
 222   };
 223
 224   /*!
 225    * Enumeration for mesh read status (used by SMESH_Gen::CreateMeshesFrom*() methods)
 226    */
 227   enum DriverMED_ReadStatus // in the order of severity
 228   {
 229     DRS_OK,
 230     DRS_EMPTY,          // a file contains no mesh with the given name
 231     DRS_WARN_RENUMBER,  // a MED file has overlapped ranges of element numbers,
 232                         // so the numbers from the file are ignored
 233     DRS_WARN_SKIP_ELEM, // some elements were skipped due to incorrect file data
 234     DRS_WARN_DESCENDING, // some elements were skipped due to descending connectivity
 235     DRS_FAIL            // general failure (exception etc.)
 236   };
 237
 238   /*!
 239    * Enumeration for ExportToMED*()
 240    */
 241   enum MED_VERSION
 242   {
 243     MED_V2_1,
 244     MED_V2_2
 245   };
 246
 247   /*!
 248    * \brief A structure containing information about MED file
 249    */
 250   struct MedFileInfo
 251   {
 252     string fileName; //!< name of file
 253     long   fileSize; //!< size of file
 254     long   major, minor, release; //!< MED file version
 255   };
 256
 257   /*!
 258    * Enumeration for CreateDimGroup()
 259    */
 260   enum NB_COMMON_NODES_ENUM
 261   {
 262     ALL_NODES, MAIN, AT_LEAST_ONE, MAJORITY
 263   };
 264
 265   /*!
 266    * Auxiliary flags for advanced extrusion.
 267    * BOUNDARY: create or not boundary for result of extrusion
 268    * SEW:      try to use existing nodes or create new nodes in any case
 269    */
 270   const long EXTRUSION_FLAG_BOUNDARY = 1;
 271   const long EXTRUSION_FLAG_SEW = 2;
 272
 273   /*!
 274    * Structure used in mesh edit preview data (MeshPreviewStruct)
 275    */
 276   struct ElementSubType { ElementType SMDS_ElementType;
 277                           boolean     isPoly;
 278                           long        nbNodesInElement; };
 279
 280   typedef sequence<ElementSubType> types_array;
 281
 282   /*!
 283    * Structure containing mesh edit preview data
 284    */
 285   struct MeshPreviewStruct { nodes_array nodesXYZ;
 286                              long_array  elementConnectivities;
 287                              types_array elementTypes; };
 288
 289   interface SMESH_Mesh;
 290
 291   interface SMESH_IDSource : SALOME::GenericObj
 292   {
 293     /*!
 294      * Returns a sequence of all element IDs
 295      */
 296     long_array GetIDs();
 297
 298     /*!
 299      * Returns number of mesh elements of each \a EntityType
 300      * @return array of number of elements per \a EntityType
 301      */
 302     long_array GetMeshInfo();
 303
 304     /*!
 305      * Returns number of mesh elements of each \a ElementType
 306      * @return array of number of elements per \a ElementType
 307      */
 308     long_array GetNbElementsByType();
 309
 310     /*!
 311      * Returns types of elements it contains.
 312      * It's empty if the SMESH_IDSource contains no IDs
 313      */
 314     array_of_ElementType GetTypes();
 315
 316     /*!
 317      * Returns the mesh
 318      */
 319     SMESH_Mesh GetMesh();
 320
 321     /*!
 322      * Returns false if GetMeshInfo() returns incorrect information that may
 323      * happen if mesh data is not yet fully loaded from the file of study.
 324      */
 325     boolean IsMeshInfoCorrect();
 326
 327     /*!
 328      * Returns mesh unstructed grid information.
 329      */
 330     SALOMEDS::TMPFile GetVtkUgStream();
 331   };
 332
 333   interface SMESH_Group;
 334   interface SMESH_GroupOnGeom;
 335   interface Filter;
 336   interface SMESH_GroupOnFilter;
 337   interface SMESH_subMesh;
 338   interface SMESH_MeshEditor;
 339
 340   typedef sequence<SMESH_subMesh>     submesh_array;
 341   typedef sequence<submesh_array>     submesh_array_array;
 342
 343   interface SMESH_Mesh : SALOME::GenericObj, SMESH_IDSource
 344   {
 345     /*!
 346      * Return true if there is a geometry to be meshed
 347      */
 348     boolean HasShapeToMesh()
 349       raises (SALOME::SALOME_Exception);
 350
 351     /*!
 352      * Get geom shape to mesh. A result should not be nil. Use HasShapeToMesh()
 353      * to know if a returned shape
 354      */
 355     GEOM::GEOM_Object GetShapeToMesh()
 356       raises (SALOME::SALOME_Exception);
 357
 358     /*!
 359      * Return false if the mesh is not yet fully loaded from the study file
 360      */
 361     boolean IsLoaded()
 362       raises (SALOME::SALOME_Exception);
 363
 364     /*!
 365      * Load full mesh data from the study file
 366      */
 367     void Load()
 368       raises (SALOME::SALOME_Exception);
 369
 370     /*!
 371      * Remove all nodes and elements
 372      */
 373     void Clear()
 374       raises (SALOME::SALOME_Exception);
 375
 376     /*!
 377      *  Get the list of sub-meshes existing in the mesh
 378      */
 379     submesh_array GetSubMeshes()
 380       raises (SALOME::SALOME_Exception);
 381
 382     /*!
 383      * Remove all nodes and elements of submesh
 384      */
 385     void ClearSubMesh(in long ShapeID)
 386       raises (SALOME::SALOME_Exception);
 387
 388     /*!
 389      * Get the subMesh object associated to a Sub-shape. The subMesh object
 390      * gives access to nodes and elements IDs.
 391      * SubMesh will be used instead of Sub-shape in a next idl version to
 392      * address a specific subMesh...
 393      */
 394     SMESH_subMesh GetSubMesh(in GEOM::GEOM_Object aSubObject, in string name)
 395       raises (SALOME::SALOME_Exception);
 396
 397     /*!
 398      * Remove a submesh
 399      */
 400     void RemoveSubMesh(in SMESH_subMesh aSubMesh)
 401       raises (SALOME::SALOME_Exception);
 402
 403
 404     /*!
 405      * Create a group
 406      */
 407     SMESH_Group CreateGroup( in ElementType elem_type,
 408                              in string      name )
 409       raises (SALOME::SALOME_Exception);
 410
 411     /*!
 412      * Create a group from geometry
 413      */
 414     SMESH_GroupOnGeom CreateGroupFromGEOM( in ElementType       elemType,
 415                                            in string            name,
 416                                            in GEOM::GEOM_Object geomObject )
 417       raises (SALOME::SALOME_Exception);
 418
 419     /*!
 420      * Create a group from filter
 421      */
 422     SMESH_GroupOnFilter CreateGroupFromFilter( in ElementType   elemType,
 423                                                in string        name,
 424                                                in SMESH::Filter filter )
 425       raises (SALOME::SALOME_Exception);
 426
 427     /*!
 428      * Remove a group
 429      */
 430     void RemoveGroup(in SMESH_GroupBase aGroup)
 431       raises (SALOME::SALOME_Exception);
 432
 433     /*!
 434      *  Remove group with its contents
 435      */
 436     void RemoveGroupWithContents( in SMESH_GroupBase aGroup )
 437       raises (SALOME::SALOME_Exception);
 438
 439     /*!
 440      *  Get the list of groups existing in the mesh
 441      */
 442     ListOfGroups GetGroups()
 443       raises (SALOME::SALOME_Exception);
 444
 445     /*!
 446      *  Get number of groups existing in the mesh
 447      */
 448     long NbGroups()
 449       raises (SALOME::SALOME_Exception);
 450
 451     /*!
 452      * Union of two groups
 453      *    New group is created. All mesh elements that are
 454      *    present in initial groups are added to the new one
 455      */
 456     SMESH_Group UnionGroups (in SMESH_GroupBase aGroup1,
 457                              in SMESH_GroupBase aGroup2,
 458                              in string          name )
 459       raises (SALOME::SALOME_Exception);
 460
 461     /*!
 462      * Union of list of groups
 463      * New group is created. All mesh elements that are
 464      * present in initial groups are added to the new one
 465      */
 466     SMESH_Group UnionListOfGroups (in ListOfGroups aListOfGroups,
 467                                    in string       name )
 468       raises (SALOME::SALOME_Exception);
 469
 470     /*!
 471      *  Intersection of two groups
 472      *  New group is created. All mesh elements that are
 473      *  present in both initial groups are added to the new one.
 474      */
 475     SMESH_Group IntersectGroups (in SMESH_GroupBase aGroup1,
 476                                  in SMESH_GroupBase aGroup2,
 477                                  in string          name )
 478       raises (SALOME::SALOME_Exception);
 479
 480     /*!
 481      *  Intersection of list of groups
 482      *  New group is created. All mesh elements that are
 483      *  present in all initial groups simultaneously are added to the new one.
 484      */
 485     SMESH_Group IntersectListOfGroups (in ListOfGroups aListOfGroups,
 486                                        in string       name)
 487       raises (SALOME::SALOME_Exception);
 488
 489     /*!
 490      *  Cut of two groups
 491      *  New group is created. All mesh elements that are present in
 492      *  main group but do not present in tool group are added to the new one
 493      */
 494     SMESH_Group CutGroups (in SMESH_GroupBase aMainGroup,
 495                            in SMESH_GroupBase aToolGroup,
 496                            in string          name )
 497       raises (SALOME::SALOME_Exception);
 498
 499     /*!
 500      *  Cut of lists of groups
 501      *  New group is created. All mesh elements that are present in
 502      *  main groups but do not present in tool groups are added to the new one
 503      */
 504     SMESH_Group CutListOfGroups (in ListOfGroups aMainGroups,
 505                                  in ListOfGroups aToolGroups,
 506                                  in string       name)
 507       raises (SALOME::SALOME_Exception);
 508
 509     /*!
 510      *  Create a group of entities basing on nodes of other groups.
 511      *  \param [in] aListOfGroups - list of either groups, sub-meshes or filters.
 512      *  \param [in] anElemType - a type of elements to include to the new group.
 513      *  \param [in] name - a name of the new group.
 514      *  \param [in] nbCommonNodes - criterion of inclusion of an element to the new group.
 515      *  \param [in] underlyingOnly - if \c True, an element is included to the
 516      *         new group provided that it is based on nodes of an element of
 517      *         \a aListOfGroups
 518      *  \return SMESH_Group - the created group
 519      */
 520     SMESH_Group CreateDimGroup( in ListOfIDSources      aListOfGroups,
 521                                 in ElementType          anElemType,
 522                                 in string               name,
 523                                 in NB_COMMON_NODES_ENUM nbCommonNodes,
 524                                 in boolean              underlyingOnly )
 525       raises (SALOME::SALOME_Exception);
 526
 527     /*!
 528      * Convert group on geometry or on filter into standalone group
 529      */
 530     SMESH_Group ConvertToStandalone( in SMESH_GroupBase theGroupOn )
 531       raises (SALOME::SALOME_Exception);
 532
 533     /*!
 534      * Add hypothesis to the mesh, under a particular sub-shape
 535      * (or the main shape itself)
 536      * This method is only used to prepare the build of the mesh and store
 537      * the algorithms and associated parameters.
 538      * Actual job of meshing the shape is done by SMESH_Gen::Compute()
 539      * @params
 540      * - aSubObject : sub-shape obtained by a shape explode in GEOM
 541      *   (or main shape)
 542      * - anHyp : an hypothesis object
 543      * @return
 544      * - An enum item explaining what's up
 545      * - anErrorText: an optional textual description of a problem (if any)
 546      */
 547     Hypothesis_Status AddHypothesis(in GEOM::GEOM_Object aSubObject,
 548                                     in SMESH_Hypothesis  anHyp,
 549                                     out string           anErrorText)
 550       raises (SALOME::SALOME_Exception);
 551
 552     /*!
 553      * Remove an hypothesis previouly added with AddHypothesis.
 554      */
 555     Hypothesis_Status RemoveHypothesis(in GEOM::GEOM_Object aSubObject,
 556                                        in SMESH_Hypothesis anHyp)
 557       raises (SALOME::SALOME_Exception);
 558
 559     /*!
 560      * Get the list of hypothesis added on a sub-shape
 561      */
 562     ListOfHypothesis GetHypothesisList(in GEOM::GEOM_Object aSubObject)
 563       raises (SALOME::SALOME_Exception);
 564
 565     /*!
 566      * Get the log of nodes and elements added or removed since previous
 567      * clear of the log.
 568      * @params
 569      * - clearAfterGet : log is emptied after Get (safe if concurrents access)
 570      */
 571     log_array GetLog(in boolean clearAfterGet)
 572       raises (SALOME::SALOME_Exception);
 573
 574     /*!
 575      * Clear the log of nodes and elements added or removed since previous
 576      * clear. Must be used immediately after GetLog if clearAfterGet is false.
 577      */
 578     void ClearLog()
 579       raises (SALOME::SALOME_Exception);
 580
 581     /*!
 582      * Toggle auto color mode on the object.
 583      * @params
 584      * - theAutoColor : flag which toggles auto color mode.
 585      */
 586     void SetAutoColor(in boolean theAutoColor)
 587       raises (SALOME::SALOME_Exception);
 588
 589     /*!
 590      * Get flag of object's auto color mode.
 591      */
 592     boolean GetAutoColor()
 593       raises (SALOME::SALOME_Exception);
 594
 595     /*!
 596      * Get the internal Id
 597      */
 598     long GetId();
 599
 600     /*!
 601      * Get the study Id
 602      */
 603     long GetStudyId();
 604
 605     /*!
 606      * Obtain instance of SMESH_MeshEditor
 607      */
 608     SMESH_MeshEditor GetMeshEditor()
 609       raises (SALOME::SALOME_Exception);
 610
 611     /*!
 612      * Return SMESH_MeshEditor that would not modify the mesh but
 613      * fill MeshPreviewStruct
 614      */
 615     SMESH_MeshEditor GetMeshEditPreviewer()
 616       raises (SALOME::SALOME_Exception);
 617
 618     /*!
 619      * Return true if the mesh has been edited since a total re-compute
 620      * and those modifications may prevent successful partial re-compute
 621      */
 622     boolean HasModificationsToDiscard()
 623       raises (SALOME::SALOME_Exception);
 624
 625     /*! Check group names for duplications.
 626      *  Consider maximum group name length stored in MED file.
 627      */
 628     boolean HasDuplicatedGroupNamesMED();
 629
 630     /*!
 631      * Export Mesh to a MED Format file
 632      * @params
 633      * - file : name of the MED file
 634      * - auto_groups : boolean parameter for creating/not creating
 635      *                 the groups Group_On_All_Nodes, Group_On_All_Faces, ... ;
 636      *                 the typical use is auto_groups=false.
 637      * - version : defines the version of format of MED file, that will be created
 638      * - overwrite : boolean parameter for overwriting/not overwriting the file, if it exists
 639      * - autoDimension : if @c true, a space dimension of a MED mesh can be either
 640      *         - 1D if all mesh nodes lie on OX coordinate axis, or
 641      *         - 2D if all mesh nodes lie on XOY coordinate plane, or
 642      *         - 3D in the rest cases.
 643      *         If @a autoDimension is @c false, the space dimension is always 3.
 644      */
 645     void ExportToMEDX( in string      file,
 646                        in boolean     auto_groups,
 647                        in MED_VERSION version,
 648                        in boolean     overwrite,
 649                        in boolean     autoDimension) raises (SALOME::SALOME_Exception);
 650
 651     /*!
 652      * Export a [part of] Mesh into a MED file
 653      * @params
 654      * - meshPart : a part of mesh to store
 655      * - file : name of the MED file
 656      * - version : define the version of format of MED file, that will be created
 657      * - overwrite : boolean parameter for overwriting/not overwriting the file, if it exists
 658      * - autoDimension : if @c True, a space dimension for export is defined by mesh
 659      *                 configuration; for example a planar mesh lying on XOY plane
 660      *                 will be exported as a mesh in 2D space.
 661      *                 If @a autoDimension == @c False, the space dimension is 3.
 662      * - fields : list of GEOM fields defined on the shape to mesh.
 663      * - geomAssocFields : each character of this string means a need to export a
 664      *         corresponding field; correspondence between fields and characters is following:
 665      *         - 'v' stands for _vertices_ field;
 666      *         - 'e' stands for _edges_ field;
 667      *         - 'f' stands for _faces_ field;
 668      *         - 's' stands for _solids_ field.
 669      */
 670     void ExportPartToMED( in SMESH_IDSource     meshPart,
 671                           in string             file,
 672                           in boolean            auto_groups,
 673                           in MED_VERSION        version,
 674                           in boolean            overwrite,
 675                           in boolean            autoDimension,
 676                           in GEOM::ListOfFields fields,
 677                           in string             geomAssocFields ) raises (SALOME::SALOME_Exception);
 678
 679     /*!
 680      * Export Mesh to a MED Format file
 681      * Works, just the same as ExportToMEDX, with overwrite parameter equal to true.
 682      * The method is kept in order to support old functionality
 683      */
 684     void ExportToMED( in string file, in boolean auto_groups, in MED_VERSION theVersion )
 685       raises (SALOME::SALOME_Exception);
 686
 687     /*!
 688      * Export Mesh to MED_V2_1 MED format
 689      * Works, just the same as ExportToMEDX with MED_VERSION parameter equal to MED_V2_1
 690      * and overwrite parameter equal to true
 691      * The method is kept in order to support old functionality
 692      */
 693     void ExportMED( in string file, in boolean auto_groups )
 694       raises (SALOME::SALOME_Exception);
 695
 696     /*!
 697      * Export Mesh to SAUV formatted file
 698      * Write a temporary med file and use med2sauv
 699      */
 700     void ExportSAUV( in string file, in boolean auto_groups )
 701       raises (SALOME::SALOME_Exception);
 702
 703     /*!
 704      * Return string representation of a MED file version comprising nbDigits
 705      */
 706     string GetVersionString(in MED_VERSION version, in short nbDigits);
 707
 708     /*!
 709      * Export Mesh to different Formats
 710      * (UNV supported version is I-DEAS 10)
 711      */
 712     void ExportDAT( in string file ) raises (SALOME::SALOME_Exception);
 713     void ExportUNV( in string file ) raises (SALOME::SALOME_Exception);
 714     void ExportSTL( in string  file,
 715                     in boolean isascii ) raises (SALOME::SALOME_Exception);
 716     void ExportCGNS( in SMESH_IDSource meshPart,
 717                      in string         file,
 718                      in boolean        overwrite,
 719                      in boolean        groupElemsByType) raises (SALOME::SALOME_Exception);
 720     void ExportGMF( in SMESH_IDSource  meshPart,
 721                     in string          file,
 722                     in boolean         withRequiredGroups) raises (SALOME::SALOME_Exception);
 723     void ExportPartToDAT( in SMESH_IDSource meshPart,
 724                           in string         file ) raises (SALOME::SALOME_Exception);
 725     void ExportPartToUNV( in SMESH_IDSource meshPart,
 726                           in string         file ) raises (SALOME::SALOME_Exception);
 727     void ExportPartToSTL( in SMESH_IDSource meshPart,
 728                           in string         file,
 729                           in boolean        isascii ) raises (SALOME::SALOME_Exception);
 730     /*!
 731      * Return computation progress [0.,1]
 732      */
 733     double GetComputeProgress();
 734
 735     /*!
 736      * Get informations about mesh contents
 737      */
 738     long NbNodes()
 739       raises (SALOME::SALOME_Exception);
 740
 741     long NbElements()
 742       raises (SALOME::SALOME_Exception);
 743
 744     long Nb0DElements()
 745       raises (SALOME::SALOME_Exception);
 746
 747     long NbBalls()
 748       raises (SALOME::SALOME_Exception);
 749
 750     long NbEdges()
 751       raises (SALOME::SALOME_Exception);
 752
 753     long NbEdgesOfOrder(in ElementOrder order)
 754       raises (SALOME::SALOME_Exception);
 755
 756     long NbFaces()
 757       raises (SALOME::SALOME_Exception);
 758
 759     long NbFacesOfOrder(in ElementOrder order)
 760       raises (SALOME::SALOME_Exception);
 761
 762     long NbTriangles()
 763       raises (SALOME::SALOME_Exception);
 764
 765     long NbTrianglesOfOrder(in ElementOrder order)
 766       raises (SALOME::SALOME_Exception);
 767
 768     long NbBiQuadTriangles()
 769       raises (SALOME::SALOME_Exception);
 770
 771     long NbQuadrangles()
 772       raises (SALOME::SALOME_Exception);
 773
 774     long NbQuadranglesOfOrder(in ElementOrder order)
 775       raises (SALOME::SALOME_Exception);
 776
 777     long NbBiQuadQuadrangles()
 778       raises (SALOME::SALOME_Exception);
 779
 780     long NbPolygons()
 781       raises (SALOME::SALOME_Exception);
 782
 783     long NbPolygonsOfOrder(in ElementOrder order)
 784       raises (SALOME::SALOME_Exception);
 785
 786     long NbVolumes()
 787       raises (SALOME::SALOME_Exception);
 788
 789     long NbVolumesOfOrder(in ElementOrder order)
 790       raises (SALOME::SALOME_Exception);
 791
 792     long NbTetras()
 793       raises (SALOME::SALOME_Exception);
 794
 795     long NbTetrasOfOrder(in ElementOrder order)
 796       raises (SALOME::SALOME_Exception);
 797
 798     long NbHexas()
 799       raises (SALOME::SALOME_Exception);
 800
 801     long NbHexasOfOrder(in ElementOrder order)
 802       raises (SALOME::SALOME_Exception);
 803
 804     long NbTriQuadraticHexas()
 805       raises (SALOME::SALOME_Exception);
 806
 807     long NbPyramids()
 808       raises (SALOME::SALOME_Exception);
 809
 810     long NbPyramidsOfOrder(in ElementOrder order)
 811       raises (SALOME::SALOME_Exception);
 812
 813     long NbPrisms()
 814       raises (SALOME::SALOME_Exception);
 815
 816     long NbPrismsOfOrder(in ElementOrder order)
 817       raises (SALOME::SALOME_Exception);
 818
 819     long NbHexagonalPrisms()
 820       raises (SALOME::SALOME_Exception);
 821
 822     long NbPolyhedrons()
 823       raises (SALOME::SALOME_Exception);
 824
 825     long NbSubMesh()
 826       raises (SALOME::SALOME_Exception);
 827
 828     long_array GetElementsId()
 829       raises (SALOME::SALOME_Exception);
 830
 831     long_array GetElementsByType( in ElementType theType )
 832       raises (SALOME::SALOME_Exception);
 833
 834     long_array GetNodesId()
 835       raises (SALOME::SALOME_Exception);
 836
 837     /*!
 838      * Returns type of mesh element
 839      */
 840     ElementType GetElementType( in long id, in boolean iselem )
 841       raises (SALOME::SALOME_Exception);
 842
 843     EntityType GetElementGeomType( in long id )
 844       raises (SALOME::SALOME_Exception);
 845
 846     GeometryType GetElementShape( in long id )
 847       raises (SALOME::SALOME_Exception);
 848
 849     long_array GetSubMeshElementsId(in long ShapeID)
 850       raises (SALOME::SALOME_Exception);
 851
 852     long_array GetSubMeshNodesId(in long ShapeID, in boolean all )
 853       raises (SALOME::SALOME_Exception);
 854
 855     ElementType GetSubMeshElementType(in long ShapeID)
 856       raises (SALOME::SALOME_Exception);
 857
 858
 859     /*!
 860      * Methods to set meshing order of submeshes
 861      */
 862
 863     /*!
 864      * \brief Return \c true if a meshing order not yet set for a concurrent sub-mesh
 865      */
 866     boolean IsUnorderedSubMesh(in long submeshID);
 867
 868     /*!
 869      * \brief Return submesh objects list in meshing order
 870      */
 871     submesh_array_array GetMeshOrder();
 872
 873     /*!
 874      * \brief Set submesh object order
 875      */
 876     boolean SetMeshOrder(in submesh_array_array theSubMeshArray);
 877
 878
 879     /*!
 880      * Get mesh description
 881      */
 882     string Dump();
 883
 884     /*!
 885      * Get mesh pointer
 886      */
 887     long long GetMeshPtr();
 888
 889     /*!
 890      * Get XYZ coordinates of node as list of double
 891      * If there is not node for given ID - returns empty list
 892      */
 893     double_array GetNodeXYZ(in long id);
 894
 895     /*!
 896      * For given node returns list of IDs of inverse elements
 897      * If there is not node for given ID - returns empty list
 898      */
 899     long_array GetNodeInverseElements(in long id);
 900
 901     /*!
 902      * \brief Return position of a node on shape
 903      */
 904     NodePosition GetNodePosition(in long NodeID);
 905
 906     /*!
 907      * \brief Return position of an element on shape
 908      */
 909     ElementPosition GetElementPosition(in long ElemID);
 910
 911     /*!
 912      * If given element is node returns IDs of shape from position
 913      * If there is not node for given ID - returns -1
 914      */
 915     long GetShapeID(in long id);
 916
 917     /*!
 918      * For given element returns ID of result shape after
 919      * ::FindShape() from SMESH_MeshEditor
 920      * If there is not element for given ID - returns -1
 921      */
 922     long GetShapeIDForElem(in long id);
 923
 924     /*!
 925      * Returns number of nodes for given element
 926      * If there is not element for given ID - returns -1
 927      */
 928     long GetElemNbNodes(in long id);
 929
 930     /*!
 931      * Returns IDs of nodes of given element
 932      */
 933     long_array GetElemNodes(in long id);
 934
 935     /*!
 936      * Returns ID of node by given index for given element
 937      * If there is not element for given ID - returns -1
 938      * If there is not node for given index - returns -2
 939      */
 940     long GetElemNode(in long id, in long index);
 941
 942     /*!
 943      * Returns true if given node is medium node
 944      * in given quadratic element
 945      */
 946     boolean IsMediumNode(in long ide, in long idn);
 947
 948     /*!
 949      * Returns true if given node is medium node
 950      * in one of quadratic elements
 951      */
 952     boolean IsMediumNodeOfAnyElem(in long idn, in ElementType elem_type);
 953
 954     /*!
 955      * Returns number of edges for given element
 956      */
 957     long ElemNbEdges(in long id);
 958
 959     /*!
 960      * Returns number of faces for given element
 961      */
 962     long ElemNbFaces(in long id);
 963
 964     /*!
 965      * Returns nodes of given face (counted from zero) for given volumic element.
 966      */
 967     long_array GetElemFaceNodes(in long elemId, in short faceIndex);
 968
 969     /*!
 970      * Returns three components of normal of given mesh face (or an empty array in KO case)
 971      */
 972     double_array GetFaceNormal(in long faceId, in boolean normalized);
 973
 974     /*!
 975      * Returns an element based on all given nodes.
 976      */
 977     long FindElementByNodes(in long_array nodes);
 978
 979     /*!
 980      * Return elements including all given nodes.
 981      */
 982     long_array GetElementsByNodes(in long_array nodes, in ElementType elem_type);
 983
 984     /*!
 985      * Returns true if given element is polygon
 986      */
 987     boolean IsPoly(in long id);
 988
 989     /*!
 990      * Returns true if given element is quadratic
 991      */
 992     boolean IsQuadratic(in long id);
 993
 994     /*!
 995      * Returns diameter of a ball discrete element or zero in case of an invalid \a id
 996      */
 997     double GetBallDiameter(in long id);
 998
 999     /*!
1000      * Returns XYZ coordinates of bary center for given element
1001      * as list of double
1002      * If there is not element for given ID - returns empty list
1003      */
1004     double_array BaryCenter(in long id);
1005
1006     /*! Gets information about imported MED file */
1007     MedFileInfo GetMEDFileInfo();
1008
1009     /*!
1010      *  Sets list of notebook variables used for Mesh operations separated by ":" symbol
1011      *  \param theParameters is a string containing the notebook variables
1012      */
1013     void SetParameters (in string theParameters);
1014
1015     /*!
1016      *  Returns list of notebook variables used for Mesh operations separated by ":" symbol
1017      */
1018     string GetParameters();
1019
1020     /*!
1021      *  Returns list of notebook variables used for last Mesh operation
1022      */
1023     string_array GetLastParameters();
1024   };
1025
1026   interface SMESH_subMesh : SALOME::GenericObj, SMESH_IDSource
1027   {
1028     /*!
1029      *
1030      */
1031     long GetNumberOfElements()
1032       raises (SALOME::SALOME_Exception);
1033
1034     /*!
1035      *
1036      */
1037     long GetNumberOfNodes( in boolean all )
1038       raises (SALOME::SALOME_Exception);
1039
1040     /*!
1041      *
1042      */
1043     long_array GetElementsId()
1044       raises (SALOME::SALOME_Exception);
1045
1046     /*!
1047      *
1048      */
1049     long_array GetElementsByType( in ElementType theType )
1050       raises (SALOME::SALOME_Exception);
1051
1052     /*!
1053      * Returns type of mesh element (same as SMESH_Mesh::GetElementType() )
1054      */
1055     ElementType GetElementType( in long id, in boolean iselem )
1056       raises (SALOME::SALOME_Exception);
1057
1058     /*!
1059      *
1060      */
1061     long_array GetNodesId()
1062       raises (SALOME::SALOME_Exception);
1063
1064     /*!
1065      * Get geom shape the submesh is dedicated to
1066      */
1067     GEOM::GEOM_Object GetSubShape()
1068       raises (SALOME::SALOME_Exception);
1069
1070     /*!
1071      * Get SMESH_Mesh which stores nodes coordinates & elements definition
1072      */
1073     SMESH_Mesh GetFather()
1074       raises (SALOME::SALOME_Exception);
1075
1076     /*!
1077      * Get the internal Id
1078      */
1079     long GetId();
1080   };
1081
1082 };
1083
1084 #endif