// File :      VISU_Gen.idl
// Created :
// Author :    Alexey Petrov
// Project :   SALOME
// Copyright : OPEN CASCADE
// $HEADERS:

/*! \file VISU_Gen.idl This file conatins a set of interfaces of %VISU module.
      This module will provide various forms of data visualization in %SALOME application.
      These forms include data tables, XY plots, 3d representations
      and combination of these forms.
*/
/*!
 \defgroup Visu SALOME VISU module
*/

#ifndef __VISU_GEN__
#define __VISU_GEN__

#include "SALOME_Exception.idl"
#include "SALOME_Component.idl"
#include "SALOMEDS.idl"
#include "SALOMEDS_Attributes.idl"
#include "MED.idl"

/*! \ingroup Visu
  The main package of interfaces of the module %VISU.
*/
module VISU {
  //-------------------------------------------------------
  const string VISU__doc__ = "Module VISU provides various forms of data visualization in SALOME application.\nThese forms include data tables, XY plots,\n3d representations and combination of these forms.";
  typedef string IdType;
  enum Scaling{ LINEAR, LOGARITHMIC};
  enum Entity{ NODE, EDGE, FACE, CELL};
/*!
 This enumeration contains a set of elements defining the type of the module.
*/
   enum VISUType{ TNONE,
		  TCURVE, TTABLE, TCONTAINER, TMESH, TSCALARMAP,
   		  TISOSURFACE, TDEFORMEDSHAPE, TCUTPLANES, TVECTORS, TSTREAMLINES,
                  TVISUGEN, TVIEWMANAGER, TRESULT,
	          TXYPLOT, TTABLEVIEW, TVIEW3D,
	          TENTITY, TFAMILY, TGROUP, TFIELD, TTIMESTAMP,
                  TALL};
  interface Base {
/*!
   Returns ID of the object.
*/
    IdType GetID();
    const string GetID__doc__ = "Returns ID of the object.";
/*!
Returns the type of the presentable object
*/
    VISUType GetType();
    const string GetType__doc__ = "Returns the type of the module interface";
  };   
/*! \brief Presentable object interface

 It is the root class of all presentable objects.
*/
  interface PrsObject : Base{
  };
    const string PrsObject__doc__ = "It is the root class of all presentable objects.";
  //-------------------------------------------------------
/*! \brief %Table representation interface

Presentation parameters of the %Table view.
*/
  interface Table : PrsObject {
/*!
Sets the title of the table.
*/
    void SetTitle(in string theTitle);
    const string SetTitle__doc__ = "Sets the title of the table.";
/*!
Gets the title of the table.
*/
    string GetTitle();
    const string GetTitle__doc__ = "Gets the title of the table.";
/*!
 This enumeration contains a set of elements defining the orientation of the table.
*/
    enum Orientation{ HORIZONTAL, /*!<Horizontal orientation of the table.*/
                       VERTIACAL /*!<Vertical orientation of the table.*/
                    };
/*!
Sets orientation of the table.
*/
    void SetOrientation(in Orientation theOrientation);
    const string SetOrientation__doc__ = "Sets orientation of the table.";
/*!
Gets orientation of the table.
*/
    Orientation GetOrientation();
    const string GetOrientation__doc__ = "Gets orientation of the table.";
 /*!
Gets the number of rows of the table
 */
    long GetNbRows();
    const string GetNbRows__doc__ = "Gets the number of rows of the table.";
 /*!
Gets the number of columns of the table
 */
    long GetNbColumns();
    const string GetNbColumns__doc__ ="Gets the number of columns of the table.";
  };
    const string Table__doc__ = "The Table interface contains presentation\nparameters of the %Table view.";
  //-------------------------------------------------------
/*! \brief Interface of curve representation.

Manages presentation parameters of one curve.
It can be used for presentation of a set of curves using a combined presentation.
*/
  interface Curve : PrsObject{
/*!
Sets the title of the curve.
*/
    void SetTitle(in string theTitle);
    const string SetTitle__doc__ = "Sets the title of the curve.";
/*!
Gets the title of the curve.
*/
    string GetTitle();
    const string GetTitle__doc__ = "Gets the title of the curve.";
/*!
Sets the color of the curve.
*/
    void SetColor(in SALOMEDS::Color theColor);
    const string SetColor__doc__ = "Sets the color of the curve.";
/*!
Gets the color of the curve.
*/
    SALOMEDS::Color GetColor();
    const string GetColor__doc__ = "Gets the color of the curve.";
 /*!
 This enumeration contains a set of elements defining the representation type of markers (data points) with help of
which the curve is constructed on the graphics.
*/
    enum MarkerType{ NONE, CIRCLE, RECTANGLE, DIAMOND,
                     DTRIANGLE, UTRIANGLE, LTRIANGLE, RTRIANGLE,
                     CROSS, XCROSS };
/*!
Sets the representation type of markers (data points) with help of
which the curve is constructed on the graphics.
*/
    void SetMarker(in MarkerType theType);
    const string SetMarker__doc__ = "Sets the representation type of markers\n(data points) with help of which\nthe curve is constructed on the graphics.";
/*!
Gets the representation type of markers (data points) with help of
which the curve is constructed on the graphics.
*/
    MarkerType GetMarker();
    const string GetMarker__doc__ = "Gets the representation type of markers\n(data points) with help of which the\ncurve is constructed on the graphics.";
/*!
 This enumeration contains a set of elements defining the
 type of representation of curve lines on the graphics.
*/
    enum LineType{ VOIDLINE, SOLIDLINE, DASHLINE, DOTLINE, DASHDOTLINE, DASHDOTDOTLINE};
/*!
Sets the type of representation of curve lines on the graphics.
*/
    void SetLine(in LineType theType, in long theLineWidth);
    const string SetLine__doc__ = "Sets the type of representation of curve\nlines on the graphics.";
/*!
Gets the type of representation of curve lines on the graphics.
*/
    LineType GetLine();
    const string GetLine__doc__ = "Gets the type of representation of curve\nlines on the graphics.";

/*!
Gets the width of the curve line.
*/
    long GetLineWidth();
    const string GetLineWidth__doc__ = "Gets the width of the curve line.";
  };
    const string Curve__doc__ = "The curve representation interface manages\npresentation parameters of one curve. It can be used\nfor presentation of a set of curves\nusing a combined presentation.";
//-------------------------------------------------------
/*! \brief The %Container presentable object interface
This interface contains a set of methods used for management of a group of curves
which are stored in the container.
*/
  interface Container : PrsObject{
/*!
Adds a curve into the container.
*/
    void AddCurve(in Curve theCurve);
    const string AddCurve__doc__ = "Adds a curve into the container.";
/*!
Removes a curve from the container.
*/
    void RemoveCurve(in Curve theCurve);
    const string RemoveCurve__doc__ = "Removes a curve from the container.";
/*!
Gets the number of curves which are stored in the container.
*/
    long GetNbCurves();
    const string GetNbCurves__doc__ = "Gets the number of curves which\nare stored in the container.";
/*!
Removes all curves from the container.
*/
    void Clear();
    const string Clear__doc__ = "Removes all curves from the container.";

  };
    const string Container__doc__ = "The Container presentable object\ninterface contains a set of methods\nused for management of a group of curves which\nare stored in the container.";
  //-------------------------------------------------------
/*!
 This enumeration contains a set of elements defining the
 type of representation of the mesh.
*/

