//  Copyright (C) 2003  CEA/DEN, EDF R&D
//
//
//
//  File   : VISU_Gen.idl
//  Author : Alexey Petrov

/*! \file VISU_Gen.idl This file conatins a set of interfaces of %VISU module.
      This module will provide various forms of data visualization in %SALOME application.
      These forms include data tables, XY plots, 3d representations
      and combination of these forms.
*/
/*!
 \defgroup Visu SALOME VISU module
*/

#ifndef __VISU_GEN__
#define __VISU_GEN__

#include "SALOME_Exception.idl"
#include "SALOME_Component.idl"
#include "SALOMEDS.idl"
#include "SALOMEDS_Attributes.idl"
#include "MED.idl"

/*! \ingroup Visu
  The main package of interfaces of the module %VISU.
*/
module VISU {
  //-------------------------------------------------------
  typedef string IdType;
  enum Scaling{ LINEAR, LOGARITHMIC};
  enum Entity{ NODE, EDGE, FACE, CELL};
/*!
 This enumeration contains a set of elements defining the type of the module.
*/
   enum VISUType{ TNONE,
		  TCURVE, TTABLE, TCONTAINER, TMESH, TSCALARMAP,
   		  TISOSURFACE, TDEFORMEDSHAPE, TCUTPLANES, TCUTLINES, TVECTORS, TSTREAMLINES,
                  TVISUGEN, TVIEWMANAGER, TRESULT,
	          TXYPLOT, TTABLEVIEW, TVIEW3D,
	          TENTITY, TFAMILY, TGROUP, TFIELD, TTIMESTAMP,
                  TALL};
  interface Base {
/*!
   Returns ID of the object.
*/
    IdType GetID();
/*!
Returns the type of the presentable object
*/
    VISUType GetType();
  };   
/*! \brief Presentable object interface

 It is the root class of all presentable objects.
*/
  interface PrsObject : Base{
  };
  //-------------------------------------------------------
/*! \brief %Table representation interface

Presentation parameters of the %Table view.
*/
  interface Table : PrsObject {
/*!
Sets the title of the table.
*/
    void SetTitle(in string theTitle);
/*!
Gets the title of the table.
*/
    string GetTitle();
/*!
 This enumeration contains a set of elements defining the orientation of the table.
*/
    enum Orientation{ HORIZONTAL, /*!<Horizontal orientation of the table.*/
                       VERTIACAL /*!<Vertical orientation of the table.*/
                    };
/*!
Sets orientation of the table.
*/
    void SetOrientation(in Orientation theOrientation);
/*!
Gets orientation of the table.
*/
    Orientation GetOrientation();
 /*!
Gets the number of rows of the table
 */
    long GetNbRows();
 /*!
Gets the number of columns of the table
 */
    long GetNbColumns();
  };
  //-------------------------------------------------------
/*! \brief Interface of curve representation.

Manages presentation parameters of one curve.
It can be used for presentation of a set of curves using a combined presentation.
*/
  interface Curve : PrsObject{
/*!
Sets the title of the curve.
*/
    void SetTitle(in string theTitle);
/*!
Gets the title of the curve.
*/
    string GetTitle();
/*!
Sets the color of the curve.
*/
    void SetColor(in SALOMEDS::Color theColor);
/*!
Gets the color of the curve.
*/
    SALOMEDS::Color GetColor();
 /*!
 This enumeration contains a set of elements defining the representation type of markers (data points) with help of
which the curve is constructed on the graphics.
*/
    enum MarkerType{ NONE, CIRCLE, RECTANGLE, DIAMOND,
                     DTRIANGLE, UTRIANGLE, LTRIANGLE, RTRIANGLE,
                     CROSS, XCROSS };
/*!
Sets the representation type of markers (data points) with help of
which the curve is constructed on the graphics.
*/
    void SetMarker(in MarkerType theType);
/*!
Gets the representation type of markers (data points) with help of
which the curve is constructed on the graphics.
*/
    MarkerType GetMarker();
/*!
 This enumeration contains a set of elements defining the
 type of representation of curve lines on the graphics.
*/
    enum LineType{ VOIDLINE, SOLIDLINE, DASHLINE, DOTLINE, DASHDOTLINE, DASHDOTDOTLINE};
/*!
Sets the type of representation of curve lines on the graphics.
*/
    void SetLine(in LineType theType, in long theLineWidth);
/*!
Gets the type of representation of curve lines on the graphics.
*/
    LineType GetLine();

/*!
Gets the width of the curve line.
*/
    long GetLineWidth();
  };
//-------------------------------------------------------
/*! \brief The %Container presentable object interface
This interface contains a set of methods used for management of a group of curves
which are stored in the container.
*/
  interface Container : PrsObject{
/*!
Adds a curve into the container.
*/
    void AddCurve(in Curve theCurve);
/*!
Removes a curve from the container.
*/
    void RemoveCurve(in Curve theCurve);
/*!
Gets the number of curves which are stored in the container.
*/
    long GetNbCurves();
/*!
Removes all curves from the container.
*/
    void Clear();

  };
  //-------------------------------------------------------
    interface Prs3d : PrsObject{
      void Destroy();
    };
/*!
 This enumeration contains a set of elements defining the
 type of representation of the mesh.
*/

