src/tool/Suivi_Frontiere/sfindr.F

   1       subroutine sfindr ( seglig, cfaare, famare,
   2      >                    lgetco, taetco,
   3      >                    ulsort, langue, codret)
   4 c ______________________________________________________________________
   5 c
   6 c                             H O M A R D
   7 c
   8 c Outil de Maillage Adaptatif par Raffinement et Deraffinement d'EDF R&D
   9 c
  10 c Version originale enregistree le 18 juin 1996 sous le numero 96036
  11 c aupres des huissiers de justice Simart et Lavoir a Clamart
  12 c Version 11.2 enregistree le 13 fevrier 2015 sous le numero 2015/014
  13 c aupres des huissiers de justice
  14 c Lavoir, Silinski & Cherqui-Abrahmi a Clamart
  15 c
  16 c    HOMARD est une marque deposee d'Electricite de France
  17 c
  18 c Copyright EDF 1996
  19 c Copyright EDF 1998
  20 c Copyright EDF 2002
  21 c Copyright EDF 2020
  22 c ______________________________________________________________________
  23 c
  24 c   Suivi de Frontiere - INhibition du suivi sur les lignes DRoites
  25 c   -        -           --                                 --
  26 c ______________________________________________________________________
  27 c
  28 c but : inhiber le suivi de frontiere pour les aretes pour des
  29 c       aretes pointant vers des droites
  30 c ______________________________________________________________________
  31 c .        .     .        .                                            .
  32 c .  nom   . e/s . taille .           description                      .
  33 c .____________________________________________________________________.
  34 c . seglig . e   .0:sfnbli. pointeur dans le tableau somseg : les      .
  35 c .        .     .        . segments de la ligne i sont aux places de  .
  36 c .        .     .        . seglig(i-1)+1 a seglig(i)-1 inclus         .
  37 c . cfaare . e   . nctfar*. codes des familles des aretes              .
  38 c .        .     . nbfare .   1 : famille MED                          .
  39 c .        .     .        .   2 : type de segment                      .
  40 c .        .     .        .   3 : orientation                          .
  41 c .        .     .        .   4 : famille d'orientation inverse        .
  42 c .        .     .        .   5 : numero de ligne de frontiere         .
  43 c .        .     .        .  > 0 si concernee par le suivi de frontiere.
  44 c .        .     .        . <= 0 si non concernee                      .
  45 c .        .     .        .   6 : famille frontiere active/inactive    .
  46 c .        .     .        .   7 : numero de surface de frontiere       .
  47 c .        .     .        . + l : appartenance a l'equivalence l       .
  48 c . famare . es  . nbarto . famille des aretes                         .
  49 c . lgetco . e   .   1    . longueur du tableau de l'etat courant      .
  50 c . taetco . e   . lgetco . tableau de l'etat courant                  .
  51 c . ulsort . e   .   1    . numero d'unite logique de la liste standard.
  52 c . langue . e   .    1   . langue des messages                        .
  53 c .        .     .        . 1 : francais, 2 : anglais                  .
  54 c . codret . es  .    1   . code de retour des modules                 .
  55 c .        .     .        . 0 : pas de probleme                        .
  56 c .        .     .        . x : probleme                               .
  57 c ______________________________________________________________________
  58 c
  59 c====
  60 c 0. declarations et dimensionnement
  61 c====
  62 c
  63 c 0.1. ==> generalites
  64 c
  65       implicit none
  66       save
  67 c
  68       character*6 nompro
  69       parameter ( nompro = 'SFINDR' )
  70 c
  71 #include "nblang.h"
  72 #include "cofina.h"
  73 #include "cofaar.h"
  74 c
  75 c 0.2. ==> communs
  76 c
  77 #include "front1.h"
  78 #include "dicfen.h"
  79 #include "nbfami.h"
  80 #include "nombar.h"
  81 #include "envex1.h"
  82 c
  83 c 0.3. ==> arguments
  84 c
  85       integer seglig(0:sfnbli)
  86       integer cfaare(nctfar,nbfare), famare(nbarto)
  87 c
  88       integer lgetco
  89       integer taetco(lgetco)
  90 c
  91       integer ulsort, langue, codret
  92 c
  93 c 0.4. ==> variables locales
  94 c
  95       integer nretap, nrsset
  96       integer iaux
  97 c
  98       integer are
  99       logical yadroi
 100 c
 101       character*6 saux
 102 c
 103       integer nbmess
 104       parameter ( nbmess = 10 )
 105       character*80 texte(nblang,nbmess)
 106 c
 107 c 0.5. ==> initialisations
 108 c ______________________________________________________________________
 109 c
 110 c====
 111 c 1. messages
 112 c====
 113 c
 114 c 1.1. ==> les messages
 115 c
 116 #include "impr01.h"
 117 c
 118 #ifdef _DEBUG_HOMARD_
 119       write (ulsort,texte(langue,1)) 'Entree', nompro
 120       call dmflsh (iaux)
 121 #endif
 122 c
 123 c                           789012345678901234567890123
 124       texte(1,4) = '(/,a6,'' INHIBITION SUR LES DROITES'')'
 125       texte(1,5) = '(33(''=''),/)'
 126       texte(1,6) = '(''La ligne '',i4,'' est une droite.'')'
 127 c
 128 c                           7890123456789012345678901234567
 129       texte(2,4) = '(/,a6,'' CANCELLATION ON STRAIGHT LINES'')'
 130       texte(2,5) = '(37(''=''),/)'
 131       texte(2,6) = '(''Line # '',i4,'' is a straight line.'')'
 132 c
 133 #include "impr03.h"
 134 c
 135 c 1.2. ==> le numero de sous-etape
 136 c
 137       nretap = taetco(1)
 138       nrsset = taetco(2) + 1
 139       taetco(2) = nrsset
 140 c
 141       call utcvne ( nretap, nrsset, saux, iaux, codret )
 142 c
 143 c 1.3. ==> le titre
 144 c
 145       write (ulsort,texte(langue,4)) saux
 146       write (ulsort,texte(langue,5))
 147 c
 148 c===
 149 c 2. Impression des numeros des lignes qui sont droites (2 points)
 150 c    On le memorise temporairement en negativant le numero du premier
 151 c    segment decrivant cette ligne
 152 c===
 153 c
 154 cgn      write (ulsort,90002) 'seglig', (seglig(iaux), iaux = 0, sfnbli)
 155       yadroi = .false.
 156 c
 157       do 21 , iaux = 1, sfnbli
 158 c
 159 #ifdef _DEBUG_HOMARD_
 160       write (ulsort,90012) 'Nombre de segments de la ligne', iaux,
 161      >                      abs(seglig(iaux))-abs(seglig(iaux-1))-2
 162 #endif
 163         if ( abs(seglig(iaux))-abs(seglig(iaux-1)).eq.3 ) then
 164 c
 165           write (ulsort,texte(langue,6)) iaux
 166           seglig(iaux) = -seglig(iaux)
 167           yadroi = .true.
 168 c
 169         endif
 170 c
 171    21 continue
 172 c
 173 c===
 174 c 3. S'il y a des droites : les aretes qui sont situees sur de telles
 175 c    lignes doivent etre retirees du suivi de frontiere : inutile de
 176 c    faire des calculs pour rien !
 177 c===
 178 c
 179       if ( yadroi ) then
 180 c
 181 c 3.1 ==>  Pour cela, il suffit de changer leur famille : on remplace
 182 c          leur famille actuelle par celle qui a toutes les memes
 183 c          caracteristiques, sauf celle du suivi de frontiere, stockee
 184 c          dans cosfin (cf. vccfam)
 185 c
 186         do 31 , are = 1, nbarto
 187 c
 188           iaux = cfaare(cosfli,famare(are))
 189 c
 190 c 3.1 ==> l'arete est active pour le SF : elle est sur la ligne iaux
 191 c
 192           if ( iaux.gt.0 ) then
 193 c
 194 c 3.1.1 ==> la ligne iaux est une droite
 195 c
 196             if ( seglig(iaux).lt.0 ) then
 197 c
 198               famare(are) = cfaare(cosfin,famare(are))
 199 c
 200             endif
 201 c
 202           endif
 203 c
 204    31   continue
 205 c
 206 c 3.2. ==> On remet les numeros positifs
 207 c
 208         do 32 , iaux = 1, sfnbli
 209 c
 210           seglig(iaux) = abs(seglig(iaux))
 211 c
 212    32   continue
 213 c
 214       endif
 215 c
 216 c====
 217 c 4. la fin
 218 c====
 219 c
 220       if ( codret.ne.0 ) then
 221 c
 222 #include "envex2.h"
 223 c
 224       write (ulsort,texte(langue,1)) 'Sortie', nompro
 225       write (ulsort,texte(langue,2)) codret
 226 c
 227       endif
 228 c
 229 #ifdef _DEBUG_HOMARD_
 230       write (ulsort,texte(langue,1)) 'Sortie', nompro
 231       call dmflsh (iaux)
 232 #endif
 233 c
 234       end