    enum PresentationType{ POINT,
                           WIREFRAME,
                           SHADED,
                           SHRINK
                         };
/*! \brief Interface of the mesh.

This interface manages the presentation parameters of the mesh.
*/
    interface Mesh : PrsObject{
/*!
Sets the color of mesh cells.
*/
    void SetCellColor(in SALOMEDS::Color theColor);
    const string SetCellColor__doc__ = "Sets the color of mesh cells.";
/*!
Gets the color of mesh cells.
*/
    SALOMEDS::Color GetCellColor();
    const string GetCellColor__doc__ = "Gets the color of mesh cells.";
/*!
Sets the color of mesh nodes.
*/
    void SetNodeColor(in SALOMEDS::Color theColor);
    const string SetNodeColor__doc__ = "Sets the color of mesh nodes.";
/*!
Gets the color of mesh nodes.
*/
    SALOMEDS::Color GetNodeColor();
    const string GetNodeColor__doc__ = "Gets the color of mesh nodes.";

/*!
Sets the color of mesh links.
*/
    void SetLinkColor(in SALOMEDS::Color theColor);
    const string SetLinkColor__doc__ = "Sets the color of mesh links.";
/*!
Gets the color of mesh links.
*/
    SALOMEDS::Color GetLinkColor();
    const string GetLinkColor__doc__ = "Gets the color of mesh links.";
/*!
Sets the type of representation of the mesh.
*/
    void SetPresentationType(in PresentationType theType);
    const string SetPresentationType__doc__ = "Sets the type of representation of the mesh.";
/*!
Gets the type of representation of the mesh.
*/
    PresentationType GetPresentationType();
    const string GetPresentationType__doc__ = "Gets the type of representation of the mesh.";
  };
    const string Mesh__doc__ = "The Mesh interface manages the presentation parameters\nof the mesh.";
  //-------------------------------------------------------
/*! \brief Interface of the %Scalar Map presentation

This interface contains presentation parameters of the ScalarMap presentation
*/
  interface ScalarMap : PrsObject{
    void SetScalarMode(in long theScaling);
    long GetScalarMode();
    void SetScaling(in Scaling theScaling);
    const string SetScaling__doc__ = "Sets the type of scaling of the values\nreflected by this presentation.";
/*!
Gets the type of scaling of the values reflected by this presentation.
*/
    Scaling GetScaling();
    const string GetScaling__doc__ = "Gets the type of scaling of the values\nreflected by this presentation.";
/*!
Sets scalar range - min and max boundaries of this presentable object.
\param theMin  Min boundary of this presentable object.
\param theMax  Max boundary of this presentable object.
*/
    void SetRange(in double theMin, in double theMax);
    const string SetRange__doc__ = "Sets scalar range - min and max boundaries\nof this presentable object.";
/*!
 Gets the min boundary of this presentable object.
*/
    double GetMin();
    const string GetMin__doc__ = "Gets the min boundary of this presentable object.";
/*!
 Gets the max boundary of this presentable object.
*/
    double GetMax();
    const string GetMax__doc__ = "Gets the max boundary of this presentable object.";

/*! %Orientation of this presentable object. */
    enum Orientation{
                     HORIZONTAL, /*!< Horizontal orientation of this presentable object.*/
                       VERTICAL  /*!< Vertical orientation of this presentable object.*/
                    };
/*!
 Sets the type of orientation of this presentable object.
*/
    void SetOrientation(in Orientation theOrientation);
    const string SetOrientation__doc__ = "Sets the type of orientation of this presentable object.";
/*!
 Gets the type of orientation of this presentable object.
*/
    Orientation GetOrientation();
    const string GetOrientation__doc__ = "Gets the type of orientation of this presentable object.";

/*! \brief Position of this presentable object.

Sets the position of this presentable object origin on the screen.
\param X   Horizontal position. The value can be between 0 and 1.
\param Y   Vertical position. The value can be between 0 and 1.
*/
    void SetPosition(in double X, in double Y);
    const string SetPosition__doc__ = "Sets the position of this presentable object\norigin on the screen.";
/*!
  Gets horizontal position of this presentable object origin.
*/
    double GetPosX();
    const string GetPosX__doc__ = "Gets horizontal position of this presentable object origin.";
/*!
  Gets vertical position of this presentable object origin.
*/
    double GetPosY();
    const string GetPosY__doc__ = "Gets vertical position of this presentable object origin.";
/*! \brief Size of this presentable object.

Sets the size of the scalar bar.
\param theWidth  Width of this presentable object. The value can be between 0 and 1.
\param theHeight  Height of this presentable object. The value can be between 0 and 1.
*/
    void SetSize(in double theWidth, in double theHeight);
    const string SetSize__doc__ = "Sets the size of the scalar bar.";
/*!
Gets the width of this presentable object.
*/
    double GetWidth();
    const string GetWidth__doc__ = "Gets the width of this presentable object.";
/*!
Gets the height of this presentable object.
*/
    double GetHeight();
    const string GetHeight__doc__ = "Gets the height of this presentable object.";
/*!
Sets the number of colors which will be used for presentation of this presentable object.
*/
    void SetNbColors(in long theNbColors);
    const string SetNbColors__doc__ = "Sets the number of colors which will be\nused for presentation of this presentable object.";
/*!
Gets the number of colors which will be used for presentation of this presentable object.
*/
    long GetNbColors();
    const string GetNbColors__doc__ = "Gets the number of colors which will be\nused for presentation of this presentable object.";
/*!
Sets the number of labels which will be used for indication of the gradation
 of this presentable object.
*/
    void SetLabels(in long theNbLabels);
    const string SetLabels__doc__ = "Sets the number of labels which will be used\nfor indication of the gradation of this presentable object.";
/*!
Gets the number of labels which will be used for indication of the gradation
 of this presentable object.
*/
    long GetLabels();
    const string GetLabels__doc__ = "Gets the number of labels which will be used\nfor indication of the gradation of this presentable object.";

/*!
Sets the title of this presentable object. For scalar bar by default - the name of the selected result is used.
*/
    void SetTitle(in string theName);
    const string SetTitle__doc__ = "Sets the title of this presentable object. For scalar bar by default - the name of the selected result is used.";
/*!
Gets the title of this presentable object.
*/
    string GetTitle();
    const string GetTitle__doc__ = "Gets the title of this presentable object.";
  };
    const string ScalarMap__doc__ = "The scalarmap interface contains presentation\nparameters of the ScalarMap presentation.";
  //-------------------------------------------------------
/*! \brief Deformed shape presentation interface

Presentation parameters of the deformed shape presentation.
*/
    interface DeformedShape : ScalarMap{
/*!
Sets the scale of the presentatable object.
*/
    void SetScale(in double theScale);
    const string SetScale__doc__ = "Sets the scale of the deformed shape.";
/*!
Gets the scale of the presentatable object.
*/
    double GetScale();
    const string GetScale__doc__ = "Gets the scale of the deformed shape";
  };
    const string DeformedShape__doc__ = "The deformed shape interface contains\nthe presentation parameters of the deformed shape.";
  //-------------------------------------------------------
/*! \brief Cut planes interface

Presentation parameters of Cut planes presentation.
*/
  interface CutPlanes : ScalarMap{
/*!
 This enumeration contains a set of elements defining the orientation in 3D space
 of cut planes presentation.
*/
    enum Orientation {XY, YZ, ZX};
/*!
Sets the type of orientation in 3D space of cut planes presentation.
*/
    void SetOrientationType(in Orientation theNb);
    const string SetOrientationType__doc__ = "Sets the type of orientation in 3D\nspace of cut planes presentation.";
/*!
Gets the type of orientation in 3D space of cut planes presentation.
*/
    Orientation GetOrientationType();
    const string GetOrientationType__doc__ = "Gets the type of orientation in 3D\nspace of cut planes presentation.";
/*!
Sets the number of cut planes.
*/
    void SetNbPlanes(in long theNb);
    const string SetNbPlanes__doc__ = "Sets the number of cut planes.";
/*!
Gets the number of cut planes.
*/
    long GetNbPlanes();
    const string GetNbPlanes__doc__ = "Gets the number of cut planes.";
/*! Rotation around X-axis.
Sets rotation angle of the cut plane presentation.
*/
    void SetRotateX(in double theAngle);
    const string SetRotateX__doc__ = "Rotation around X-axis.\nSets rotation angle of the cut plane presentation.";
/*! Rotation around X-axis.
Gets rotation angle of the cut plane presentation.
*/
    double GetRotateX();
    const string GetRotateX__doc__ = "Rotation around X-axis.\nGets rotation angle of the cut plane presentation.";
/*! Rotation around Y-axis.
Sets rotation angle of the cut plane presentation.
*/
    void SetRotateY(in double theAngle);
    const string SetRotateY__doc__ = "Rotation around Y-axis.\nSets rotation angle of the cut plane presentation.";
/*! Rotation around Y-axis.
Sets rotation angle of the cut plane presentation.
*/
    double GetRotateY();
    const string GetRotateY__doc__ = "Rotation around Y-axis.\nGets rotation angle of the cut plane presentation.";
  };
    const string CutPlanes__doc__ = "The cut planes interface contains\nthe presentation parameters of cut planes presentation.";
  //-------------------------------------------------------
  /*! \brief Interface of the stream lines representation    
  This interface contains presentation parameters of
  stream lines presentations.
  */
  interface StreamLines : DeformedShape{
    enum Direction{ FORWARD,
		    BACKWARD,
		    BOTH
    };
  };
  const string StreamLines__doc__ = "";


/*! \brief Interface of the isometric surface representation

   This interface contains presentation parameters of
    isometric surface presentations.
*/
  interface IsoSurfaces : ScalarMap{
/*!
   Sets the number of isometric surfaces.
*/
    void SetNbSurfaces(in long theNb);
    const string SetNbSurfaces__doc__ = "Sets the number of isometric surfaces.";
/*!
   Gets the number of isometric surfaces
*/
    long GetNbSurfaces();
    const string GetNbSurfaces__doc__ = "Gets the number of isometric surfaces.";
  };
    const string IsoSurfaces__doc__ = "The isometric surface interface contains\nthe presentation parameters of the isometric surface presentations.";
  //-------------------------------------------------------
/*! \brief Interface of the vector presentation.

This interface contains presentation parameters of the vector.
*/
  interface Vectors : DeformedShape{
/*!
Sets the width of the line of the vector.
*/
    void SetLineWidth(in double theWidth);
    const string SetLineWidth__doc__ = "Sets the width of the line of the vector.";
/*!
Gets the width of the line of the vector.
*/
    double GetLineWidth();
    const string GetLineWidth__doc__ = "Gets the width of the line of the vector.";
/*!
 This enumeration contains a set of elements defining the type of representation of the vector head.
*/
    enum GlyphType{ ARROW,
                    CONE2,
                    CONE6,
                    NONE
                  };
/*!
Sets the type of representation of the vector head.
*/
    void SetGlyphType(in GlyphType theType);
    const string SetGlyphType__doc__ = "Sets the type of representation of the vector head.";
/*!
Gets the type of representation of the vector head.
*/
    GlyphType GetGlyphType();
    const string GetGlyphType__doc__ = "Gets the type of representation of the vector head.";
/*!
 This enumeration contains a set of elements defining the position of the vector head.
*/