    enum PresentationType{ POINT,
                           WIREFRAME,
                           SHADED,
                           SHRINK
                         };
/*! \brief Interface of the mesh.

This interface manages the presentation parameters of the mesh.
*/
    interface Mesh : Prs3d{
/*!
Sets the color of mesh cells.
*/
    void SetCellColor(in SALOMEDS::Color theColor);
/*!
Gets the color of mesh cells.
*/
    SALOMEDS::Color GetCellColor();
/*!
Sets the color of mesh nodes.
*/
    void SetNodeColor(in SALOMEDS::Color theColor);
/*!
Gets the color of mesh nodes.
*/
    SALOMEDS::Color GetNodeColor();

/*!
Sets the color of mesh links.
*/
    void SetLinkColor(in SALOMEDS::Color theColor);
/*!
Gets the color of mesh links.
*/
    SALOMEDS::Color GetLinkColor();
/*!
Sets the type of representation of the mesh.
*/
    void SetPresentationType(in PresentationType theType);
/*!
Gets the type of representation of the mesh.
*/
    PresentationType GetPresentationType();
  };
  //-------------------------------------------------------
/*! \brief Interface of the %Scalar Map presentation

This interface contains presentation parameters of the ScalarMap presentation
*/
  interface ScalarMap : Prs3d{
    void SetScalarMode(in long theScaling);
    long GetScalarMode();
    void SetScaling(in Scaling theScaling);
/*!
Gets the type of scaling of the values reflected by this presentation.
*/
    Scaling GetScaling();
/*!
Sets scalar range - min and max boundaries of this presentable object.
\param theMin  Min boundary of this presentable object.
\param theMax  Max boundary of this presentable object.
*/
    void SetRange(in double theMin, in double theMax);
/*!
 Gets the min boundary of this presentable object.
*/
    double GetMin();
/*!
 Gets the max boundary of this presentable object.
*/
    double GetMax();

/*! %Orientation of this presentable object. */
    enum Orientation{
                     HORIZONTAL, /*!< Horizontal orientation of this presentable object.*/
                       VERTICAL  /*!< Vertical orientation of this presentable object.*/
                    };
/*!
 Sets the type of orientation of this presentable object.
*/
    void SetOrientation(in Orientation theOrientation);
/*!
 Gets the type of orientation of this presentable object.
*/
    Orientation GetOrientation();

/*! \brief Position of this presentable object.

Sets the position of this presentable object origin on the screen.
\param X   Horizontal position. The value can be between 0 and 1.
\param Y   Vertical position. The value can be between 0 and 1.
*/
    void SetPosition(in double X, in double Y);
/*!
  Gets horizontal position of this presentable object origin.
*/
    double GetPosX();
/*!
  Gets vertical position of this presentable object origin.
*/
    double GetPosY();
/*! \brief Size of this presentable object.

Sets the size of the scalar bar.
\param theWidth  Width of this presentable object. The value can be between 0 and 1.
\param theHeight  Height of this presentable object. The value can be between 0 and 1.
*/
    void SetSize(in double theWidth, in double theHeight);
/*!
Gets the width of this presentable object.
*/
    double GetWidth();
/*!
Gets the height of this presentable object.
*/
    double GetHeight();
/*!
Sets the number of colors which will be used for presentation of this presentable object.
*/
    void SetNbColors(in long theNbColors);
/*!
Gets the number of colors which will be used for presentation of this presentable object.
*/
    long GetNbColors();
/*!
Sets the number of labels which will be used for indication of the gradation
 of this presentable object.
*/
    void SetLabels(in long theNbLabels);
/*!
Gets the number of labels which will be used for indication of the gradation
 of this presentable object.
*/
    long GetLabels();
/*!
Sets the title of this presentable object. For scalar bar by default - the name of the selected result is used.
*/
    void SetTitle(in string theName);
/*!
Gets the title of this presentable object.
*/
    string GetTitle();
  };
  //-------------------------------------------------------
/*! \brief Deformed shape presentation interface

Presentation parameters of the deformed shape presentation.
*/
    interface DeformedShape : ScalarMap{
/*!
Sets the scale of the presentatable object.
*/
    void SetScale(in double theScale);
/*!
Gets the scale of the presentatable object.
*/
    double GetScale();
  };
  //-------------------------------------------------------
/*! \brief Cut planes interface

Presentation parameters of Cut planes presentation.
*/
  interface CutPlanes : ScalarMap{
/*!
 This enumeration contains a set of elements defining the orientation in 3D space
 of cut planes presentation.
*/
    enum Orientation {XY, YZ, ZX};
/*!
Sets the type of orientation in 3D space of cut planes presentation.
*/
    void SetOrientationType(in Orientation theNb);
/*!
Gets the type of orientation in 3D space of cut planes presentation.
*/
    Orientation GetOrientationType();
    void SetDisplacement(in double theDisp);
    double GetDisplacement();
/*!
Sets the number of cut planes.
*/
    void SetNbPlanes(in long theNb);
/*!
Gets the number of cut planes.
*/
    long GetNbPlanes();
/*! Rotation around X-axis.
Sets rotation angle of the cut plane presentation.
*/
    void SetRotateX(in double theAngle);
/*! Rotation around X-axis.
Gets rotation angle of the cut plane presentation.
*/
    double GetRotateX();
/*! Rotation around Y-axis.
Sets rotation angle of the cut plane presentation.
*/
    void SetRotateY(in double theAngle);
/*! Rotation around Y-axis.
Sets rotation angle of the cut plane presentation.
*/
    double GetRotateY();
  };
  //-------------------------------------------------------
  /*! \brief Interface of the stream lines representation    
  This interface contains presentation parameters of
  stream lines presentations.
  */
/*! \brief Cut lines interface

Presentation parameters of Cut lines presentation.
*/
  interface CutLines : ScalarMap{

