idl/SMESH_Mesh.idl

   1 // Copyright (C) 2007-2013  CEA/DEN, EDF R&D, OPEN CASCADE
   2 //
   3 // Copyright (C) 2003-2007  OPEN CASCADE, EADS/CCR, LIP6, CEA/DEN,
   4 // CEDRAT, EDF R&D, LEG, PRINCIPIA R&D, BUREAU VERITAS
   5 //
   6 // This library is free software; you can redistribute it and/or
   7 // modify it under the terms of the GNU Lesser General Public
   8 // License as published by the Free Software Foundation; either
   9 // version 2.1 of the License.
  10 //
  11 // This library is distributed in the hope that it will be useful,
  12 // but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 // MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14 // Lesser General Public License for more details.
  15 //
  16 // You should have received a copy of the GNU Lesser General Public
  17 // License along with this library; if not, write to the Free Software
  18 // Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
  19 //
  20 // See http://www.salome-platform.org/ or email : webmaster.salome@opencascade.com
  21 //
  22
  23 //  File   : SMESH_Mesh.idl
  24 //  Author : Paul RASCLE, EDF
  25 //
  26 #ifndef _SMESH_MESH_IDL_
  27 #define _SMESH_MESH_IDL_
  28
  29 #include "SALOME_Exception.idl"
  30 #include "SALOME_GenericObj.idl"
  31 #include "GEOM_Gen.idl"
  32
  33 module SMESH
  34 {
  35   interface SMESH_Hypothesis;
  36   typedef sequence<SMESH_Hypothesis> ListOfHypothesis;
  37   interface SMESH_GroupBase;
  38   typedef sequence<SMESH_GroupBase> ListOfGroups;
  39   interface SMESH_IDSource;
  40   typedef sequence<SMESH_IDSource> ListOfIDSources;
  41
  42   typedef sequence<double    > double_array ;
  43   typedef sequence<long      > long_array ;
  44   typedef sequence<string    > string_array ;
  45   typedef sequence<long_array> array_of_long_array ;
  46
  47   enum log_command
  48     {
  49       ADD_NODE,
  50       ADD_EDGE,
  51       ADD_TRIANGLE,
  52       ADD_QUADRANGLE,
  53       ADD_POLYGON,
  54       ADD_TETRAHEDRON,
  55       ADD_PYRAMID,
  56       ADD_PRISM,
  57       ADD_HEXAHEDRON,
  58       ADD_POLYHEDRON,
  59       REMOVE_NODE,
  60       REMOVE_ELEMENT,
  61       MOVE_NODE,
  62       CHANGE_ELEMENT_NODES,
  63       CHANGE_POLYHEDRON_NODES,
  64       RENUMBER,
  65       CLEAR_MESH,
  66       ADD_QUADEDGE,
  67       ADD_QUADTRIANGLE,
  68       ADD_QUADQUADRANGLE,
  69       ADD_QUADTETRAHEDRON,
  70       ADD_QUADPYRAMID,
  71       ADD_QUADPENTAHEDRON,
  72       ADD_QUADHEXAHEDRON,
  73       ADD_ELEM0D,
  74       ADD_BIQUAD_TRIANGLE,
  75       ADD_BIQUAD_QUADRANGLE,
  76       ADD_TRIQUAD_HEXA,
  77       ADD_HEXAGONAL_PRISM,
  78       ADD_BALL
  79     };
  80
  81   struct log_block
  82   {
  83     long commandType;
  84     long number;
  85     double_array coords;
  86     long_array indexes;
  87   };
  88   typedef sequence<log_block> log_array;
  89
  90   struct PointStruct { double x;
  91                        double y;
  92                        double z; } ;
  93
  94   typedef sequence<PointStruct> nodes_array;
  95
  96   struct DirStruct   { PointStruct PS ; } ;          // analog to OCCT gp_Vec
  97
  98   struct AxisStruct  { double x;
  99                        double y;
 100                        double z;
 101                        double vx;
 102                        double vy;
 103                        double vz; } ;
 104   /*!
 105    * Node location on a shape
 106    */
 107   struct NodePosition {
 108     long             shapeID;
 109     GEOM::shape_type shapeType;
 110     double_array     params; // [U] on EDGE, [U,V] on FACE, [] on the rest shapes
 111   };
 112
 113   /*!
 114    * Element location on a shape
 115    */
 116   struct ElementPosition {
 117     long             shapeID;
 118     GEOM::shape_type shapeType;
 119   };
 120
 121   /*!
 122    * Enumeration for element type, like in SMDS
 123    */
 124   enum ElementType
 125   {
 126     ALL,
 127     NODE,
 128     EDGE,
 129     FACE,
 130     VOLUME,
 131     ELEM0D,
 132     BALL
 133   };
 134   typedef sequence<ElementType> array_of_ElementType ;
 135
 136   /*!
 137    * Enumeration for element geometry type, like SMDSAbs_GeometryType in SMDSAbs_ElementType.hxx
 138    */
 139   enum GeometryType
 140   {
 141     Geom_POINT,
 142     Geom_EDGE,
 143     Geom_TRIANGLE,
 144     Geom_QUADRANGLE, // when a new GeometryType is added, please
 145     Geom_POLYGON,    // update a corresponding list in SMESH_2smeshpy.cxx, ln 665
 146     Geom_TETRA,
 147     Geom_PYRAMID,
 148     Geom_HEXA,
 149     Geom_PENTA,
 150     Geom_HEXAGONAL_PRISM,
 151     Geom_POLYHEDRA,
 152     Geom_BALL
 153   };
 154
 155   /*!
 156    * ElementOrder points out entities of what order are requested
 157    */
 158   enum ElementOrder {
 159     ORDER_ANY,          /*! entities of any order */
 160     ORDER_LINEAR,       /*! entities of 1st order */
 161     ORDER_QUADRATIC     /*! entities of 2nd order */
 162   };
 163
 164   /*!
 165    * Enumeration of entity type used in mesh info array,
 166    * it should be synchronised with enum SMDSAbs_EntityType
 167    */
 168   enum EntityType
 169   {
 170     Entity_Node,
 171     Entity_0D,
 172     Entity_Edge,
 173     Entity_Quad_Edge,
 174     Entity_Triangle,
 175     Entity_Quad_Triangle,
 176     Entity_BiQuad_Triangle,
 177     Entity_Quadrangle,
 178     Entity_Quad_Quadrangle,
 179     Entity_BiQuad_Quadrangle,
 180     Entity_Polygon,
 181     Entity_Quad_Polygon,
 182     Entity_Tetra,
 183     Entity_Quad_Tetra,
 184     Entity_Pyramid,
 185     Entity_Quad_Pyramid,
 186     Entity_Hexa,
 187     Entity_Quad_Hexa,
 188     Entity_TriQuad_Hexa,
 189     Entity_Penta,
 190     Entity_Quad_Penta,
 191     Entity_Hexagonal_Prism,
 192     Entity_Polyhedra,
 193     Entity_Quad_Polyhedra,
 194     Entity_Ball,
 195     Entity_Last
 196   };
 197
 198   /*!
 199    * Enumeration for hypothesis status (used by AddHypothesis() and RemoveHypothesis() methods)
 200    */
 201   enum Hypothesis_Status // in the order of severity
 202   {
 203     HYP_OK,
 204     HYP_MISSING,      // algo misses a hypothesis
 205     HYP_CONCURENT,    // several applicable hypotheses
 206     HYP_BAD_PARAMETER,// hypothesis has a bad parameter value
 207     HYP_HIDDEN_ALGO,  // an algo is hidden by an upper dim algo generating all-dim elements
 208     HYP_HIDING_ALGO,  // an algo hides lower dim algos by generating all-dim elements
 209     HYP_UNKNOWN_FATAL,//  --- all statuses below should be considered as fatal
 210                       //      for Add/RemoveHypothesis operations
 211     HYP_INCOMPATIBLE, // hypothesis does not fit algo
 212     HYP_NOTCONFORM,   // not conform mesh is produced appling a hypothesis
 213     HYP_ALREADY_EXIST,// such hypothesis already exist
 214     HYP_BAD_DIM,      // bad dimension
 215     HYP_BAD_SUBSHAPE, // shape is neither the main one, nor its sub-shape, nor a group
 216     HYP_BAD_GEOMETRY, // geometry mismatches algorithm's expectation
 217     HYP_NEED_SHAPE    // algorithm can work on shape only
 218   };
 219
 220   /*!
 221    * Enumeration for mesh read status (used by SMESH_Gen::CreateMeshesFrom*() methods)
 222    */
 223   enum DriverMED_ReadStatus // in the order of severity
 224   {
 225     DRS_OK,
 226     DRS_EMPTY,          // a file contains no mesh with the given name
 227     DRS_WARN_RENUMBER,  // a MED file has overlapped ranges of element numbers,
 228                         // so the numbers from the file are ignored
 229     DRS_WARN_SKIP_ELEM, // some elements were skipped due to incorrect file data
 230     DRS_WARN_DESCENDING, // some elements were skipped due to descending connectivity
 231     DRS_FAIL            // general failure (exception etc.)
 232   };
 233
 234   /*!
 235    * Enumeration for ExportToMED*()
 236    */
 237   enum MED_VERSION
 238   {
 239     MED_V2_1,
 240     MED_V2_2
 241   };
 242
 243   /*!
 244    * \brief A structure containing information about MED file
 245    */
 246   struct MedFileInfo
 247   {
 248     string fileName; //!< name of file
 249     long   fileSize; //!< size of file
 250     long   major, minor, release; //!< MED file version
 251   };
 252
 253   /*!
 254    * Auxilary flags for advanced extrusion.
 255    * BOUNDARY: create or not boundary for result of extrusion
 256    * SEW:      try to use existing nodes or create new nodes in any case
 257    */
 258   const long EXTRUSION_FLAG_BOUNDARY = 1;
 259   const long EXTRUSION_FLAG_SEW = 2;
 260
 261   /*!
 262    * Structure used in mesh edit preview data (MeshPreviewStruct)
 263    */
 264   struct ElementSubType { ElementType SMDS_ElementType;
 265                           boolean     isPoly;
 266                           long        nbNodesInElement; };
 267
 268   typedef sequence<ElementSubType> types_array;
 269
 270   /*!
 271    * Structure containing mesh edit preview data
 272    */
 273   struct MeshPreviewStruct { nodes_array nodesXYZ;
 274                              long_array  elementConnectivities;
 275                              types_array elementTypes; };
 276
 277   interface SMESH_Mesh;
 278
 279   interface SMESH_IDSource
 280   {
 281     /*!
 282      * Returns a sequence of all element IDs
 283      */
 284     long_array GetIDs();
 285
 286     /*!
 287      * Returns statistic of mesh elements
 288      * @return array of number enityties by index of EntityType
 289      */
 290     long_array GetMeshInfo();
 291
 292     /*!
 293      * Returns types of elements it contains.
 294      * It's empty if the SMESH_IDSource contains no IDs
 295      */
 296     array_of_ElementType GetTypes();
 297
 298     /*!
 299      * Returns the mesh
 300      */
 301     SMESH_Mesh GetMesh();
 302
 303     /*!
 304      * Returns false if GetMeshInfo() returns incorrect information that may
 305      * happen if mesh data is not yet fully loaded from the file of study.
 306      */
 307     boolean IsMeshInfoCorrect();
 308   };
 309
 310   interface SMESH_Group;
 311   interface SMESH_GroupOnGeom;
 312   interface Filter;
 313   interface SMESH_GroupOnFilter;
 314   interface SMESH_subMesh;
 315   interface SMESH_MeshEditor;
 316
 317   typedef sequence<SMESH_subMesh>     submesh_array;
 318   typedef sequence<submesh_array>     submesh_array_array;
 319
 320   interface SMESH_Mesh : SALOME::GenericObj, SMESH_IDSource
 321   {
 322     /*!
 323      * Return true if there is a geometry to be meshed
 324      */
 325     boolean HasShapeToMesh()
 326       raises (SALOME::SALOME_Exception);
 327
 328     /*!
 329      * Get geom shape to mesh. A result sould not be nil. Use HasShapeToMesh()
 330      * to know if a returned shape
 331      */
 332     GEOM::GEOM_Object GetShapeToMesh()
 333       raises (SALOME::SALOME_Exception);
 334
 335     /*!
 336      * Return false if the mesh is not yet fully loaded from the study file
 337      */
 338     boolean IsLoaded()
 339       raises (SALOME::SALOME_Exception);
 340
 341     /*!
 342      * Load full mesh data from the study file
 343      */
 344     void Load()
 345       raises (SALOME::SALOME_Exception);
 346
 347     /*!
 348      * Remove all nodes and elements
 349      */
 350     void Clear()
 351       raises (SALOME::SALOME_Exception);
 352
 353     /*!
 354      *  Get the list of sub-meshes existing in the mesh
 355      */
 356     submesh_array GetSubMeshes()
 357       raises (SALOME::SALOME_Exception);
 358
 359     /*!
 360      * Remove all nodes and elements of submesh
 361      */
 362     void ClearSubMesh(in long ShapeID)
 363       raises (SALOME::SALOME_Exception);
 364
 365     /*!
 366      * Get the subMesh object associated to a Sub-shape. The subMesh object
 367      * gives access to nodes and elements IDs.
 368      * SubMesh will be used instead of Sub-shape in a next idl version to
 369      * adress a specific subMesh...
 370      */
 371     SMESH_subMesh GetSubMesh(in GEOM::GEOM_Object aSubObject, in string name)
 372       raises (SALOME::SALOME_Exception);
 373
 374     /*!
 375      * Remove a submesh
 376      */
 377     void RemoveSubMesh(in SMESH_subMesh aSubMesh)
 378       raises (SALOME::SALOME_Exception);
 379
 380
 381     /*!
 382      * Create a group
 383      */
 384     SMESH_Group CreateGroup( in ElementType elem_type,
 385                              in string      name )
 386       raises (SALOME::SALOME_Exception);
 387
 388     /*!
 389      * Create a group from geometry
 390      */
 391     SMESH_GroupOnGeom CreateGroupFromGEOM( in ElementType       elemType,
 392                                            in string            name,
 393                                            in GEOM::GEOM_Object geomObject )
 394       raises (SALOME::SALOME_Exception);
 395
 396     /*!
 397      * Create a group from filter
 398      */
 399     SMESH_GroupOnFilter CreateGroupFromFilter( in ElementType   elemType,
 400                                                in string        name,
 401                                                in SMESH::Filter filter )
 402       raises (SALOME::SALOME_Exception);
 403
 404     /*!
 405      * Remove a group
 406      */
 407     void RemoveGroup(in SMESH_GroupBase aGroup)
 408       raises (SALOME::SALOME_Exception);
 409
 410     /*!
 411      *  Remove group with its contents
 412      */
 413     void RemoveGroupWithContents( in SMESH_GroupBase aGroup )
 414       raises (SALOME::SALOME_Exception);
 415
 416     /*!
 417      *  Get the list of groups existing in the mesh
 418      */
 419     ListOfGroups GetGroups()
 420       raises (SALOME::SALOME_Exception);
 421
 422     /*!
 423      *  Get number of groups existing in the mesh
 424      */
 425     long NbGroups()
 426       raises (SALOME::SALOME_Exception);
 427
 428     /*!
 429      * Union of two groups
 430      *    New group is created. All mesh elements that are
 431      *    present in initial groups are added to the new one
 432      */
 433     SMESH_Group UnionGroups (in SMESH_GroupBase aGroup1,
 434                              in SMESH_GroupBase aGroup2,
 435                              in string          name )
 436       raises (SALOME::SALOME_Exception);
 437
 438     /*!
 439      * Union of list of groups
 440      * New group is created. All mesh elements that are
 441      * present in initial groups are added to the new one
 442      */
 443     SMESH_Group UnionListOfGroups (in ListOfGroups aListOfGroups,
 444                                    in string       name )
 445       raises (SALOME::SALOME_Exception);
 446
 447     /*!
 448      *  Intersection of two groups
 449      *  New group is created. All mesh elements that are
 450      *  present in both initial groups are added to the new one.
 451      */
 452     SMESH_Group IntersectGroups (in SMESH_GroupBase aGroup1,
 453                                  in SMESH_GroupBase aGroup2,
 454                                  in string          name )
 455       raises (SALOME::SALOME_Exception);
 456
 457     /*!
 458      *  Intersection of list of groups
 459      *  New group is created. All mesh elements that are
 460      *  present in all initial groups simultaneously are added to the new one.
 461      */
 462     SMESH_Group IntersectListOfGroups (in ListOfGroups aListOfGroups,
 463                                        in string       name)
 464       raises (SALOME::SALOME_Exception);
 465
 466     /*!
 467      *  Cut of two groups
 468      *  New group is created. All mesh elements that are present in
 469      *  main group but do not present in tool group are added to the new one
 470      */
 471     SMESH_Group CutGroups (in SMESH_GroupBase aMainGroup,
 472                            in SMESH_GroupBase aToolGroup,
 473                            in string          name )
 474       raises (SALOME::SALOME_Exception);
 475
 476     /*!
 477      *  Cut of lists of groups
 478      *  New group is created. All mesh elements that are present in
 479      *  main groups but do not present in tool groups are added to the new one
 480      */
 481     SMESH_Group CutListOfGroups (in ListOfGroups aMainGroups,
 482                                  in ListOfGroups aToolGroups,
 483                                  in string       name)
 484       raises (SALOME::SALOME_Exception);
 485
 486     /*!
 487      *  Create groups of entities from existing groups of superior dimensions
 488      *  New group is created. System
 489      *  1) extracts all nodes from each group,
 490      *  2) combines all elements of specified dimension laying on these nodes.
 491      */
 492     SMESH_Group CreateDimGroup( in ListOfGroups aListOfGroups,
 493                                 in ElementType  anElemType,
 494                                 in string       name )
 495       raises (SALOME::SALOME_Exception);
 496
 497     /*!
 498      * Convert group on geometry or on filter into standalone group
 499      */
 500     SMESH_Group ConvertToStandalone( in SMESH_GroupBase theGroupOn )
 501       raises (SALOME::SALOME_Exception);
 502
 503     /*!
 504      * Add hypothesis to the mesh, under a particular Sub-shape
 505      * (or the main shape itself)
 506      * The Add method is only used to prepare the build of the mesh and store
 507      * the algorithms and associated parameters.
 508      * Actual job of mesh the shape is done by MESH_Gen.
 509      * @params
 510      * - aSubShape : sub-shape obtained by a shape explode in GEOM
 511      *   (or main shape)
 512      * - anHyp : hypothesis object
 513      * @return
 514      * - OK if the hypothesis is compatible with the sub-shape
 515      *   (and all previous hypothesis on the sub-shape)
 516      * - NOK if the hypothesis is not compatible with the sub-shape
 517      *   (or one previous hypothesis on the sub-shape)
 518      * raises exception if hypothesis has not been created
 519      */
 520     Hypothesis_Status AddHypothesis(in GEOM::GEOM_Object aSubObject,
 521                                     in SMESH_Hypothesis anHyp)
 522       raises (SALOME::SALOME_Exception);
 523
 524     /*!
 525      * Remove an hypothesis previouly added with AddHypothesis.
 526      */
 527     Hypothesis_Status RemoveHypothesis(in GEOM::GEOM_Object aSubObject,
 528                                        in SMESH_Hypothesis anHyp)
 529       raises (SALOME::SALOME_Exception);
 530
 531     /*!
 532      * Get the list of hypothesis added on a sub-shape
 533      */
 534     ListOfHypothesis GetHypothesisList(in GEOM::GEOM_Object aSubObject)
 535       raises (SALOME::SALOME_Exception);
 536
 537     /*!
 538      * Get the log of nodes and elements added or removed since previous
 539      * clear of the log.
 540      * @params
 541      * - clearAfterGet : log is emptied after Get (safe if concurrents access)
 542      */
 543     log_array GetLog(in boolean clearAfterGet)
 544       raises (SALOME::SALOME_Exception);
 545
 546     /*!
 547      * Clear the log of nodes and elements added or removed since previous
 548      * clear. Must be used immediately after GetLog if clearAfterGet is false.
 549      */
 550     void ClearLog()
 551       raises (SALOME::SALOME_Exception);
 552
 553     /*!
 554      * Toggle auto color mode on the object.
 555      * @params
 556      * - theAutoColor : flag which toggles auto color mode.
 557      */
 558     void SetAutoColor(in boolean theAutoColor)
 559       raises (SALOME::SALOME_Exception);
 560
 561     /*!
 562      * Get flag of object's auto color mode.
 563      */
 564     boolean GetAutoColor()
 565       raises (SALOME::SALOME_Exception);
 566
 567     /*!
 568      * Get the internal Id
 569      */
 570     long GetId();
 571
 572     /*!
 573      * Get the study Id
 574      */
 575     long GetStudyId();
 576
 577     /*!
 578      * Obtain instance of SMESH_MeshEditor
 579      */
 580     SMESH_MeshEditor GetMeshEditor()
 581       raises (SALOME::SALOME_Exception);
 582
 583     /*!
 584      * Return SMESH_MeshEditor that would not modify the mesh but
 585      * fill MeshPreviewStruct
 586      */
 587     SMESH_MeshEditor GetMeshEditPreviewer()
 588       raises (SALOME::SALOME_Exception);
 589
 590     /*!
 591      * Return true if the mesh has been edited since a total re-compute
 592      * and those modifications may prevent successful partial re-compute
 593      */
 594     boolean HasModificationsToDiscard()
 595       raises (SALOME::SALOME_Exception);
 596
 597     /*! Check group names for duplications.
 598      *  Consider maximum group name length stored in MED file.
 599      */
 600     boolean HasDuplicatedGroupNamesMED();
 601
 602     /*!
 603      * Export Mesh to a MED Format file
 604      * @params
 605      * - file : name of the MED file
 606      * - auto_groups : boolean parameter for creating/not creating
 607      *                 the groups Group_On_All_Nodes, Group_On_All_Faces, ... ;
 608      *                 the typical use is auto_groups=false.
 609      * - version : define the version of format of MED file, that will be created
 610      * - overwrite : boolean parameter for overwriting/not overwriting the file, if it exists
 611      * - autoDimension: if @c True (default), a space dimension of a MED mesh can be either
 612      *         - 1D if all mesh nodes lie on OX coordinate axis, or
 613      *         - 2D if all mesh nodes lie on XOY coordinate plane, or
 614      *         - 3D in the rest cases.
 615      *
 616      *         If @a autoDimension is @c False, the space dimension is always 3.
 617      */
 618     void ExportToMEDX( in string      file,
 619                        in boolean     auto_groups,
 620                        in MED_VERSION version,
 621                        in boolean     overwrite,
 622                        in boolean     autoDimension ) raises (SALOME::SALOME_Exception);
 623
 624     /*!
 625      * Export a part of Mesh into a MED file
 626      * @params
 627      * - meshPart : a part of mesh to store
 628      * - file : name of the MED file
 629      * - version : define the version of format of MED file, that will be created
 630      * - overwrite : boolean parameter for overwriting/not overwriting the file, if it exists
 631      * - autoDimension: if @c True, a space dimension for export is defined by mesh
 632      *                 configuration; for example a planar mesh lying on XOY plane
 633      *                 will be exported as a mesh in 2D space.
 634      *                 If @a autoDimension == @c False, the space dimension is 3.
 635      */
 636     void ExportPartToMED( in SMESH_IDSource meshPart,
 637                           in string         file,
 638                           in boolean        auto_groups,
 639                           in MED_VERSION    version,
 640                           in boolean        overwrite,
 641                           in boolean        autoDimension ) raises (SALOME::SALOME_Exception);
 642
 643     /*!
 644      * Export Mesh to a MED Format file
 645      * Works, just the same as ExportToMEDX, with overwrite parameter equal to true.
 646      * The method is kept in order to support old functionality
 647      */
 648     void ExportToMED( in string file, in boolean auto_groups, in MED_VERSION theVersion )
 649       raises (SALOME::SALOME_Exception);
 650
 651     /*!
 652      * Export Mesh to MED_V2_1 MED format
 653      * Works, just the same as ExportToMEDX with MED_VERSION parameter equal to MED_V2_1
 654      * and overwrite parameter equal to true
 655      * The method is kept in order to support old functionality
 656      */
 657     void ExportMED( in string file, in boolean auto_groups )
 658       raises (SALOME::SALOME_Exception);
 659
 660     /*!
 661      * Export Mesh to SAUV formatted file
 662      * Write a temporary med file and use med2sauv
 663      */
 664     void ExportSAUV( in string file, in boolean auto_groups )
 665       raises (SALOME::SALOME_Exception);
 666
 667     /*!
 668      * Return string representation of a MED file version comprising nbDigits
 669      */
 670     string GetVersionString(in MED_VERSION version, in short nbDigits);
 671
 672     /*!
 673      * Export Mesh to different Formats
 674      * (UNV supported version is I-DEAS 10)
 675      */
 676     void ExportDAT( in string file ) raises (SALOME::SALOME_Exception);
 677     void ExportUNV( in string file ) raises (SALOME::SALOME_Exception);
 678     void ExportSTL( in string  file,
 679                     in boolean isascii ) raises (SALOME::SALOME_Exception);
 680     void ExportCGNS( in SMESH_IDSource meshPart,
 681                      in string         file,
 682                      in boolean        overwrite ) raises (SALOME::SALOME_Exception);
 683     void ExportGMF( in SMESH_IDSource  meshPart,
 684                     in string          file,
 685                     in boolean         withRequiredGroups) raises (SALOME::SALOME_Exception);
 686     void ExportPartToDAT( in SMESH_IDSource meshPart,
 687                           in string         file ) raises (SALOME::SALOME_Exception);
 688     void ExportPartToUNV( in SMESH_IDSource meshPart,
 689                           in string         file ) raises (SALOME::SALOME_Exception);
 690     void ExportPartToSTL( in SMESH_IDSource meshPart,
 691                           in string         file,
 692                           in boolean        isascii ) raises (SALOME::SALOME_Exception);
 693
 694     /*!
 695      * Get informations about mesh contents
 696      */
 697     long NbNodes()
 698       raises (SALOME::SALOME_Exception);
 699
 700     long NbElements()
 701       raises (SALOME::SALOME_Exception);
 702
 703     long Nb0DElements()
 704       raises (SALOME::SALOME_Exception);
 705
 706     long NbBalls()
 707       raises (SALOME::SALOME_Exception);
 708
 709     long NbEdges()
 710       raises (SALOME::SALOME_Exception);
 711
 712     long NbEdgesOfOrder(in ElementOrder order)
 713       raises (SALOME::SALOME_Exception);
 714
 715     long NbFaces()
 716       raises (SALOME::SALOME_Exception);
 717
 718     long NbFacesOfOrder(in ElementOrder order)
 719       raises (SALOME::SALOME_Exception);
 720
 721     long NbTriangles()
 722       raises (SALOME::SALOME_Exception);
 723
 724     long NbTrianglesOfOrder(in ElementOrder order)
 725       raises (SALOME::SALOME_Exception);
 726
 727     long NbBiQuadTriangles()
 728       raises (SALOME::SALOME_Exception);
 729
 730     long NbQuadrangles()
 731       raises (SALOME::SALOME_Exception);
 732
 733     long NbQuadranglesOfOrder(in ElementOrder order)
 734       raises (SALOME::SALOME_Exception);
 735
 736     long NbBiQuadQuadrangles()
 737       raises (SALOME::SALOME_Exception);
 738
 739     long NbPolygons()
 740       raises (SALOME::SALOME_Exception);
 741
 742     long NbVolumes()
 743       raises (SALOME::SALOME_Exception);
 744
 745     long NbVolumesOfOrder(in ElementOrder order)
 746       raises (SALOME::SALOME_Exception);
 747
 748     long NbTetras()
 749       raises (SALOME::SALOME_Exception);
 750
 751     long NbTetrasOfOrder(in ElementOrder order)
 752       raises (SALOME::SALOME_Exception);
 753
 754     long NbHexas()
 755       raises (SALOME::SALOME_Exception);
 756
 757     long NbHexasOfOrder(in ElementOrder order)
 758       raises (SALOME::SALOME_Exception);
 759
 760     long NbTriQuadraticHexas()
 761       raises (SALOME::SALOME_Exception);
 762
 763     long NbPyramids()
 764       raises (SALOME::SALOME_Exception);
 765
 766     long NbPyramidsOfOrder(in ElementOrder order)
 767       raises (SALOME::SALOME_Exception);
 768
 769     long NbPrisms()
 770       raises (SALOME::SALOME_Exception);
 771
 772     long NbPrismsOfOrder(in ElementOrder order)
 773       raises (SALOME::SALOME_Exception);
 774
 775     long NbHexagonalPrisms()
 776       raises (SALOME::SALOME_Exception);
 777
 778     long NbPolyhedrons()
 779       raises (SALOME::SALOME_Exception);
 780
 781     long NbSubMesh()
 782       raises (SALOME::SALOME_Exception);
 783
 784     long_array GetElementsId()
 785       raises (SALOME::SALOME_Exception);
 786
 787     long_array GetElementsByType( in ElementType theType )
 788       raises (SALOME::SALOME_Exception);
 789
 790     long_array GetNodesId()
 791       raises (SALOME::SALOME_Exception);
 792
 793     /*!
 794      * Returns type of mesh element
 795      */
 796     ElementType GetElementType( in long id, in boolean iselem )
 797       raises (SALOME::SALOME_Exception);
 798
 799     EntityType GetElementGeomType( in long id )
 800       raises (SALOME::SALOME_Exception);
 801
 802     long_array GetSubMeshElementsId(in long ShapeID)
 803       raises (SALOME::SALOME_Exception);
 804
 805     long_array GetSubMeshNodesId(in long ShapeID, in boolean all )
 806       raises (SALOME::SALOME_Exception);
 807
 808     ElementType GetSubMeshElementType(in long ShapeID)
 809       raises (SALOME::SALOME_Exception);
 810
 811
 812     /*!
 813      * Methods to set meshing order of submeshes
 814      */
 815
 816     /*!
 817      * \brief Return submesh objects list in meshing order
 818      */
 819     submesh_array_array GetMeshOrder();
 820
 821     /*!
 822      * \brief Set submesh object order
 823      */
 824     boolean SetMeshOrder(in submesh_array_array theSubMeshArray);
 825
 826
 827     /*!
 828      * Get mesh description
 829      */
 830     string Dump();
 831
 832     /*!
 833      * Get mesh pointer
 834      */
 835     long long GetMeshPtr();
 836
 837     /*!
 838      * Get XYZ coordinates of node as list of double
 839      * If there is not node for given ID - returns empty list
 840      */
 841     double_array GetNodeXYZ(in long id);
 842
 843     /*!
 844      * For given node returns list of IDs of inverse elements
 845      * If there is not node for given ID - returns empty list
 846      */
 847     long_array GetNodeInverseElements(in long id);
 848
 849     /*!
 850      * \brief Return position of a node on shape
 851      */
 852     NodePosition GetNodePosition(in long NodeID);
 853
 854     /*!
 855      * \brief Return position of an element on shape
 856      */
 857     ElementPosition GetElementPosition(in long ElemID);
 858
 859     /*!
 860      * If given element is node returns IDs of shape from position
 861      * If there is not node for given ID - returns -1
 862      */
 863     long GetShapeID(in long id);
 864
 865     /*!
 866      * For given element returns ID of result shape after
 867      * ::FindShape() from SMESH_MeshEditor
 868      * If there is not element for given ID - returns -1
 869      */
 870     long GetShapeIDForElem(in long id);
 871
 872     /*!
 873      * Returns number of nodes for given element
 874      * If there is not element for given ID - returns -1
 875      */
 876     long GetElemNbNodes(in long id);
 877
 878     /*!
 879      * Returns IDs of nodes of given element
 880      */
 881     long_array GetElemNodes(in long id);
 882
 883     /*!
 884      * Returns ID of node by given index for given element
 885      * If there is not element for given ID - returns -1
 886      * If there is not node for given index - returns -2
 887      */
 888     long GetElemNode(in long id, in long index);
 889
 890     /*!
 891      * Returns true if given node is medium node
 892      * in given quadratic element
 893      */
 894     boolean IsMediumNode(in long ide, in long idn);
 895
 896     /*!
 897      * Returns true if given node is medium node
 898      * in one of quadratic elements
 899      */
 900     boolean IsMediumNodeOfAnyElem(in long idn, in ElementType elem_type);
 901
 902     /*!
 903      * Returns number of edges for given element
 904      */
 905     long ElemNbEdges(in long id);
 906
 907     /*!
 908      * Returns number of faces for given element
 909      */
 910     long ElemNbFaces(in long id);
 911
 912     /*!
 913      * Returns nodes of given face (counted from zero) for given volumic element.
 914      */
 915     long_array GetElemFaceNodes(in long elemId, in short faceIndex);
 916
 917     /*!
 918      * Returns an element based on all given nodes.
 919      */
 920     long FindElementByNodes(in long_array nodes);
 921
 922     /*!
 923      * Returns true if given element is polygon
 924      */
 925     boolean IsPoly(in long id);
 926
 927     /*!
 928      * Returns true if given element is quadratic
 929      */
 930     boolean IsQuadratic(in long id);
 931
 932     /*!
 933      * Returns diameter of a ball discrete element or zero in case of an invalid \a id
 934      */
 935     double GetBallDiameter(in long id);
 936
 937     /*!
 938      * Returns XYZ coordinates of bary center for given element
 939      * as list of double
 940      * If there is not element for given ID - returns empty list
 941      */
 942     double_array BaryCenter(in long id);
 943
 944     /*! Gets information about imported MED file */
 945     MedFileInfo GetMEDFileInfo();
 946
 947     /*!
 948      *  Sets list of notebook variables used for Mesh operations separated by ":" symbol
 949      *  \param theParameters is a string containing the notebook variables
 950      */
 951     void SetParameters (in string theParameters);
 952
 953     /*!
 954      *  Returns list of notebook variables used for Mesh operations separated by ":" symbol
 955      */
 956     string GetParameters();
 957
 958     /*!
 959      *  Returns list of notebook variables used for last Mesh operation
 960      */
 961     string_array GetLastParameters();
 962   };
 963
 964   interface SMESH_subMesh : SALOME::GenericObj, SMESH_IDSource
 965   {
 966     /*!
 967      *
 968      */
 969     long GetNumberOfElements()
 970       raises (SALOME::SALOME_Exception);
 971
 972     /*!
 973      *
 974      */
 975     long GetNumberOfNodes( in boolean all )
 976       raises (SALOME::SALOME_Exception);
 977
 978     /*!
 979      *
 980      */
 981     long_array GetElementsId()
 982       raises (SALOME::SALOME_Exception);
 983
 984     /*!
 985      *
 986      */
 987     long_array GetElementsByType( in ElementType theType )
 988       raises (SALOME::SALOME_Exception);
 989
 990     /*!
 991      * Return type of submesh element
 992      */
 993     ElementType GetElementType( in long id, in boolean iselem )
 994       raises (SALOME::SALOME_Exception);
 995
 996     /*!
 997      *
 998      */
 999     long_array GetNodesId()
1000       raises (SALOME::SALOME_Exception);
1001
1002     /*!
1003      * Get geom shape the submesh is dedicated to
1004      */
1005     GEOM::GEOM_Object GetSubShape()
1006       raises (SALOME::SALOME_Exception);
1007
1008     /*!
1009      * Get SMESH_Mesh which stores nodes coordinates & elements definition
1010      */
1011     SMESH_Mesh GetFather()
1012       raises (SALOME::SALOME_Exception);
1013
1014     /*!
1015      * Get the internal Id
1016      */
1017     long GetId();
1018   };
1019
1020 };
1021
1022 #endif