src/tool/Decision/deiter.F

   1       subroutine deiter ( nivmax,
   2      >                    decare, decfac,
   3      >                    hetare,
   4      >                    aretri, hettri, nivtri,
   5      >                    tritet,
   6      >                    tesupp, teindi,
   7      >                    ulsort, langue, codret)
   8 c ______________________________________________________________________
   9 c
  10 c                             H O M A R D
  11 c
  12 c Outil de Maillage Adaptatif par Raffinement et Deraffinement d'EDF R&D
  13 c
  14 c Version originale enregistree le 18 juin 1996 sous le numero 96036
  15 c aupres des huissiers de justice Simart et Lavoir a Clamart
  16 c Version 11.2 enregistree le 13 fevrier 2015 sous le numero 2015/014
  17 c aupres des huissiers de justice
  18 c Lavoir, Silinski & Cherqui-Abrahmi a Clamart
  19 c
  20 c    HOMARD est une marque deposee d'Electricite de France
  21 c
  22 c Copyright EDF 1996
  23 c Copyright EDF 1998
  24 c Copyright EDF 2002
  25 c Copyright EDF 2020
  26 c ______________________________________________________________________
  27 c
  28 c traitement des DEcisions - Initialisation de l'indicateur entier
  29 c                --          -
  30 c                          - cas des TEtraedres - Raffinement
  31 c                                    --           -
  32 c ______________________________________________________________________
  33 c .        .     .        .                                            .
  34 c .  nom   . e/s . taille .           description                      .
  35 c .____________________________________________________________________.
  36 c . nivmax . e   .   1    . niveau max a ne pas depasser en raffinement.
  37 c . decare .  s  .0:nbarto. decisions des aretes                       .
  38 c . decfac .  s  . -nbquto. decision sur les faces (quad. + tri.)      .
  39 c .        .     . :nbtrto.                                            .
  40 c . hetare . e   . nbarto . historique de l'etat des aretes            .
  41 c . aretri . e   .nbtrto*3. numeros des 3 aretes des triangles         .
  42 c . hettri . e   . nbtrto . historique de l'etat des triangles         .
  43 c . nivtri . e   . nbtrto . niveau des triangles                       .
  44 c . tritet . e   .nbtecf*4. numeros des 4 triangles des tetraedres     .
  45 c . tesupp . e   . nbteto . support pour les tetraedres                .
  46 c . teindi . e   . nbteto . valeurs entieres pour les tetraedres       .
  47 c . ulsort . e   .   1    . numero d'unite logique de la liste standard.
  48 c . langue . e   .    1   . langue des messages                        .
  49 c .        .     .        . 1 : francais, 2 : anglais                  .
  50 c . codret . es  .    1   . code de retour des modules                 .
  51 c .        .     .        . 0 : pas de probleme                        .
  52 c .        .     .        . 2 : probleme dans le traitement            .
  53 c ______________________________________________________________________
  54 c
  55 c====
  56 c 0. declarations et dimensionnement
  57 c====
  58 c
  59 c 0.1. ==> generalites
  60 c
  61       implicit none
  62       save
  63 c
  64       character*6 nompro
  65       parameter ( nompro = 'DEITER' )
  66 c
  67 #include "nblang.h"
  68 c
  69 c 0.2. ==> communs
  70 c
  71 #include "envex1.h"
  72 #include "nombar.h"
  73 #include "nombtr.h"
  74 #include "nombqu.h"
  75 #include "nombte.h"
  76 #include "impr02.h"
  77 c
  78 c 0.3. ==> arguments
  79 c
  80       integer nivmax
  81       integer decare(0:nbarto), decfac(-nbquto:nbtrto)
  82       integer hetare(nbarto)
  83       integer aretri(nbtrto,3), hettri(nbtrto), nivtri(nbtrto)
  84       integer tritet(nbtecf,4)
  85       integer tesupp(nbteto), teindi(nbteto)
  86 c
  87       integer ulsort, langue, codret
  88 c
  89 c 0.4. ==> variables locales
  90 c
  91       integer areloc, facloc
  92       integer letria, letetr
  93       integer iaux, jaux, kaux
  94 c
  95       integer nbmess
  96       parameter (nbmess = 30 )
  97       character*80 texte(nblang,nbmess)
  98 c ______________________________________________________________________
  99 c
 100 c====
 101 c 1. initialisation
 102 c====
 103 c
 104 c 1.1. ==> Les messages
 105 c
 106 #include "impr01.h"
 107 c
 108 #ifdef _DEBUG_HOMARD_
 109       write (ulsort,texte(langue,1)) 'Entree', nompro
 110       call dmflsh (iaux)
 111 #endif
 112 c
 113 #include "impr05.h"
 114 #include "derco1.h"
 115 c
 116       codret = 0
 117 c
 118 c====
 119 c 2. traitement des indicateurs portant sur les tetraedres
 120 c    pour le filtrage sur les niveaux, on tient compte du fait que
 121 c    le niveau d'un tetraedre est identifie a celui de l'une quelconque
 122 c    de ses triangles.
 123 c====
 124 c
 125 #ifdef _DEBUG_HOMARD_
 126         write(ulsort,texte(langue,4)) mess14(langue,3,3)
 127 #endif
 128 c
 129 #ifdef _DEBUG_HOMARD_
 130         write(ulsort,texte(langue,5))
 131 #endif
 132 c
 133       iaux = 0
 134 c
 135       do 21 , letetr = 1, nbteto
 136 c
 137         if ( tesupp(letetr).ne.0 ) then
 138           if ( teindi(letetr).eq.1 ) then
 139 cgn      write (ulsort,*) '--> tetra ',letetr
 140             jaux = tritet(letetr,1)
 141             if ( nivmax.ge.0 .and. nivtri(jaux).ge.nivmax ) then
 142               iaux = iaux + 1
 143             else
 144               do 22 , facloc = 1, 4
 145                 letria = tritet(letetr,facloc)
 146 cgn      write (ulsort,*) '----> tria ',letria
 147                 if ( mod(hettri(letria),10).eq.0 ) then
 148                   decfac(letria) = 4
 149                 endif
 150                 do 23 , areloc = 1, 3
 151                   kaux = aretri(letria,areloc)
 152                   if ( mod(hetare(kaux),10).eq.0 ) then
 153                     decare(kaux) = 2
 154                   elseif ( mod(hetare(kaux),10).eq.2 ) then
 155                     decare(kaux) = 0
 156                   endif
 157    23           continue
 158    22         continue
 159             endif
 160           endif
 161         endif
 162 c
 163    21 continue
 164 c
 165       if ( iaux.ne.0 ) then
 166         write(ulsort,texte(langue,10))
 167         write(ulsort,texte(langue,4)) mess14(langue,3,3)
 168         write(ulsort,texte(langue,7)) nivmax
 169         write(ulsort,texte(langue,9)) iaux
 170       endif
 171 c
 172 c====
 173 c 3. la fin
 174 c====
 175 c
 176       if ( codret.ne.0 ) then
 177 c
 178 #include "envex2.h"
 179 c
 180       write (ulsort,texte(langue,1)) 'Sortie', nompro
 181       write (ulsort,texte(langue,2)) codret
 182 c
 183       endif
 184 c
 185 #ifdef _DEBUG_HOMARD_
 186       write (ulsort,texte(langue,1)) 'Sortie', nompro
 187       call dmflsh (iaux)
 188 #endif
 189 c
 190       end