    void SetOrientationType(in CutPlanes::Orientation theNb);
    void SetOrientationType2(in CutPlanes::Orientation theNb);

    CutPlanes::Orientation GetOrientationType();
    CutPlanes::Orientation GetOrientationType2();

    void SetDisplacement(in double theDisp);
    void SetDisplacement2(in double theDisp);

    double GetDisplacement();
    double GetDisplacement2();

    void SetNbLines(in long theNb);
    long GetNbLines();

    void SetRotateX(in double theAngle);
    void SetRotateX2(in double theAngle);

    double GetRotateX();
    double GetRotateX2();

    void SetRotateY(in double theAngle);
    void SetRotateY2(in double theAngle);

    double GetRotateY();
    double GetRotateY2();
  };

  interface StreamLines : DeformedShape{
    enum Direction{ FORWARD,
		    BACKWARD,
		    BOTH
    };

    void SetDirection(in Direction theDirection);
    Direction GetDirection();

    void SetStepLength(in double theStep);
    double GetStepLength();

    void SetPropagationTime(in double theTime);
    double GetPropagationTime();

    void SetIntegrationStep(in double theStep);
    double GetIntegrationStep();

    void SetSource(in Prs3d thePrs3d);
    Prs3d GetSource();

    void SetUsedPoints(in double thePercents);
    double GetUsedPoints();
  };


/*! \brief Interface of the isometric surface representation

   This interface contains presentation parameters of
    isometric surface presentations.
*/
  interface IsoSurfaces : ScalarMap{
/*!
   Sets the number of isometric surfaces.
*/
    void SetNbSurfaces(in long theNb);
/*!
   Gets the number of isometric surfaces
*/
    long GetNbSurfaces();
  };
  //-------------------------------------------------------
/*! \brief Interface of the vector presentation.

This interface contains presentation parameters of the vector.
*/
  interface Vectors : DeformedShape{
/*!
Sets the width of the line of the vector.
*/
    void SetLineWidth(in double theWidth);
/*!
Gets the width of the line of the vector.
*/
    double GetLineWidth();
/*!
 This enumeration contains a set of elements defining the type of representation of the vector head.
*/
    enum GlyphType{ ARROW,
                    CONE2,
                    CONE6,
                    NONE
                  };
/*!
Sets the type of representation of the vector head.
*/
    void SetGlyphType(in GlyphType theType);
/*!
Gets the type of representation of the vector head.
*/
    GlyphType GetGlyphType();
/*!
 This enumeration contains a set of elements defining the position of the vector head.
*/

