idl/SMESH_Mesh.idl

   1 // Copyright (C) 2007-2021  CEA/DEN, EDF R&D, OPEN CASCADE
   2 //
   3 // Copyright (C) 2003-2007  OPEN CASCADE, EADS/CCR, LIP6, CEA/DEN,
   4 // CEDRAT, EDF R&D, LEG, PRINCIPIA R&D, BUREAU VERITAS
   5 //
   6 // This library is free software; you can redistribute it and/or
   7 // modify it under the terms of the GNU Lesser General Public
   8 // License as published by the Free Software Foundation; either
   9 // version 2.1 of the License, or (at your option) any later version.
  10 //
  11 // This library is distributed in the hope that it will be useful,
  12 // but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 // MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14 // Lesser General Public License for more details.
  15 //
  16 // You should have received a copy of the GNU Lesser General Public
  17 // License along with this library; if not, write to the Free Software
  18 // Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
  19 //
  20 // See http://www.salome-platform.org/ or email : webmaster.salome@opencascade.com
  21 //
  22
  23 //  File   : SMESH_Mesh.idl
  24 //  Author : Paul RASCLE, EDF
  25 //
  26 #ifndef _SMESH_MESH_IDL_
  27 #define _SMESH_MESH_IDL_
  28
  29 #include "SALOME_Exception.idl"
  30 #include "SALOME_GenericObj.idl"
  31 #include "GEOM_Gen.idl"
  32 #include "SMESH_smIdType.idl"
  33
  34 module SMESH
  35 {
  36   interface SMESH_Hypothesis;
  37   typedef sequence<SMESH_Hypothesis> ListOfHypothesis;
  38   interface SMESH_GroupBase;
  39   typedef sequence<SMESH_GroupBase> ListOfGroups;
  40   interface SMESH_IDSource;
  41   typedef sequence<SMESH_IDSource> ListOfIDSources;
  42
  43   typedef sequence<double    > double_array ;
  44   typedef sequence<long      > long_array ;
  45   typedef sequence<smIdType  > smIdType_array ;
  46   typedef sequence<string    > string_array ;
  47   typedef sequence<long_array> array_of_long_array ;
  48
  49   enum log_command
  50     {
  51       ADD_NODE,
  52       ADD_EDGE,
  53       ADD_TRIANGLE,
  54       ADD_QUADRANGLE,
  55       ADD_POLYGON,
  56       ADD_TETRAHEDRON,
  57       ADD_PYRAMID,
  58       ADD_PRISM,
  59       ADD_HEXAHEDRON,
  60       ADD_POLYHEDRON,
  61       REMOVE_NODE,
  62       REMOVE_ELEMENT,
  63       MOVE_NODE,
  64       CHANGE_ELEMENT_NODES,
  65       CHANGE_POLYHEDRON_NODES,
  66       RENUMBER,
  67       CLEAR_MESH,
  68       ADD_QUADEDGE,
  69       ADD_QUADTRIANGLE,
  70       ADD_QUADQUADRANGLE,
  71       ADD_QUADPOLYGON,
  72       ADD_QUADTETRAHEDRON,
  73       ADD_QUADPYRAMID,
  74       ADD_QUADPENTAHEDRON,
  75       ADD_QUADHEXAHEDRON,
  76       ADD_ELEM0D,
  77       ADD_BIQUAD_TRIANGLE,
  78       ADD_BIQUAD_QUADRANGLE,
  79       ADD_TRIQUAD_HEXA,
  80       ADD_HEXAGONAL_PRISM,
  81       ADD_BALL
  82     };
  83
  84   struct log_block
  85   {
  86     long commandType;
  87     long number;
  88     double_array coords;
  89     long_array indexes;
  90   };
  91   typedef sequence<log_block> log_array;
  92
  93   struct PointStruct { double x;
  94                        double y;
  95                        double z; };
  96
  97   typedef sequence<PointStruct> nodes_array;
  98
  99   struct DirStruct   { PointStruct PS; };          // analog to OCCT gp_Vec
 100
 101   struct AxisStruct  { double x;
 102                        double y;
 103                        double z;
 104                        double vx;
 105                        double vy;
 106                        double vz; };
 107   /*!
 108    * Node location on a shape
 109    */
 110   struct NodePosition {
 111     long             shapeID;
 112     GEOM::shape_type shapeType;
 113     double_array     params; // [U] on EDGE, [U,V] on FACE, [] on the rest shapes
 114   };
 115
 116   /*!
 117    * Element location on a shape
 118    */
 119   struct ElementPosition {
 120     long             shapeID;
 121     GEOM::shape_type shapeType;
 122   };
 123
 124   /*!
 125    * Enumeration for element type, like in SMDS
 126    */
 127   enum ElementType
 128   {
 129     ALL,
 130     NODE,
 131     EDGE,
 132     FACE,
 133     VOLUME,
 134     ELEM0D,
 135     BALL,
 136     NB_ELEMENT_TYPES
 137   };
 138   typedef sequence<ElementType> array_of_ElementType;
 139
 140   /*!
 141    * Enumeration for element geometry type, like SMDSAbs_GeometryType in SMDSAbs_ElementType.hxx
 142    */
 143   enum GeometryType
 144   {
 145     Geom_POINT,
 146     Geom_EDGE,
 147     Geom_TRIANGLE,
 148     Geom_QUADRANGLE, // when a new GeometryType is added, please
 149     Geom_POLYGON,    // update a corresponding list in SMESH_2smeshpy.cxx, ln 665
 150     Geom_TETRA,
 151     Geom_PYRAMID,
 152     Geom_HEXA,
 153     Geom_PENTA,
 154     Geom_HEXAGONAL_PRISM,
 155     Geom_POLYHEDRA,
 156     Geom_BALL,
 157     Geom_LAST
 158   };
 159
 160   /*!
 161    * ElementOrder points out entities of what order are requested
 162    */
 163   enum ElementOrder {
 164     ORDER_ANY,          /*! entities of any order */
 165     ORDER_LINEAR,       /*! entities of 1st order */
 166     ORDER_QUADRATIC     /*! entities of 2nd order */
 167   };
 168
 169   /*!
 170    * Enumeration of entity type used in mesh info array,
 171    * it should be synchronised with enum SMDSAbs_EntityType
 172    */
 173   enum EntityType
 174   {
 175     Entity_Node,
 176     Entity_0D,
 177     Entity_Edge,
 178     Entity_Quad_Edge,
 179     Entity_Triangle,
 180     Entity_Quad_Triangle,
 181     Entity_BiQuad_Triangle,
 182     Entity_Quadrangle,
 183     Entity_Quad_Quadrangle,
 184     Entity_BiQuad_Quadrangle,
 185     Entity_Polygon,
 186     Entity_Quad_Polygon,
 187     Entity_Tetra,
 188     Entity_Quad_Tetra,
 189     Entity_Pyramid,
 190     Entity_Quad_Pyramid,
 191     Entity_Hexa,
 192     Entity_Quad_Hexa,
 193     Entity_TriQuad_Hexa,
 194     Entity_Penta,
 195     Entity_Quad_Penta,
 196     Entity_BiQuad_Penta,
 197     Entity_Hexagonal_Prism,
 198     Entity_Polyhedra,
 199     Entity_Quad_Polyhedra,
 200     Entity_Ball,
 201     Entity_Last
 202   };
 203
 204   /*!
 205    * Enumeration for hypothesis status (used by AddHypothesis() and RemoveHypothesis() methods)
 206    */
 207   enum Hypothesis_Status // in the order of severity
 208   {
 209     HYP_OK,
 210     HYP_MISSING,      // algo misses a hypothesis
 211     HYP_CONCURRENT,   // several applicable hypotheses
 212     HYP_BAD_PARAMETER,// hypothesis has a bad parameter value
 213     HYP_HIDDEN_ALGO,  // an algo is hidden by an upper dim algo generating all-dim elements
 214     HYP_HIDING_ALGO,  // an algo hides lower dim algos by generating all-dim elements
 215     HYP_UNKNOWN_FATAL,//  --- all statuses below should be considered as fatal
 216                       //      for Add/RemoveHypothesis operations
 217     HYP_INCOMPATIBLE, // hypothesis does not fit algo
 218     HYP_NOTCONFORM,   // not conform mesh is produced applying a hypothesis
 219     HYP_ALREADY_EXIST,// such hypothesis already exist
 220     HYP_BAD_DIM,      // bad dimension
 221     HYP_BAD_SUBSHAPE, // shape is neither the main one, nor its sub-shape, nor a group
 222     HYP_BAD_GEOMETRY, // geometry mismatches algorithm's expectation
 223     HYP_NEED_SHAPE,   // algorithm can work on shape only
 224     HYP_INCOMPAT_HYPS // several additional hypotheses are incompatible one with other
 225   };
 226
 227   /*!
 228    * Enumeration for mesh read status (used by SMESH_Gen::CreateMeshesFrom*() methods)
 229    */
 230   enum DriverMED_ReadStatus // in the order of severity
 231   {
 232     DRS_OK,
 233     DRS_EMPTY,           // a file contains no mesh with the given name
 234     DRS_WARN_RENUMBER,   // a MED file has overlapped ranges of element numbers,
 235                          // so the numbers from the file are ignored
 236     DRS_WARN_SKIP_ELEM,  // some elements were skipped due to incorrect file data
 237     DRS_WARN_DESCENDING, // some elements were skipped due to descending connectivity
 238     DRS_FAIL             // general failure (exception etc.)
 239   };
 240
 241   /*!
 242    * \brief A structure containing information about MED file
 243    */
 244   struct MedFileInfo
 245   {
 246     string fileName; //!< name of file
 247     long   fileSize; //!< size of file
 248     long   major, minor, release; //!< MED file version
 249   };
 250
 251   /*!
 252    * Enumeration for CreateDimGroup()
 253    */
 254   enum NB_COMMON_NODES_ENUM
 255   {
 256     ALL_NODES, MAIN, AT_LEAST_ONE, MAJORITY
 257   };
 258
 259   /*!
 260    * Auxiliary flags for advanced extrusion.
 261    * BOUNDARY: create or not boundary for result of extrusion
 262    * SEW:      try to use existing nodes or create new nodes in any case
 263    */
 264   const long EXTRUSION_FLAG_BOUNDARY = 1;
 265   const long EXTRUSION_FLAG_SEW = 2;
 266
 267   /*!
 268    * Structure used in mesh edit preview data (MeshPreviewStruct)
 269    */
 270   struct ElementSubType { ElementType SMDS_ElementType;
 271                           boolean     isPoly;
 272                           short       nbNodesInElement; };
 273
 274   typedef sequence<ElementSubType> types_array;
 275
 276   /*!
 277    * Structure containing mesh edit preview data
 278    */
 279   struct MeshPreviewStruct { nodes_array nodesXYZ;
 280                              long_array  elementConnectivities;
 281                              types_array elementTypes; };
 282
 283   interface SMESH_Mesh;
 284
 285   interface SMESH_IDSource : SALOME::GenericObj
 286   {
 287     /*!
 288      * Returns a sequence of all element IDs
 289      */
 290     smIdType_array GetIDs();
 291
 292     /*!
 293      * Returns number of mesh elements of each \a EntityType
 294      * @return array of number of elements per \a EntityType
 295      */
 296     smIdType_array GetMeshInfo();
 297
 298     /*!
 299      * Returns number of mesh elements of each \a ElementType
 300      * @return array of number of elements per \a ElementType
 301      */
 302     smIdType_array GetNbElementsByType();
 303
 304     /*!
 305      * Returns types of elements it contains.
 306      * It's empty if the SMESH_IDSource contains no IDs
 307      */
 308     array_of_ElementType GetTypes();
 309
 310     /*!
 311      * Returns the mesh
 312      */
 313     SMESH_Mesh GetMesh();
 314
 315     /*!
 316      * Returns false if GetMeshInfo() returns incorrect information that may
 317      * happen if mesh data is not yet fully loaded from the file of study.
 318      */
 319     boolean IsMeshInfoCorrect();
 320
 321     /*!
 322      * Returns mesh unstructed grid information.
 323      */
 324     SALOMEDS::TMPFile GetVtkUgStream();
 325   };
 326
 327   interface SMESH_Group;
 328   interface SMESH_GroupOnGeom;
 329   interface Filter;
 330   interface SMESH_GroupOnFilter;
 331   interface SMESH_subMesh;
 332   interface SMESH_MeshEditor;
 333
 334   typedef sequence<SMESH_subMesh>     submesh_array;
 335   typedef sequence<submesh_array>     submesh_array_array;
 336
 337   interface SMESH_Mesh : SMESH_IDSource
 338   {
 339     /*!
 340      * Return true if there is a geometry to be meshed
 341      */
 342     boolean HasShapeToMesh()
 343       raises (SALOME::SALOME_Exception);
 344
 345     /*!
 346      * Get geom shape to mesh. A result should not be nil. Use HasShapeToMesh()
 347      * to know if a returned shape
 348      */
 349     GEOM::GEOM_Object GetShapeToMesh()
 350       raises (SALOME::SALOME_Exception);
 351
 352     /*!
 353      * Replaces a shape in the mesh
 354      */
 355     void ReplaceShape(in GEOM::GEOM_Object theNewGeom)
 356       raises (SALOME::SALOME_Exception);
 357
 358     /*!
 359      * Return false if the mesh is not yet fully loaded from the study file
 360      */
 361     boolean IsLoaded()
 362       raises (SALOME::SALOME_Exception);
 363
 364     /*!
 365      * Load full mesh data from the study file
 366      */
 367     void Load()
 368       raises (SALOME::SALOME_Exception);
 369
 370     /*!
 371      * Remove all nodes and elements
 372      */
 373     void Clear()
 374       raises (SALOME::SALOME_Exception);
 375
 376     /*!
 377      *  Get the list of sub-meshes existing in the mesh
 378      */
 379     submesh_array GetSubMeshes()
 380       raises (SALOME::SALOME_Exception);
 381
 382     /*!
 383      * Remove all nodes and elements of submesh
 384      */
 385     void ClearSubMesh(in long ShapeID)
 386       raises (SALOME::SALOME_Exception);
 387
 388     /*!
 389      * Get the subMesh object associated to a Sub-shape. The subMesh object
 390      * gives access to nodes and elements IDs.
 391      * SubMesh will be used instead of Sub-shape in a next idl version to
 392      * address a specific subMesh...
 393      */
 394     SMESH_subMesh GetSubMesh(in GEOM::GEOM_Object aSubObject, in string name)
 395       raises (SALOME::SALOME_Exception);
 396
 397     /*!
 398      * Remove a submesh
 399      */
 400     void RemoveSubMesh(in SMESH_subMesh aSubMesh)
 401       raises (SALOME::SALOME_Exception);
 402
 403
 404     /*!
 405      * Create a group
 406      */
 407     SMESH_Group CreateGroup( in ElementType elem_type,
 408                              in string      name )
 409       raises (SALOME::SALOME_Exception);
 410
 411     /*!
 412      * Create a group from geometry
 413      */
 414     SMESH_GroupOnGeom CreateGroupFromGEOM( in ElementType       elemType,
 415                                            in string            name,
 416                                            in GEOM::GEOM_Object geomObject )
 417       raises (SALOME::SALOME_Exception);
 418
 419     /*!
 420      * Create a group from filter
 421      */
 422     SMESH_GroupOnFilter CreateGroupFromFilter( in ElementType   elemType,
 423                                                in string        name,
 424                                                in SMESH::Filter filter )
 425       raises (SALOME::SALOME_Exception);
 426
 427     /*!
 428      * Remove a group
 429      */
 430     void RemoveGroup(in SMESH_GroupBase aGroup)
 431       raises (SALOME::SALOME_Exception);
 432
 433     /*!
 434      *  Remove group with its contents
 435      */
 436     void RemoveGroupWithContents( in SMESH_GroupBase aGroup )
 437       raises (SALOME::SALOME_Exception);
 438
 439     /*!
 440      *  Get the list of groups existing in the mesh
 441      */
 442     ListOfGroups GetGroups()
 443       raises (SALOME::SALOME_Exception);
 444
 445     /*!
 446      *  Get number of groups existing in the mesh
 447      */
 448     long NbGroups()
 449       raises (SALOME::SALOME_Exception);
 450
 451     /*!
 452      * Union of two groups
 453      *    New group is created. All mesh elements that are
 454      *    present in initial groups are added to the new one
 455      */
 456     SMESH_Group UnionGroups (in SMESH_GroupBase aGroup1,
 457                              in SMESH_GroupBase aGroup2,
 458                              in string          name )
 459       raises (SALOME::SALOME_Exception);
 460
 461     /*!
 462      * Union of list of groups
 463      * New group is created. All mesh elements that are
 464      * present in initial groups are added to the new one
 465      */
 466     SMESH_Group UnionListOfGroups (in ListOfGroups aListOfGroups,
 467                                    in string       name )
 468       raises (SALOME::SALOME_Exception);
 469
 470     /*!
 471      *  Intersection of two groups
 472      *  New group is created. All mesh elements that are
 473      *  present in both initial groups are added to the new one.
 474      */
 475     SMESH_Group IntersectGroups (in SMESH_GroupBase aGroup1,
 476                                  in SMESH_GroupBase aGroup2,
 477                                  in string          name )
 478       raises (SALOME::SALOME_Exception);
 479
 480     /*!
 481      *  Intersection of list of groups
 482      *  New group is created. All mesh elements that are
 483      *  present in all initial groups simultaneously are added to the new one.
 484      */
 485     SMESH_Group IntersectListOfGroups (in ListOfGroups aListOfGroups,
 486                                        in string       name)
 487       raises (SALOME::SALOME_Exception);
 488
 489     /*!
 490      *  Cut of two groups
 491      *  New group is created. All mesh elements that are present in
 492      *  main group but do not present in tool group are added to the new one
 493      */
 494     SMESH_Group CutGroups (in SMESH_GroupBase aMainGroup,
 495                            in SMESH_GroupBase aToolGroup,
 496                            in string          name )
 497       raises (SALOME::SALOME_Exception);
 498
 499     /*!
 500      *  Cut of lists of groups
 501      *  New group is created. All mesh elements that are present in
 502      *  main groups but do not present in tool groups are added to the new one
 503      */
 504     SMESH_Group CutListOfGroups (in ListOfGroups aMainGroups,
 505                                  in ListOfGroups aToolGroups,
 506                                  in string       name)
 507       raises (SALOME::SALOME_Exception);
 508
 509     /*!
 510      *  Create a group of entities basing on nodes of other groups.
 511      *  \param [in] aListOfGroups - list of either groups, sub-meshes or filters.
 512      *  \param [in] anElemType - a type of elements to include to the new group.
 513      *  \param [in] name - a name of the new group.
 514      *  \param [in] nbCommonNodes - criterion of inclusion of an element to the new group.
 515      *  \param [in] underlyingOnly - if \c True, an element is included to the
 516      *         new group provided that it is based on nodes of an element of
 517      *         \a aListOfGroups
 518      *  \return SMESH_Group - the created group
 519      */
 520     SMESH_Group CreateDimGroup( in ListOfIDSources      aListOfGroups,
 521                                 in ElementType          anElemType,
 522                                 in string               name,
 523                                 in NB_COMMON_NODES_ENUM nbCommonNodes,
 524                                 in boolean              underlyingOnly )
 525       raises (SALOME::SALOME_Exception);
 526
 527     /*!
 528      * Distribute all faces of the mesh among groups using sharp edges and optionally
 529      * existing 1D elements as group boundaries.
 530      *  \param [in] sharpAngle - edge is considered sharp if an angle between normals of
 531      *              adjacent faces is more than \a sharpAngle in degrees.
 532      *  \param [in] createEdges - to create 1D elements for detected sharp edges.
 533      *  \param [in] useExistingEdges - to use existing edges as group boundaries
 534      *  \return ListOfGroups - the created groups
 535      */
 536     ListOfGroups FaceGroupsSeparatedByEdges( in double  sharpAngle,
 537                                              in boolean createEdges,
 538                                              in boolean useExistingEdges )
 539       raises (SALOME::SALOME_Exception);
 540
 541     /*!
 542      * Convert group on geometry or on filter into standalone group
 543      */
 544     SMESH_Group ConvertToStandalone( in SMESH_GroupBase theGroupOn )
 545       raises (SALOME::SALOME_Exception);
 546
 547     /*!
 548      * Add hypothesis to the mesh, under a particular sub-shape
 549      * (or the main shape itself)
 550      * This method is only used to prepare the build of the mesh and store
 551      * the algorithms and associated parameters.
 552      * Actual job of meshing the shape is done by SMESH_Gen::Compute()
 553      * @params
 554      * - aSubObject : sub-shape obtained by a shape explode in GEOM
 555      *   (or main shape)
 556      * - anHyp : an hypothesis object
 557      * @return
 558      * - An enum item explaining what's up
 559      * - anErrorText: an optional textual description of a problem (if any)
 560      */
 561     Hypothesis_Status AddHypothesis(in GEOM::GEOM_Object aSubObject,
 562                                     in SMESH_Hypothesis  anHyp,
 563                                     out string           anErrorText)
 564       raises (SALOME::SALOME_Exception);
 565
 566     /*!
 567      * Remove an hypothesis previously added with AddHypothesis.
 568      */
 569     Hypothesis_Status RemoveHypothesis(in GEOM::GEOM_Object aSubObject,
 570                                        in SMESH_Hypothesis anHyp)
 571       raises (SALOME::SALOME_Exception);
 572
 573     /*!
 574      * Get the list of hypothesis added on a sub-shape
 575      */
 576     ListOfHypothesis GetHypothesisList(in GEOM::GEOM_Object aSubObject)
 577       raises (SALOME::SALOME_Exception);
 578
 579     /*!
 580      * Get the log of nodes and elements added or removed since previous
 581      * clear of the log.
 582      * @params
 583      * - clearAfterGet : log is emptied after Get (safe if concurrents access)
 584      */
 585     log_array GetLog(in boolean clearAfterGet)
 586       raises (SALOME::SALOME_Exception);
 587
 588     /*!
 589      * Clear the log of nodes and elements added or removed since previous
 590      * clear. Must be used immediately after GetLog if clearAfterGet is false.
 591      */
 592     void ClearLog()
 593       raises (SALOME::SALOME_Exception);
 594
 595     /*!
 596      * Toggle auto color mode on the object.
 597      * @params
 598      * - theAutoColor : flag which toggles auto color mode.
 599      */
 600     void SetAutoColor(in boolean theAutoColor)
 601       raises (SALOME::SALOME_Exception);
 602
 603     /*!
 604      * Get flag of object's auto color mode.
 605      */
 606     boolean GetAutoColor()
 607       raises (SALOME::SALOME_Exception);
 608
 609     /*!
 610      * Get the internal Id
 611      */
 612     long GetId();
 613
 614     /*!
 615      * Obtain instance of SMESH_MeshEditor
 616      */
 617     SMESH_MeshEditor GetMeshEditor()
 618       raises (SALOME::SALOME_Exception);
 619
 620     /*!
 621      * Return SMESH_MeshEditor that would not modify the mesh but
 622      * fill MeshPreviewStruct
 623      */
 624     SMESH_MeshEditor GetMeshEditPreviewer()
 625       raises (SALOME::SALOME_Exception);
 626
 627     /*!
 628      * Return true if the mesh has been edited since a total re-compute
 629      * and those modifications may prevent successful partial re-compute
 630      */
 631     boolean HasModificationsToDiscard()
 632       raises (SALOME::SALOME_Exception);
 633
 634     /*! Check group names for duplications.
 635      *  Consider maximum group name length stored in MED file.
 636      */
 637     boolean HasDuplicatedGroupNamesMED();
 638
 639     /*!
 640      * Export a Mesh to MED file.
 641      * @params
 642      * - fileName : name of the MED file
 643      * - auto_groups : boolean parameter for creating/not creating
 644      *                 the groups Group_On_All_Nodes, Group_On_All_Faces, ... ;
 645      *                 the typical use is auto_groups=false.
 646      * - overwrite : boolean parameter for overwriting/not overwriting the file, if it exists
 647      * - version : define the version of MED file format, coded with major and minor digits (release digit not used)
 648      *           for instance med 3.2.1 is coded 3*10+2 = 32, med 4.0.0 is coded 4*10+0 = 40.
 649      *           The rules of compatibility to write a mesh in an older version than the current version
 650      *           depend on the current version. For instance, with med 4.0 it is possible to write/append
 651      *           med files in 4.0.0 (default format) or 3.2.1 or 3.3.1 formats.
 652      *           The minor must be between 0 and the current minor version of MED file library.
 653      *           If version is equal to -1, the version is not changed (default).
 654      * - autoDimension : if @c true, a space dimension of a MED mesh can be either
 655      *         - 1D if all mesh nodes lie on OX coordinate axis, or
 656      *         - 2D if all mesh nodes lie on XOY coordinate plane, or
 657      *         - 3D in the rest cases.
 658      *         If @a autoDimension is @c false, the space dimension is always 3.
 659      */
 660     void ExportMED( in string      fileName,
 661                     in boolean     auto_groups,
 662                     in long        version,
 663                     in boolean     overwrite,
 664                     in boolean     autoDimension) raises (SALOME::SALOME_Exception);
 665
 666     long long ExportMEDCoupling(in boolean     auto_groups,
 667       in boolean     autoDimension
 668     ) raises (SALOME::SALOME_Exception);
 669
 670     /*!
 671      * Export a [part of] Mesh into a MED file
 672      * @params
 673      * - meshPart : a part of mesh to store
 674      * - fileName : name of the MED file
 675      * - overwrite : boolean parameter for overwriting/not overwriting the file, if it exists
 676      * - version : define the version of MED file format, coded with major and minor digits (release digit not used)
 677      *           for instance med 3.2.1 is coded 3*10+2 = 32, med 4.0.0 is coded 4*10+0 = 40.
 678      *           The rules of compatibility to write a mesh in an older version than the current version
 679      *           depend on the current version. For instance, with med 4.0 it is possible to write/append
 680      *           med files in 4.0.0 (default format) or 3.2.1 or 3.3.1 formats.
 681      *           The minor must be between 0 and the current minor version of MED file library.
 682      *           If version is equal to -1, the version is not changed (default).
 683      * - autoDimension : if @c True, a space dimension for export is defined by mesh
 684      *                 configuration; for example a planar mesh lying on XOY plane
 685      *                 will be exported as a mesh in 2D space.
 686      *                 If @a autoDimension == @c False, the space dimension is 3.
 687      * - fields : list of GEOM fields defined on the shape to mesh.
 688      * - geomAssocFields : each character of this string means a need to export a
 689      *         corresponding field; correspondence between fields and characters is following:
 690      *         - 'v' stands for _vertices_ field;
 691      *         - 'e' stands for _edges_ field;
 692      *         - 'f' stands for _faces_ field;
 693      *         - 's' stands for _solids_ field.
 694      * - ZTolerance : tolerance in Z direction. If Z coordinate of a node is close to zero
 695      *                within a given tolerance, the coordinate is set to zero.
 696      *                If @a ZTolerance is negative, the node coordinates are kept as is.
 697      */
 698     void ExportPartToMED( in SMESH_IDSource     meshPart,
 699                           in string             fileName,
 700                           in boolean            auto_groups,
 701                           in long               version,
 702                           in boolean            overwrite,
 703                           in boolean            autoDimension,
 704                           in GEOM::ListOfFields fields,
 705                           in string             geomAssocFields,
 706                           in double             ZTolerance) raises (SALOME::SALOME_Exception);
 707
 708     long long ExportPartToMEDCoupling( in SMESH_IDSource     meshPart,
 709                           in boolean            auto_groups,
 710                           in boolean            autoDimension,
 711                           in GEOM::ListOfFields fields,
 712                           in string             geomAssocFields,
 713                           in double             ZTolerance) raises (SALOME::SALOME_Exception);
 714
 715     /*!
 716      * Export Mesh to SAUV formatted file
 717      * Write a temporary med file and use med2sauv
 718      */
 719     void ExportSAUV( in string file, in boolean auto_groups )
 720       raises (SALOME::SALOME_Exception);
 721
 722     /*!
 723      * Return string representation of a MED file version comprising nbDigits
 724      */
 725     string GetVersionString(in long minor, in short nbDigits);
 726
 727     /*!
 728      *  Return the list of med versions compatibles for write/append,
 729      *  encoded in 10*major+minor (for instance, code for med 3.2.1 is 32)
 730      */
 731     long_array GetMEDVersionsCompatibleForAppend();
 732
 733     /*!
 734      * Export Mesh to different Formats
 735      * (UNV supported version is I-DEAS 10)
 736      */
 737     void ExportDAT( in string file ) raises (SALOME::SALOME_Exception);
 738     void ExportUNV( in string file ) raises (SALOME::SALOME_Exception);
 739     void ExportSTL( in string  file,
 740                     in boolean isascii ) raises (SALOME::SALOME_Exception);
 741     void ExportCGNS( in SMESH_IDSource meshPart,
 742                      in string         file,
 743                      in boolean        overwrite,
 744                      in boolean        groupElemsByType) raises (SALOME::SALOME_Exception);
 745     void ExportGMF( in SMESH_IDSource  meshPart,
 746                     in string          file,
 747                     in boolean         withRequiredGroups) raises (SALOME::SALOME_Exception);
 748     void ExportPartToDAT( in SMESH_IDSource meshPart,
 749                           in string         file ) raises (SALOME::SALOME_Exception);
 750     void ExportPartToUNV( in SMESH_IDSource meshPart,
 751                           in string         file ) raises (SALOME::SALOME_Exception);
 752     void ExportPartToSTL( in SMESH_IDSource meshPart,
 753                           in string         file,
 754                           in boolean        isascii ) raises (SALOME::SALOME_Exception);
 755     /*!
 756      * Return computation progress [0.,1]
 757      */
 758     double GetComputeProgress();
 759
 760     /*!
 761      * Get information about mesh contents
 762      */
 763     smIdType NbNodes()
 764       raises (SALOME::SALOME_Exception);
 765
 766     smIdType NbElements()
 767       raises (SALOME::SALOME_Exception);
 768
 769     smIdType Nb0DElements()
 770       raises (SALOME::SALOME_Exception);
 771
 772     smIdType NbBalls()
 773       raises (SALOME::SALOME_Exception);
 774
 775     smIdType NbEdges()
 776       raises (SALOME::SALOME_Exception);
 777
 778     smIdType NbEdgesOfOrder(in ElementOrder order)
 779       raises (SALOME::SALOME_Exception);
 780
 781     smIdType NbFaces()
 782       raises (SALOME::SALOME_Exception);
 783
 784     smIdType NbFacesOfOrder(in ElementOrder order)
 785       raises (SALOME::SALOME_Exception);
 786
 787     smIdType NbTriangles()
 788       raises (SALOME::SALOME_Exception);
 789
 790     smIdType NbTrianglesOfOrder(in ElementOrder order)
 791       raises (SALOME::SALOME_Exception);
 792
 793     smIdType NbBiQuadTriangles()
 794       raises (SALOME::SALOME_Exception);
 795
 796     smIdType NbQuadrangles()
 797       raises (SALOME::SALOME_Exception);
 798
 799     smIdType NbQuadranglesOfOrder(in ElementOrder order)
 800       raises (SALOME::SALOME_Exception);
 801
 802     smIdType NbBiQuadQuadrangles()
 803       raises (SALOME::SALOME_Exception);
 804
 805     smIdType NbPolygons()
 806       raises (SALOME::SALOME_Exception);
 807
 808     smIdType NbPolygonsOfOrder(in ElementOrder order)
 809       raises (SALOME::SALOME_Exception);
 810
 811     smIdType NbVolumes()
 812       raises (SALOME::SALOME_Exception);
 813
 814     smIdType NbVolumesOfOrder(in ElementOrder order)
 815       raises (SALOME::SALOME_Exception);
 816
 817     smIdType NbTetras()
 818       raises (SALOME::SALOME_Exception);
 819
 820     smIdType NbTetrasOfOrder(in ElementOrder order)
 821       raises (SALOME::SALOME_Exception);
 822
 823     smIdType NbHexas()
 824       raises (SALOME::SALOME_Exception);
 825
 826     smIdType NbHexasOfOrder(in ElementOrder order)
 827       raises (SALOME::SALOME_Exception);
 828
 829     smIdType NbTriQuadraticHexas()
 830       raises (SALOME::SALOME_Exception);
 831
 832     smIdType NbPyramids()
 833       raises (SALOME::SALOME_Exception);
 834
 835     smIdType NbPyramidsOfOrder(in ElementOrder order)
 836       raises (SALOME::SALOME_Exception);
 837
 838     smIdType NbPrisms()
 839       raises (SALOME::SALOME_Exception);
 840
 841     smIdType NbPrismsOfOrder(in ElementOrder order)
 842       raises (SALOME::SALOME_Exception);
 843
 844     smIdType NbHexagonalPrisms()
 845       raises (SALOME::SALOME_Exception);
 846
 847     smIdType NbPolyhedrons()
 848       raises (SALOME::SALOME_Exception);
 849
 850     smIdType NbSubMesh()
 851       raises (SALOME::SALOME_Exception);
 852
 853     smIdType_array GetElementsId()
 854       raises (SALOME::SALOME_Exception);
 855
 856     smIdType_array GetElementsByType( in ElementType theType )
 857       raises (SALOME::SALOME_Exception);
 858
 859     smIdType_array GetNodesId()
 860       raises (SALOME::SALOME_Exception);
 861
 862     /*!
 863      * Returns type of mesh element
 864      */
 865     ElementType GetElementType( in smIdType id, in boolean iselem )
 866       raises (SALOME::SALOME_Exception);
 867
 868     EntityType GetElementGeomType( in smIdType id )
 869       raises (SALOME::SALOME_Exception);
 870
 871     GeometryType GetElementShape( in smIdType id )
 872       raises (SALOME::SALOME_Exception);
 873
 874     smIdType_array GetSubMeshElementsId(in long ShapeID)
 875       raises (SALOME::SALOME_Exception);
 876
 877     smIdType_array GetSubMeshNodesId(in long ShapeID, in boolean all )
 878       raises (SALOME::SALOME_Exception);
 879
 880     ElementType GetSubMeshElementType(in long ShapeID)
 881       raises (SALOME::SALOME_Exception);
 882
 883
 884     /*!
 885      * Methods to set meshing order of submeshes
 886      */
 887
 888     /*!
 889      * \brief Return \c true if a meshing order not yet set for a concurrent sub-mesh
 890      */
 891     boolean IsUnorderedSubMesh(in long submeshID);
 892
 893     /*!
 894      * \brief Return submesh objects list in meshing order
 895      */
 896     submesh_array_array GetMeshOrder();
 897
 898     /*!
 899      * \brief Set submesh object order
 900      */
 901     boolean SetMeshOrder(in submesh_array_array theSubMeshArray);
 902
 903
 904     /*!
 905      * Get mesh description
 906      */
 907     string Dump();
 908
 909     /*!
 910      * Get mesh pointer
 911      */
 912     long long GetMeshPtr();
 913
 914     /*!
 915      * Get XYZ coordinates of node as list of double
 916      * If there is not node for given ID - returns empty list
 917      */
 918     double_array GetNodeXYZ(in smIdType id);
 919
 920     /*!
 921      * For given node returns list of IDs of inverse elements
 922      * If there is not node for given ID - returns empty list
 923      */
 924     smIdType_array GetNodeInverseElements(in smIdType id, in ElementType elemType);
 925
 926     /*!
 927      * \brief Return position of a node on shape
 928      */
 929     NodePosition GetNodePosition(in smIdType NodeID);
 930
 931     /*!
 932      * \brief Return position of an element on shape
 933      */
 934     ElementPosition GetElementPosition(in smIdType ElemID);
 935
 936     /*!
 937      * If given element is node returns IDs of shape from position
 938      * If there is not node for given ID - returns -1
 939      */
 940     long GetShapeID(in smIdType id);
 941
 942     /*!
 943      * For given element returns ID of result shape after
 944      * ::FindShape() from SMESH_MeshEditor
 945      * If there is not element for given ID - returns -1
 946      */
 947     long GetShapeIDForElem(in smIdType id);
 948
 949     /*!
 950      * Returns number of nodes for given element
 951      * If there is not element for given ID - returns -1
 952      */
 953     short GetElemNbNodes(in smIdType id);
 954
 955     /*!
 956      * Returns IDs of nodes of given element
 957      */
 958     smIdType_array GetElemNodes(in smIdType id);
 959
 960     /*!
 961      * Returns ID of node by given index for given element
 962      * If there is not element for given ID - returns -1
 963      * If there is not node for given index - returns -2
 964      */
 965     smIdType GetElemNode(in smIdType id, in short index);
 966
 967     /*!
 968      * Returns true if given node is medium node
 969      * in given quadratic element
 970      */
 971     boolean IsMediumNode(in smIdType ide, in smIdType idn);
 972
 973     /*!
 974      * Returns true if given node is medium node
 975      * in one of quadratic elements
 976      */
 977     boolean IsMediumNodeOfAnyElem(in smIdType idn, in ElementType elem_type);
 978
 979     /*!
 980      * Returns number of edges for given element
 981      */
 982     long ElemNbEdges(in smIdType id);
 983
 984     /*!
 985      * Returns number of faces for given element
 986      */
 987     long ElemNbFaces(in smIdType id);
 988
 989     /*!
 990      * Returns nodes of given face (counted from zero) for given volumic element.
 991      */
 992     smIdType_array GetElemFaceNodes(in smIdType elemId, in short faceIndex);
 993
 994     /*!
 995      * Returns three components of normal of given mesh face (or an empty array in KO case)
 996      */
 997     double_array GetFaceNormal(in long faceId, in boolean normalized);
 998
 999     /*!
1000      * Returns an element based on all given nodes.
1001      */
1002     smIdType FindElementByNodes(in smIdType_array nodes);
1003
1004     /*!
1005      * Return elements including all given nodes.
1006      */
1007     smIdType_array GetElementsByNodes(in smIdType_array nodes, in ElementType elem_type);
1008
1009     /*!
1010      * Returns true if given element is polygon
1011      */
1012     boolean IsPoly(in smIdType id);
1013
1014     /*!
1015      * Returns true if given element is quadratic
1016      */
1017     boolean IsQuadratic(in smIdType id);
1018
1019     /*!
1020      * Returns diameter of a ball discrete element or zero in case of an invalid \a id
1021      */
1022     double GetBallDiameter(in smIdType id);
1023
1024     /*!
1025      * Returns XYZ coordinates of bary center for given element
1026      * as list of double
1027      * If there is not element for given ID - returns empty list
1028      */
1029     double_array BaryCenter(in smIdType id);
1030
1031     /*! Gets information about imported MED file */
1032     MedFileInfo GetMEDFileInfo();
1033
1034     /*!
1035      *  Sets list of notebook variables used for Mesh operations separated by ":" symbol
1036      *  \param theParameters is a string containing the notebook variables
1037      */
1038     void SetParameters (in string theParameters);
1039
1040     /*!
1041      *  Returns list of notebook variables used for Mesh operations separated by ":" symbol
1042      */
1043     string GetParameters();
1044
1045     /*!
1046      *  Returns list of notebook variables used for last Mesh operation
1047      */
1048     string_array GetLastParameters();
1049   };
1050
1051   interface SMESH_subMesh : SMESH_IDSource
1052   {
1053     /*!
1054      *
1055      */
1056     smIdType GetNumberOfElements()
1057       raises (SALOME::SALOME_Exception);
1058
1059     /*!
1060      *
1061      */
1062     smIdType GetNumberOfNodes( in boolean all )
1063       raises (SALOME::SALOME_Exception);
1064
1065     /*!
1066      *
1067      */
1068     smIdType_array GetElementsId()
1069       raises (SALOME::SALOME_Exception);
1070
1071     /*!
1072      *
1073      */
1074     smIdType_array GetElementsByType( in ElementType theType )
1075       raises (SALOME::SALOME_Exception);
1076
1077     /*!
1078      * Returns type of mesh element (same as SMESH_Mesh::GetElementType() )
1079      */
1080     ElementType GetElementType( in smIdType id, in boolean iselem )
1081       raises (SALOME::SALOME_Exception);
1082
1083     /*!
1084      *
1085      */
1086     smIdType_array GetNodesId()
1087       raises (SALOME::SALOME_Exception);
1088
1089     /*!
1090      * Get geom shape the submesh is dedicated to
1091      */
1092     GEOM::GEOM_Object GetSubShape()
1093       raises (SALOME::SALOME_Exception);
1094
1095     /*!
1096      * Get SMESH_Mesh which stores nodes coordinates & elements definition
1097      */
1098     SMESH_Mesh GetFather()
1099       raises (SALOME::SALOME_Exception);
1100
1101     /*!
1102      * Get the internal Id
1103      */
1104     long GetId();
1105   };
1106
1107 };
1108
1109 #endif