src/tool/Utilitaire/uttrir.F

   1       subroutine uttrir ( classt, vmin, vmax,
   2      >                    nbval, valeur,
   3      >                    ulsort, langue, codret)
   4 c ______________________________________________________________________
   5 c
   6 c                             H O M A R D
   7 c
   8 c Outil de Maillage Adaptatif par Raffinement et Deraffinement d'EDF R&D
   9 c
  10 c Version originale enregistree le 18 juin 1996 sous le numero 96036
  11 c aupres des huissiers de justice Simart et Lavoir a Clamart
  12 c Version 11.2 enregistree le 13 fevrier 2015 sous le numero 2015/014
  13 c aupres des huissiers de justice
  14 c Lavoir, Silinski & Cherqui-Abrahmi a Clamart
  15 c
  16 c    HOMARD est une marque deposee d'Electricite de France
  17 c
  18 c Copyright EDF 1996
  19 c Copyright EDF 1998
  20 c Copyright EDF 2002
  21 c Copyright EDF 2020
  22 c ______________________________________________________________________
  23 c
  24 c    UTilitaire - TRI d'un tableau Reel
  25 c    --           ---              -
  26 c ______________________________________________________________________
  27 c .        .     .        .                                            .
  28 c .  nom   . e/s . taille .           description                      .
  29 c .____________________________________________________________________.
  30 c . classt .  s  . nbval  . classement des numeros associes aux valeurs.
  31 c .        .     .        . 1 : le numero de la plus petite valeur     .
  32 c .        .     .        . nbval : le numero de la plus grande valeur .
  33 c . vmin   .  s  .   1    . valeur minimale atteinte                   .
  34 c . vmax   .  s  .   1    . valeur maximale atteinte                   .
  35 c . nbval  . e   .   1    . nombre de valeurs a traiter                .
  36 c . valeur . e   . nbval  . liste des valeurs a ranger                 .
  37 c . ulsort . e   .   1    . numero d'unite logique de la liste standard.
  38 c . langue . e   .    1   . langue des messages                        .
  39 c .        .     .        . 1 : francais, 2 : anglais                  .
  40 c . codret . es  .    1   . code de retour des modules                 .
  41 c .        .     .        . 0 : pas de probleme                        .
  42 c .        .     .        . 1 : probleme                               .
  43 c ______________________________________________________________________
  44 c
  45 c====
  46 c 0. declarations et dimensionnement
  47 c====
  48 c
  49 c 0.1. ==> generalites
  50 c
  51       implicit none
  52       save
  53 c
  54       character*6 nompro
  55       parameter ( nompro = 'UTTRIR' )
  56 c
  57 #include "nblang.h"
  58 c
  59 c 0.2. ==> communs
  60 c
  61 #include "envex1.h"
  62 c
  63 c 0.3. ==> arguments
  64 c
  65       integer nbval
  66       integer classt(nbval)
  67 c
  68       double precision valeur(nbval), vmin, vmax
  69 c
  70       integer ulsort, langue, codret
  71 c
  72 c 0.4. ==> variables locales
  73 c
  74       integer iaux, jaux
  75       integer numero, nbvtri
  76 c
  77       integer nbmess
  78       parameter ( nbmess = 10 )
  79       character*80 texte(nblang,nbmess)
  80 c
  81 c 0.5. ==> initialisations
  82 c ______________________________________________________________________
  83 c
  84 c====
  85 c 1. messages
  86 c====
  87 c
  88 #include "impr01.h"
  89 c
  90 #ifdef _DEBUG_HOMARD_
  91       write (ulsort,texte(langue,1)) 'Entree', nompro
  92       call dmflsh (iaux)
  93 #endif
  94 c
  95       texte(1,4) = '(''Tri d''''un tableau reel.'')'
  96       texte(1,5) = '(''Nombre de valeurs a trier :'',i13)'
  97       texte(1,6) = '(''Valeur minimale :'',g13.7)'
  98       texte(1,7) = '(''Valeur maximale :'',g13.7)'
  99 c
 100       texte(2,4) = '(''Sort of a real array.'')'
 101       texte(2,5) = '(''Number of valeurs to sort :'',i13)'
 102       texte(2,6) = '(''Minimum value :'',g13.7)'
 103       texte(2,7) = '(''Maximum value :'',g13.7)'
 104 c
 105 #ifdef _DEBUG_HOMARD_
 106       write (ulsort,texte(langue,4))
 107       write (ulsort,texte(langue,5)) nbval
 108  1000 format (a,'(',i13,') = ',g13.8)
 109  1001 format (a,'(',g13.8,') = ',g13.8)
 110 #endif
 111 c
 112 c====
 113 c 2. Tri
 114 c====
 115 c
 116       nbvtri = 0
 117 c
 118       do 21 , iaux = 1 , nbval
 119 c
 120 #ifdef _DEBUG_HOMARD_
 121       write (ulsort,1000) 'valeur',iaux, valeur(iaux)
 122 #endif
 123 c
 124 c 2.1. ==> recherche de la valeur superieure a la courante parmi
 125 c          les valeurs deja classees
 126 c
 127         do 211 , jaux = 1 , nbvtri
 128 #ifdef _DEBUG_HOMARD_
 129       write (ulsort,1000) '   classt',jaux, classt(jaux)
 130 #endif
 131           if ( valeur(classt(jaux)).gt.valeur(iaux) ) then
 132             numero = jaux
 133             goto 212
 134           endif
 135   211   continue
 136 c
 137         numero = nbvtri + 1
 138 c
 139 c 2.2. ==> insertion de l'element courant a la bonne place dans la liste
 140 c
 141   212   continue
 142 c
 143 #ifdef _DEBUG_HOMARD_
 144       write (ulsort,1001) '   ==> numero',valeur(iaux), numero
 145 #endif
 146 c
 147         do 213 , jaux = nbvtri, numero, -1
 148           classt(jaux+1) = classt(jaux)
 149   213   continue
 150 c
 151         classt(numero) = iaux
 152 c
 153         nbvtri = nbvtri + 1
 154 c
 155    21 continue
 156 c
 157       vmin = valeur(classt(1))
 158       vmax = valeur(classt(nbval))
 159 c
 160 #ifdef _DEBUG_HOMARD_
 161       write (ulsort,texte(langue,6)) vmin
 162       write (ulsort,texte(langue,7)) vmax
 163 #endif
 164 c
 165 c====
 166 c 4. la fin
 167 c====
 168 c
 169       if ( codret.ne.0 ) then
 170 c
 171 #include "envex2.h"
 172 c
 173       write (ulsort,texte(langue,1)) 'Sortie', nompro
 174       write (ulsort,texte(langue,2)) codret
 175 c
 176       endif
 177 c
 178 #ifdef _DEBUG_HOMARD_
 179       write (ulsort,texte(langue,1)) 'Sortie', nompro
 180       call dmflsh (iaux)
 181 #endif
 182 c
 183       end