src/tool/Decision/deiper.F

   1       subroutine deiper ( nivmax,
   2      >                    decare, decfac,
   3      >                    hetare,
   4      >                    aretri, hettri, nivtri,
   5      >                    arequa, hetqua,
   6      >                    facpen,
   7      >                    pesupp, peindi,
   8      >                    ulsort, langue, codret)
   9 c ______________________________________________________________________
  10 c
  11 c                             H O M A R D
  12 c
  13 c Outil de Maillage Adaptatif par Raffinement et Deraffinement d'EDF R&D
  14 c
  15 c Version originale enregistree le 18 juin 1996 sous le numero 96036
  16 c aupres des huissiers de justice Simart et Lavoir a Clamart
  17 c Version 11.2 enregistree le 13 fevrier 2015 sous le numero 2015/014
  18 c aupres des huissiers de justice
  19 c Lavoir, Silinski & Cherqui-Abrahmi a Clamart
  20 c
  21 c    HOMARD est une marque deposee d'Electricite de France
  22 c
  23 c Copyright EDF 1996
  24 c Copyright EDF 1998
  25 c Copyright EDF 2002
  26 c Copyright EDF 2020
  27 c ______________________________________________________________________
  28 c
  29 c traitement des DEcisions - Initialisation de l'indicateur entier
  30 c                --          -
  31 c                          - cas des PEntaedres - Raffinement
  32 c                                    --           -
  33 c ______________________________________________________________________
  34 c .        .     .        .                                            .
  35 c .  nom   . e/s . taille .           description                      .
  36 c .____________________________________________________________________.
  37 c . nivmax . e   .   1    . niveau max a ne pas depasser en raffinement.
  38 c . decare .  s  .0:nbarto. decisions des aretes                       .
  39 c . decfac .  s  . -nbquto. decision sur les faces (quad. + tri.)      .
  40 c .        .     . :nbtrto.                                            .
  41 c . hetare . e   . nbarto . historique de l'etat des aretes            .
  42 c . aretri . e   .nbtrto*3. numeros des 3 aretes des triangles         .
  43 c . hettri . e   . nbtrto . historique de l'etat des triangles         .
  44 c . nivtri . e   . nbtrto . niveau des triangles                       .
  45 c . arequa . e   .nbquto*4. numeros des 4 aretes des quadrangles       .
  46 c . hetqua . e   . nbquto . historique de l'etat des quadrangles       .
  47 c . facpen . e   .nbpecf*5. numeros des faces des pentaedres           .
  48 c . pesupp . e   . nbpeto . support pour les pentaedres                .
  49 c . peindi . e   . nbpeto . valeurs entieres pour les pentaedres       .
  50 c . ulsort . e   .   1    . numero d'unite logique de la liste standard.
  51 c . langue . e   .    1   . langue des messages                        .
  52 c .        .     .        . 1 : francais, 2 : anglais                  .
  53 c . codret . es  .    1   . code de retour des modules                 .
  54 c .        .     .        . 0 : pas de probleme                        .
  55 c .        .     .        . 2 : probleme dans le traitement            .
  56 c ______________________________________________________________________
  57 c
  58 c====
  59 c 0. declarations et dimensionnement
  60 c====
  61 c
  62 c 0.1. ==> generalites
  63 c
  64       implicit none
  65       save
  66 c
  67       character*6 nompro
  68       parameter ( nompro = 'DEIPER' )
  69 c
  70 #include "nblang.h"
  71 c
  72 c 0.2. ==> communs
  73 c
  74 #include "envex1.h"
  75 #include "nombar.h"
  76 #include "nombtr.h"
  77 #include "nombqu.h"
  78 #include "nombpe.h"
  79 #include "impr02.h"
  80 c
  81 c 0.3. ==> arguments
  82 c
  83       integer nivmax
  84       integer decare(0:nbarto), decfac(-nbquto:nbtrto)
  85       integer hetare(nbarto)
  86       integer aretri(nbtrto,3), hettri(nbtrto), nivtri(nbtrto)
  87       integer arequa(nbquto,4), hetqua(nbquto)
  88       integer facpen(nbpecf,5)
  89       integer pesupp(nbpeto), peindi(nbpeto)
  90 c
  91       integer ulsort, langue, codret
  92 c
  93 c 0.4. ==> variables locales
  94 c
  95       integer areloc, facloc
  96       integer laface, lepent
  97       integer iaux, jaux, kaux
  98 c
  99       integer nbmess
 100       parameter (nbmess = 10 )
 101       character*80 texte(nblang,nbmess)
 102 c ______________________________________________________________________
 103 c
 104 c====
 105 c 1. initialisation
 106 c====
 107 c
 108 c 1.1. ==> Les messages
 109 c
 110 #include "impr01.h"
 111 c
 112 #ifdef _DEBUG_HOMARD_
 113       write (ulsort,texte(langue,1)) 'Entree', nompro
 114       call dmflsh (iaux)
 115 #endif
 116 c
 117 #include "impr05.h"
 118 c
 119       codret = 0
 120 c
 121 c====
 122 c 2. traitement des indicateurs portant sur les pentaedres
 123 c    pour le filtrage sur les niveaux, on tient compte du fait que
 124 c    le niveau d'un pentaedre est identifie a celui de n'importe lequel
 125 c    de ses faces.
 126 c====
 127 c
 128 #ifdef _DEBUG_HOMARD_
 129         write(ulsort,texte(langue,4)) mess14(langue,3,7)
 130 #endif
 131 c
 132 #ifdef _DEBUG_HOMARD_
 133         write(ulsort,texte(langue,5))
 134 #endif
 135 c
 136       iaux = 0
 137 c
 138       do 21 , lepent = 1, nbpeto
 139 cgn        print *,lepent,pesupp(lepent),peindi(lepent)
 140         if ( pesupp(lepent).ne.0 ) then
 141           if ( peindi(lepent).eq.1 ) then
 142             jaux = facpen(lepent,1)
 143             if ( nivmax.ge.0 .and. nivtri(jaux).ge.nivmax ) then
 144               iaux = iaux + 1
 145             else
 146               do 22 , facloc = 1, 5
 147                 laface = facpen(lepent,facloc)
 148                 if ( facloc.le.2 ) then
 149                   if ( mod(hettri(laface),10).eq.0 ) then
 150                     decfac(laface) = 4
 151                   endif
 152                   do 23 , areloc = 1, 3
 153                     kaux = aretri(laface,areloc)
 154                     if ( mod(hetare(kaux),10).eq.0 ) then
 155 cgn        write(ulsort,*) 'raffinement de arete', kaux
 156                         decare(kaux) = 2
 157                     elseif ( mod(hetare(kaux),10).eq.2 ) then
 158 cgn        write(ulsort,*) 'maintien de arete', kaux
 159                       decare(kaux) = 0
 160                     endif
 161    23             continue
 162                 else
 163                   if ( mod(hetqua(laface),100).eq.0 ) then
 164                     decfac(-laface) = 4
 165                   endif
 166                   do 24 , areloc = 1, 4
 167                     kaux = arequa(laface,areloc)
 168                     if ( mod(hetare(kaux),10).eq.0 ) then
 169                       decare(kaux) = 2
 170 cgn        write(ulsort,*) 'raffinement de arete', kaux
 171                     elseif ( mod(hetare(kaux),10).eq.2 ) then
 172                       decare(kaux) = 0
 173 cgn        write(ulsort,*) 'maintien de arete', kaux
 174                     endif
 175    24             continue
 176                 endif
 177    22         continue
 178             endif
 179           endif
 180         endif
 181 c
 182    21 continue
 183 c
 184       if ( iaux.ne.0 ) then
 185         write(ulsort,texte(langue,10))
 186         write(ulsort,texte(langue,4)) mess14(langue,3,6)
 187         write(ulsort,texte(langue,7)) nivmax
 188         write(ulsort,texte(langue,9)) iaux
 189       endif
 190 c
 191 c====
 192 c 3. la fin
 193 c====
 194 c
 195       if ( codret.ne.0 ) then
 196 c
 197 #include "envex2.h"
 198 c
 199       write (ulsort,texte(langue,1)) 'Sortie', nompro
 200       write (ulsort,texte(langue,2)) codret
 201 c
 202       endif
 203 c
 204 #ifdef _DEBUG_HOMARD_
 205       write (ulsort,texte(langue,1)) 'Sortie', nompro
 206       call dmflsh (iaux)
 207 #endif
 208 c
 209       end