    enum GlyphPos{ CENTER, /*!<In the center of the vector.*/
                   TAIL,   /*!<In the tail of the vector.*/
                   HEAD  /*!<In the head of the vector.*/
                 };
/*!
Sets the position of the vector head.
*/
    void SetGlyphPos(in GlyphPos thePos);
    const string SetGlyphPos__doc__ = "Sets the position of the vector head.";
/*!
Gets the position of the vector head.
*/
    GlyphPos GetGlyphPos();
    const string GetGlyphPos__doc__ = "Gets the position of the vector head.";
  };
    const string Vectors__doc__ = "Interface of the vector presentation contains\nthe presentation parameters of the vector.";
  //-------------------------------------------------------
/*! \brief Interface %Result

This interface serves for inner representation of data generated in other sources. (MED object or file)
This data is needed for further construction of graphical presentations.
*/
  interface Result : Base {
  };
    const string Result__doc__ = "This interface serves for inner representation\nof data generated in other sources. (MED object or file) This data is needed for further construction of graphical presentations.";
  //-------------------------------------------------------
  interface ViewManager;
/*! \brief %VISU_Gen interface

This is the main interface of %VISU component. It is necessary for creation of
post-processing presentations from given %Result and %Table object reference, using the views
provided by %ViewManager.
*/
   interface VISU_Gen : Engines::Component, SALOMEDS::Driver, Base{
     void SetCurrentStudy(in SALOMEDS::Study theStudy);
     SALOMEDS::Study GetCurrentStudy();
/*!
    Gets the %ViewManager which is used for creation of
    post-processing presentations.
*/
    ViewManager GetViewManager();
    const string GetViewManager__doc__ = "Gets the ViewManager which is used for creation\nof post-processing presentations.";

/*!
Imports tables from a file and create TableAttribute in Sudy
*/
    SALOMEDS::SObject ImportTables(in string theFileName);
/*!
Imports data from a file.
*/
    Result ImportFile(in string theFileName);
    const string ImportFile__doc__ = "Imports data from a file.";
/*!
Imports data from a %MED object field.
*/
    Result ImportMed(in SALOME_MED::FIELD theField);
    const string ImportMed__doc__ = "Imports data from a MED object field.";
/*!
Imports data from a %MED object mesh.
*/
    Result ImportMedMesh(in SALOME_MED::MESH theMesh);
    const string ImportMedMesh__doc__ = "Imports data from a MED object mesh.";

/*!
Imports data from a %MED object SUPPORT.
*/
    Result ImportMedSupport(in SALOME_MED::SUPPORT theSupport);
    const string ImportMedSupport__doc__ = "Imports data from a MED support.";

/*!
Creates a %Mesh on the basis of the data generated in other sources (MED object or file).
*/
    const string CreateMesh__doc__ = "Creates a Mesh on the basis of the data\ngenerated in other sources (MED object or file).";
    Mesh MeshOnEntity(in Result theResult, in string theMeshName, in Entity theEntity);
    Mesh FamilyMeshOnEntity(in Result theResult, in string theMeshName, in Entity theEntity, in string theFamilyName);
    Mesh GroupMesh(in Result theResult, in string theMeshName, in string theGroupName);
/*!
Creates a scalar bar presentation.
\param theResult   Data generated in other sources. (MED object or file)
\param theMeshName  One of the meshes presented in MED file
\param theEntity Type of entity where the field is defined
\param theFieldName  Group of data attributed to the %MESH. The data can be scalar or vector.
\param theIteration  Number of iteration on the field
*/
    ScalarMap ScalarMapOnField(in Result theResult, in string theMeshName, in Entity theEntity, in string theFieldName, in double theIteration);
    const string CreateScalarMap__doc__ = "Creates a scalar bar presentation.";
/*!
Creates a deformed shape presentation.
\param theResult   Data generated in other sources. (MED object or file)
\param theMeshName  One of the meshes presented in MED file
\param theEntity Type of entity where the field is defined
\param theFieldName  Group of data attributed to the %MESH. The data can be scalar or vector.
\param theIteration  Number of iteration on the field
*/
    DeformedShape DeformedShapeOnField(in Result theResult, in string theMeshName, in Entity theEntity, in string theFieldName, in double theIteration);
    const string CreateDeformedShape__doc__ = "Creates a deformed shape presentation.";
/*!
Creates a vector presentation.
\param theResult   Data generated in other sources. (MED object or file)
\param theMeshName  One of the meshes presented in MED file
\param theEntity Type of entity where the field is defined
\param theFieldName  Group of data attributed to the %MESH. The data can be scalar or vector.
\param theIteration  Number of iteration on the field
*/

