//  Copyright (C) 2009-2010 EDF R&D
//
//  This library is free software; you can redistribute it and/or
//  modify it under the terms of the GNU Lesser General Public
//  License as published by the Free Software Foundation; either
//  version 2.1 of the License.
//
//  This library is distributed in the hope that it will be useful,
//  but WITHOUT ANY WARRANTY; without even the implied warranty of
//  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
//  Lesser General Public License for more details.
//
//  You should have received a copy of the GNU Lesser General Public
//  License along with this library; if not, write to the Free Software
//  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
//
//  See http://www.salome-platform.org/ or email : webmaster.salome@opencascade.com
//
//  $Id$
//

#ifndef __DEVIATION_GEN__
#define __DEVIATION_GEN__

#include "SALOME_Component.idl"
#include "SALOMEDS.idl"
#include "SALOME_Exception.idl"

module GENERICSOLVER_ORB
{

  typedef sequence<double> Point;
  typedef SALOMEDS::ID ID;
  typedef sequence<string> VarList;

  interface DEVIATION_Gen : Engines::Component, SALOMEDS::Driver
  {

    /**
     * @brief Initialize the component with the deterministic variables and the lists of
     *        probabilistic variables.
     *
     * The Init method prepares the component for a series of computation with
     * the method Exec. It extracts the deterministic data from Salome study and
     * stores this data along with the lists of input and output variables to
     * identify them in future calls to Exec.
     *
     * @param inputVarList   a list of strings containing the names of the input
     *                       variables in the same order as in subsequent calls to Exec.
     * @param outputVarList  a list of strings containing the names of the output
     *                       variables in the same order as they should be returned
     *                       in subsequent calls to Exec.
     * @param studyID        the identifier of the study containing the deterministic data
     * @param entry          the identifier of the deterministic case within the study
     */
    void Init(in VarList inputVarList, in VarList outputVarList, in long studyID, in ID entry)
      raises (SALOME::SALOME_Exception);

    /**
     * @brief Execute a computation with a given sample of variables.
     *
     * The Exec method realizes the computation with some parameters (within
     * inPoint) corresponding to the variables set previously with the method
     * Init. The result is put in outPoint in the order specified by
     * outputVarList of Init method.
     *
     * @param inPoint   a vector of floating point values to be evaluated
     * @param outPoint  the result of the computation as a vector of floating point values
     */
    void Exec(in Point inPoint, out Point outPoint)
      raises (SALOME::SALOME_Exception);

    /**
     * @brief Cleanup everything that was previously set
     *
     * The Finalize method is in charge of cleaning everything that what set hitherto.
     * It may be empty.
     */
    void Finalize()
      raises (SALOME::SALOME_Exception);

  };
};

#endif