    enum GlyphPos{ CENTER, /*!<In the center of the vector.*/
                   TAIL,   /*!<In the tail of the vector.*/
                   HEAD  /*!<In the head of the vector.*/
                 };
/*!
Sets the position of the vector head.
*/
    void SetGlyphPos(in GlyphPos thePos);
/*!
Gets the position of the vector head.
*/
    GlyphPos GetGlyphPos();
  };
  //-------------------------------------------------------
  interface Animation : Base{
    void addField(in SALOMEDS::SObject theObject);

    void generatePresentations(in long theFieldNum);
    boolean generateFrames();
    void clearView();

    void startAnimation();
    void stopAnimation();

    void nextFrame();
    void prevFrame();
    void firstFrame();
    void lastFrame();
    void gotoFrame(in long theFrame);

    long getNbFields();
    long getNbFrames();
    boolean isRunning();
    long getCurrentFrame();

    ScalarMap getPresentation(in long theField, in long theFrame);

    void setPresentationType(in long theFieldNum, in VISUType theType);
    VISUType getPresentationType(in long theFieldNum);

    void setSpeed(in long theSpeed);
    long getSpeed();

    boolean isProportional();

    void setAnimationRange(in double theMin, in double theMax);
    double getMinRange();
    double getMaxRange();
    boolean isRangeDefined();

    void dumpTo(in string thePath);

    boolean isCycling();

    double getMinTime();
    double getMaxTime();

    void setProportional(in boolean theProp);
    void setCycling(in boolean theCycle);
  };

/*! \brief Interface %Result

This interface serves for inner representation of data generated in other sources. (MED object or file)
This data is needed for further construction of graphical presentations.
*/
  interface Result : Base {
  };
  //-------------------------------------------------------
  interface ViewManager;
  interface View3D;
/*! \brief %VISU_Gen interface

This is the main interface of %VISU component. It is necessary for creation of
post-processing presentations from given %Result and %Table object reference, using the views
provided by %ViewManager.
*/
   interface VISU_Gen : Engines::Component, SALOMEDS::Driver, Base{
     void SetCurrentStudy(in SALOMEDS::Study theStudy);
     SALOMEDS::Study GetCurrentStudy();
/*!
    Gets the %ViewManager which is used for creation of
    post-processing presentations.
*/
    ViewManager GetViewManager();

/*!
Imports tables from a file and create TableAttribute in Sudy
*/
    SALOMEDS::SObject ImportTables(in string theFileName);
/*!
Imports data from a file.
*/
    Result ImportFile(in string theFileName);
/*!
Imports data from a %MED object.
*/
    Result ImportMed(in SALOMEDS::SObject theMedSObject);
/*!
Imports data from a %MED field.
*/
    Result ImportMedField(in SALOME_MED::FIELD theField);
/*!
Creates a %Mesh on the basis of the data generated in other sources (MED object or file).
*/
    Mesh MeshOnEntity(in Result theResult, in string theMeshName, in Entity theEntity);
    Mesh FamilyMeshOnEntity(in Result theResult, in string theMeshName, in Entity theEntity, in string theFamilyName);
    Mesh GroupMesh(in Result theResult, in string theMeshName, in string theGroupName);
/*!
Creates a scalar bar presentation.
\param theResult   Data generated in other sources. (MED object or file)
\param theMeshName  One of the meshes presented in MED file
\param theEntity Type of entity where the field is defined
\param theFieldName  Group of data attributed to the %MESH. The data can be scalar or vector.
\param theIteration  Number of iteration on the field
*/
    ScalarMap ScalarMapOnField(in Result theResult, in string theMeshName, in Entity theEntity, in string theFieldName, in double theIteration);
/*!
Creates a deformed shape presentation.
\param theResult   Data generated in other sources. (MED object or file)
\param theMeshName  One of the meshes presented in MED file
\param theEntity Type of entity where the field is defined
\param theFieldName  Group of data attributed to the %MESH. The data can be scalar or vector.
\param theIteration  Number of iteration on the field
*/
    DeformedShape DeformedShapeOnField(in Result theResult, in string theMeshName, in Entity theEntity, in string theFieldName, in double theIteration);
/*!
Creates a vector presentation.
\param theResult   Data generated in other sources. (MED object or file)
\param theMeshName  One of the meshes presented in MED file
\param theEntity Type of entity where the field is defined
\param theFieldName  Group of data attributed to the %MESH. The data can be scalar or vector.
\param theIteration  Number of iteration on the field
*/