    Vectors VectorsOnField(in Result theResult, in string theMeshName, in Entity theEntity, in string theFieldName, in double theIteration);
    const string CreateVectors__doc__ = "Creates a vector presentation.";
/*!
Creates an iso surface presentation.
\param theResult   Data generated in other sources. (MED object or file)
\param theMeshName  One of the meshes presented in MED file
\param theEntity Type of entity where the field is defined
\param theFieldName  Group of data attributed to the %MESH. The data can be scalar or vector.
\param theIteration  Number of iteration on the field
*/

    IsoSurfaces IsoSurfacesOnField(in Result theResult, in string theMeshName, in Entity theEntity, in string theFieldName, in double theIteration);
    const string CreateIsoSurfaces__doc__ = "Creates an iso surface presentation.";
/*!
Creates an stream lines presentation.
\param theResult   Data generated in other sources. (MED object or file)
\param theMeshName  One of the meshes presented in MED file
\param theEntity Type of entity where the field is defined
\param theFieldName  Group of data attributed to the %MESH. The data can be scalar or vector.
\param theIteration  Number of iteration on the field
*/    
    StreamLines StreamLinesOnField(in Result theResult, in string theMeshName, in Entity theEntity, in string theFieldName, in double theIteration);
    const string CreateStreamLines__doc__ = "Creates an stream lines presentation.";

/*!
Creates a presentation of cut planes.
\param theResult   Data generated in other sources. (MED object or file)
\param theMeshName  One of the meshes presented in MED file
\param theEntity Type of entity where the field is defined
\param theFieldName  Group of data attributed to the %MESH. The data can be scalar or vector.
\param theIteration  Number of iteration on the field
*/
    CutPlanes CutPlanesOnField(in Result theResult, in string theMeshName, in Entity theEntity, in string theFieldName, in double theIteration);
    const string CreateCutPlanes__doc__ = "Creates a presentation of cut planes.";
/*!
Creates a table presentation.
*/
    Table CreateTable(in string theTableEntry);
    const string CreateTable__doc__ = "Creates a table prasentation containing the data.";
/*!
Creates a curve on the basis of points, whose values are taken from the table.
\param theTable  Table containing the data for construction of curves.
\param HRow  Index of the row in the table:  abscissa of the point.
\param VRow  Index of the row in the table:  ordinate of the point.
*/
    Curve CreateCurve(in Table theTable, in long theHRow, in long theVRow);
    const string CreateCurve__doc__ = "Creates a curve on the basis of points, whose values\nare taken from the table.";
/*!
Creates a presentation form containing an array of references to the curves.
*/
     Container CreateContainer();
     const string CreateContainer__doc__ = "Creates a presentation form containing an array\nof references to the curves.";
  };
     const string VISU_Gen__doc__ = "This is the main interface of the VISU component. It is\nnecessary for creation of post-processing presentations from given result and table object reference, using the views provided by the viewmanager.";
/*! \brief %View interface

 Contains a set of methods used by the %View frame, which can be one of
 the following types: 3d, Table, XY plot.
 %View interface is a base for all types of %view interfaces.
*/
  interface View: Base{
/*!
Sets the title of the %View frame.
*/
    void SetTitle(in string theTitle);
    const string SetTitle__doc__ = "Sets the title of the view frame.";
/*!
Gets the title of the %View frame.
*/
    string GetTitle();
    const string GetTitle__doc__ = "Gets the title of the view frame.";
/*!
Sets background color of the %View frame.
*/
    void SetBackground(in SALOMEDS::Color theColor);
    const string SetBackground__doc__ = "Sets background color of the view frame.";
/*!
Gets background color of the %View frame.
*/
    SALOMEDS::Color GetBackground();
    const string GetBackground__doc__ = "Gets background color of the view frame.";
/*!
Minimizes to the task bar or to the bottom of the Desktop the %View frame.
*/
    void Minimize();
    const string Minimize__doc__ = "Minimizes to the task bar or to the bottom of the\nDesktop the view frame.";
/*!
Restores the %View frame.
*/
    void Restore();
    const string Restore__doc__ = "Restores the view frame.";
/*!
Maximizes the %View frame.
*/
    void Maximize();
    const string Maximize__doc__ = "Maximizes the view frame.";
/*!
Removes all presentations (presentable objects) from the %view.
*/
    void EraseAll();
    const string EraseAll__doc__ = "Removes all presentations (presentable objects) from the view.";
/*!
Displays all presentations (presentable objects) in the %view.
*/
    void DisplayAll();
    const string DisplayAll__doc__ = "Displays all presentations (presentable objects) in the view.";
/*!
Removes a definite presentation (presentable object) from the %view.
*/
    void Erase(in PrsObject thePrsObj);
    const string Erase__doc__ = "Removes a definite presentation (presentable object) from the view.";
/*!
Displays a definite presentation (presentable object) in the %view.
*/
    void Display(in PrsObject thePrsObj);
    const string Display__doc__ = "Displays a definite presentation (presentable object) in the view.";
/*!
Allows to display only a definite presentation (presentable object) in the %view.
All other presentations are removed from the %view.
*/
    void DisplayOnly(in PrsObject thePrsObj);
    const string DisplayOnly__doc__ = "Allows to display only a definite presentation\n(presentable object) in the view. All other presentations are\nremoved from the view.";
/*!
Updates the view.
*/
    void Update();
    const string Update__doc__ = "Updates the view.";

/*!
Saves the view.
*/
    boolean SavePicture(in string theFileName);
    const string SavePicture__doc__ = "Saves the view contents into image file.";
  };

