//  Copyright (C) 2007-2010  CEA/DEN, EDF R&D, OPEN CASCADE
//
//  Copyright (C) 2003-2007  OPEN CASCADE, EADS/CCR, LIP6, CEA/DEN,
//  CEDRAT, EDF R&D, LEG, PRINCIPIA R&D, BUREAU VERITAS
//
//  This library is free software; you can redistribute it and/or
//  modify it under the terms of the GNU Lesser General Public
//  License as published by the Free Software Foundation; either
//  version 2.1 of the License.
//
//  This library is distributed in the hope that it will be useful,
//  but WITHOUT ANY WARRANTY; without even the implied warranty of
//  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
//  Lesser General Public License for more details.
//
//  You should have received a copy of the GNU Lesser General Public
//  License along with this library; if not, write to the Free Software
//  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
//
//  See http://www.salome-platform.org/ or email : webmaster.salome@opencascade.com
//
#ifndef __GENERICSOLVER_GEN__
#define __GENERICSOLVER_GEN__

#include "SALOME_Component.idl"
#include "SALOMEDS.idl"
#include "SALOME_Exception.idl"

module GENERICSOLVER_ORB
{

  typedef sequence<double> Point;
  typedef SALOMEDS::ID ID;

  interface GENERICSOLVER_Gen : Engines::Component, SALOMEDS::Driver
  {

    /**
     * @brief Prepare module for later computation.
     *
     * The Init method prepares the module for a series of computation
     * based on a study case. The study case is a set of parameters that
     * globally defines _ALL_ information needed to make a computation.
     * When Init exits, the module is ready to run if a call to an hypothetical
     * method Exec() (without any more argument) occurs.
     *
     * @return                   0 if success, non zero if failure
     * @param studyID            the identifier of the study containing the study case
     * @param entry              the identifier of the study case within the study
     * @param wrapperDescription a string containing the XML wrapper description
     */
    short Init(in short studyID, in ID entry, in string wrapperDescription)
      raises (SALOME::SALOME_Exception);

    /**
     * @brief Run the module with modified parameters
     *
     * The Run method realizes the computation with some parameters (within inPoint)
     * altered compared to what Init set before. The result is put in outPoint.
     *
     * @return          0 if success, non zero if failure
     * @param inPoint   a vector of floating point values to be modified
     * @param outPoint  the result of the computation as a vector of floating point values
     */
    short Exec(in Point inPoint, inout Point outPoint)
      raises (SALOME::SALOME_Exception);

    /**
     * @brief Cleanup everything that was previously set
     *
     * The Finalize method is in charge of cleaning everything that what set hitherto.
     * It may be empty.
     *
     * @return          0 if success, non zero if failure
     */
    short Finalize()
      raises (SALOME::SALOME_Exception);

  };
};

#endif