    Vectors VectorsOnField(in Result theResult, in string theMeshName, in Entity theEntity, in string theFieldName, in double theIteration);
/*!
Creates an iso surface presentation.
\param theResult   Data generated in other sources. (MED object or file)
\param theMeshName  One of the meshes presented in MED file
\param theEntity Type of entity where the field is defined
\param theFieldName  Group of data attributed to the %MESH. The data can be scalar or vector.
\param theIteration  Number of iteration on the field
*/

    IsoSurfaces IsoSurfacesOnField(in Result theResult, in string theMeshName, in Entity theEntity, in string theFieldName, in double theIteration);
/*!
Creates an stream lines presentation.
\param theResult   Data generated in other sources. (MED object or file)
\param theMeshName  One of the meshes presented in MED file
\param theEntity Type of entity where the field is defined
\param theFieldName  Group of data attributed to the %MESH. The data can be scalar or vector.
\param theIteration  Number of iteration on the field
*/    
    StreamLines StreamLinesOnField(in Result theResult, in string theMeshName, in Entity theEntity, in string theFieldName, in double theIteration);

/*!
Creates a presentation of cut planes.
\param theResult   Data generated in other sources. (MED object or file)
\param theMeshName  One of the meshes presented in MED file
\param theEntity Type of entity where the field is defined
\param theFieldName  Group of data attributed to the %MESH. The data can be scalar or vector.
\param theIteration  Number of iteration on the field
*/
    CutPlanes CutPlanesOnField(in Result theResult, in string theMeshName, in Entity theEntity, in string theFieldName, in double theIteration);

/*!
Creates a presentation of cut lines.
\param theResult   Data generated in other sources. (MED object or file)
\param theMeshName  One of the meshes presented in MED file
\param theEntity Type of entity where the field is defined
\param theFieldName  Group of data attributed to the %MESH. The data can be scalar or vector.
\param theIteration  Number of iteration on the field
*/
    CutLines CutLinesOnField(in Result theResult, in string theMeshName, in Entity theEntity, in string theFieldName, in double theIteration);

/*!
Creates a table presentation.
*/
    Table CreateTable(in string theTableEntry);
/*!
Creates a curve on the basis of points, whose values are taken from the table.
\param theTable  Table containing the data for construction of curves.
\param HRow  Index of the row in the table:  abscissa of the point.
\param VRow  Index of the row in the table:  ordinate of the point.
*/
    Curve CreateCurve(in Table theTable, in long theHRow, in long theVRow);
/*!
Creates a presentation form containing an array of references to the curves.
*/
     Container CreateContainer();

     Animation CreateAnimation(in View3D theView3d);
  };
/*! \brief %View interface

 Contains a set of methods used by the %View frame, which can be one of
 the following types: 3d, Table, XY plot.
 %View interface is a base for all types of %view interfaces.
*/
  interface View: Base{
/*!
Sets the title of the %View frame.
*/
    void SetTitle(in string theTitle);
/*!
Gets the title of the %View frame.
*/
    string GetTitle();
/*!
Sets background color of the %View frame.
*/
    void SetBackground(in SALOMEDS::Color theColor);
/*!
Gets background color of the %View frame.
*/
    SALOMEDS::Color GetBackground();
/*!
Minimizes to the task bar or to the bottom of the Desktop the %View frame.
*/
    void Minimize();
/*!
Restores the %View frame.
*/
    void Restore();
/*!
Maximizes the %View frame.
*/
    void Maximize();
/*!
Removes all presentations (presentable objects) from the %view.
*/
    void EraseAll();
/*!
Displays all presentations (presentable objects) in the %view.
*/
    void DisplayAll();
/*!
Removes a definite presentation (presentable object) from the %view.
*/
    void Erase(in PrsObject thePrsObj);
/*!
Displays a definite presentation (presentable object) in the %view.
*/
    void Display(in PrsObject thePrsObj);
/*!
Allows to display only a definite presentation (presentable object) in the %view.
All other presentations are removed from the %view.
*/
    void DisplayOnly(in PrsObject thePrsObj);
/*!
Updates the view.
*/
    void Update();

/*!
Saves the view.
*/
    boolean SavePicture(in string theFileName);
  };