    const string View__doc__ = "Contains a set of methods used by the view frame,\nwhich can be one of the following types:\n3d, table, XY plot.";
  //-------------------------------------------------------
/*! \brief 3D view interface

This interface contains a set of methods necessary for representation of objects in 3D space.
*/

  interface View3D : View {
/*!
This enumeration contains a set of elements determining a predefined point of view
  (position of the camera in 3D space relative to the presentable object).
*/
    enum ViewType{ FRONT, BACK, LEFT, RIGHT, TOP, BOTTOM};
/*!
This enumeration contains a set of elements determining the axis
*/
    enum Axis{ XAxis, YAxis, ZAxis};
/*!
Data type defining coordinates in 3D space.
*/
    typedef double XYZ[3];

/*!
 Makes all presentations, which are currently present in the %view, completely visible.
*/

    void FitAll();
    const string FitAll__doc__ = "Makes all presentations, which are currently present in the\nview, completely visible.";

/*!
Sets a predefined point of view (FRONT, BACK, LEFT, RIGHT, TOP, BOTTOM). (In other words it means
 a predefined position of the camera in 3D space with respect to the object which is represented.)
*/
    void SetView(in ViewType theType);
    const string SetView__doc__ = "Sets a predefined point of view\n(FRONT, BACK, LEFT, RIGHT, TOP, BOTTOM).";

/*!
Sets the position of the camera in 3D space. This point is used as the first point of the vector defining
the view direction of the camera.
*/
    void SetPointOfView(in XYZ theCoord);
    const string SetPointOfView__doc__ = "Sets the position of the camera in 3D space.";
/*!
Gets the position of the camera in 3D space.This point is used as the first point of the vector defining
the view direction of the camera.
*/
    XYZ GetPointOfView();
    const string GetPointOfView__doc__ = "Gets the position of the camera in 3D space.";
/*!
Sets the vertical line of the camera in 3D space.
*/
    void SetViewUp(in XYZ theDir);
    const string SetViewUp__doc__ = "Sets the vertical line of the camera in 3D space.";
/*!
Gets the vertical line of the camera in 3D space.
*/
    XYZ GetViewUp();
    const string GetViewUp__doc__ = "Gets the vertical line of the camera in 3D space.";
/*!
Sets the point of sight of the camera. This point is used as the second point of the vector defining
the view direction of the camera.
*/
    void SetFocalPoint(in XYZ theDir);
    const string SetFocalPoint__doc__ = "Sets the point of sight of the camera.";
/*!
Gets the point of sight of the camera. This point is used as the second point of the vector defining
the view direction of the camera.
*/
    XYZ GetFocalPoint();
    const string GetFocalPoint__doc__ = "Gets the point of sight of the camera.";
/*!
Zooming of the presentable object. Sets the scale.
*/
    void SetParallelScale(in double theScale);
    const string SetParallelScale__doc__ = "Zooming of the presentable object. Sets the scale.";
/*!
Zooming of the presentable object. Gets the scale.
*/
    double GetParallelScale();
    const string GetParallelScale__doc__ = "Zooming of the presentable object. Gets the scale.";
/*!
Scaling of the view along a definite axis.
\param theAxis The axis of the scaling
\param theParam The coefficient of the scaling
*/
    void ScaleView(in Axis theAxis, in double theParam);
    const string ScaleView__doc__ = "Scaling of the view along a definite axis and with a\ndefinite coefficient of the scaling.";
/*!
Removes the scaling of the view.
*/
    void RemoveScale();
    const string RemoveScale__doc__ = "Removes the scaling of the view.";
/*!
Returns True if the view parameters have been created, False if the parameters have been modified.
*/
    boolean SaveViewParams(in string theName);
    const string SaveViewParams__doc__ = "Returns True if the view parameters have been created,\nFalse if the parameters have been modified.";
/*!
Returns True if the view parameters have been found and applied to the view,
False if the parameters with this name don't exist.
*/
    boolean RestoreViewParams(in string theName);
    const string RestoreViewParams__doc__ = "Returns True if the view parameters have been found and\napplied to the view, False if the parameters with this name don't exist.";
  };
    const string View3D__doc__ = "This interface contains a set of methods necessary for representation\nof objects in 3D space.";


  //-------------------------------------------------------
  interface TableView : View {
   
  };


  //-------------------------------------------------------
  interface XYPlot : View {
    void SetSubTitle(in string theTitle);
    string GetSubTitle();

    enum CurveType { POINTS, MULTYLINE, SPLINE};
    void SetCurveType(in CurveType theType);
    CurveType GetCurveType();
	
    void SetMarkerSize(in long theSize);
    long GetMarkerSize();

    void EnableXGrid(in boolean theMajor, in long theNumMajor, in boolean theMinor, in long theNumMinor);
    void EnableYGrid(in boolean theMajor, in long theNumMajor, in boolean theMinor, in long theNumMinor);
 
    void SetHorScaling(in Scaling theScaling);
    Scaling GetHorScaling();
    void SetVerScaling(in Scaling theScaling);
    Scaling GetVerScaling();

    void SetXTitle(in string theTitle);
    string GetXTitle();

    void SetYTitle(in string theTitle);
    string GetYTitle();

    void ShowLegend(in boolean theShowing);

    void FitAll();
  };

  //-------------------------------------------------------
/*! \brief Interface of the %ViewManager

   The %ViewManager is necessary for work with view windows (creation and deletion).
*/

    interface ViewManager: Base{
/*! \brief Getting an active %View Frame

 Returns an object reference to the active %View Frame.
 Type of the %View must be checked.
 \note <BR>Returns nil if there are no views currently opened.
*/

    View GetCurrentView();
    const string GetCurrentView__doc__ = "Getting an active View Frame.\nReturns an object reference to the active view frame.";
/*! \brief Creation of a 3d %View.

 Returns an object reference to the newly created 3d %View.
*/
    View3D Create3DView();
    const string Create3DView__doc__ = "Creation of a 3d view.\nReturns an object reference to the newly created 3d view.";

    TableView CreateTableView(in Table theTable);

    const string CreateTableView__doc__ = "Creation of a table view.\nReturns an object reference to the newly created table view.";
    XYPlot CreateXYPlot();

    const string CreateXYPlot__doc__ = "Creation of a 2d view.\nReturns an object reference to the newly created XYPlot view.";
    void Destroy(in View theView);

    const string Destroy__doc__ = "Destroying of the view";


 };
    const string ViewManager__doc__ = "The ViewManager interface is necessary for work\nwith view windows (creation and deletion).";
};
#endif