  //-------------------------------------------------------
/*! \brief 3D view interface

This interface contains a set of methods necessary for representation of objects in 3D space.
*/

  interface View3D : View {
/*!
This enumeration contains a set of elements determining a predefined point of view
  (position of the camera in 3D space relative to the presentable object).
*/
    enum ViewType{ FRONT, BACK, LEFT, RIGHT, TOP, BOTTOM};
/*!
This enumeration contains a set of elements determining the axis
*/
    enum Axis{ XAxis, YAxis, ZAxis};
/*!
Data type defining coordinates in 3D space.
*/
    typedef double XYZ[3];

/*!
 Makes all presentations, which are currently present in the %view, completely visible.
*/

    void FitAll();

/*!
Sets a predefined point of view (FRONT, BACK, LEFT, RIGHT, TOP, BOTTOM). (In other words it means
 a predefined position of the camera in 3D space with respect to the object which is represented.)
*/
    void SetView(in ViewType theType);

/*!
Sets the position of the camera in 3D space. This point is used as the first point of the vector defining
the view direction of the camera.
*/
    void SetPointOfView(in XYZ theCoord);
/*!
Gets the position of the camera in 3D space.This point is used as the first point of the vector defining
the view direction of the camera.
*/
    XYZ GetPointOfView();
/*!
Sets the vertical line of the camera in 3D space.
*/
    void SetViewUp(in XYZ theDir);
/*!
Gets the vertical line of the camera in 3D space.
*/
    XYZ GetViewUp();
/*!
Sets the point of sight of the camera. This point is used as the second point of the vector defining
the view direction of the camera.
*/
    void SetFocalPoint(in XYZ theDir);
/*!
Gets the point of sight of the camera. This point is used as the second point of the vector defining
the view direction of the camera.
*/
    XYZ GetFocalPoint();
/*!
Zooming of the presentable object. Sets the scale.
*/
    void SetParallelScale(in double theScale);
/*!
Zooming of the presentable object. Gets the scale.
*/
    double GetParallelScale();
/*!
Scaling of the view along a definite axis.
\param theAxis The axis of the scaling
\param theParam The coefficient of the scaling
*/
    void ScaleView(in Axis theAxis, in double theParam);
/*!
Removes the scaling of the view.
*/
    void RemoveScale();
/*!
Returns True if the view parameters have been created, False if the parameters have been modified.
*/
    boolean SaveViewParams(in string theName);
/*!
Returns True if the view parameters have been found and applied to the view,
False if the parameters with this name don't exist.
*/
    boolean RestoreViewParams(in string theName);
  };


  //-------------------------------------------------------
  interface TableView : View {
   
  };


  //-------------------------------------------------------
  interface XYPlot : View {
    void SetSubTitle(in string theTitle);
    string GetSubTitle();

    enum CurveType { POINTS, MULTYLINE, SPLINE};
    void SetCurveType(in CurveType theType);
    CurveType GetCurveType();
	
    void SetMarkerSize(in long theSize);
    long GetMarkerSize();

    void EnableXGrid(in boolean theMajor, in long theNumMajor, in boolean theMinor, in long theNumMinor);
    void EnableYGrid(in boolean theMajor, in long theNumMajor, in boolean theMinor, in long theNumMinor);
 
    void SetHorScaling(in Scaling theScaling);
    Scaling GetHorScaling();
    void SetVerScaling(in Scaling theScaling);
    Scaling GetVerScaling();

    void SetXTitle(in string theTitle);
    string GetXTitle();

    void SetYTitle(in string theTitle);
    string GetYTitle();

    void ShowLegend(in boolean theShowing);

    void FitAll();
  };

  //-------------------------------------------------------
/*! \brief Interface of the %ViewManager

   The %ViewManager is necessary for work with view windows (creation and deletion).
*/

    interface ViewManager: Base{
/*! \brief Getting an active %View Frame

 Returns an object reference to the active %View Frame.
 Type of the %View must be checked.
 \note <BR>Returns nil if there are no views currently opened.
*/

    View GetCurrentView();
/*! \brief Creation of a 3d %View.

 Returns an object reference to the newly created 3d %View.
*/
    View3D Create3DView();

    TableView CreateTableView(in Table theTable);

    XYPlot CreateXYPlot();

    void Destroy(in View theView);

 };
};
#endif