src/tool/Creation_Maillage/cmh608.F

   1       subroutine cmh608 ( lehexa,
   2      >                    indnoe, indare, indtet, indpyr, indhex,
   3      >                    indptp,
   4      >                    listso, listar, listfa, listcf,
   5      >                    coonoe, hetnoe, arenoe,
   6      >                    famnoe,
   7      >                    hetare, somare,
   8      >                    filare, merare, famare,
   9      >                    aretri,
  10      >                    arequa, filqua,
  11      >                    hettet, aretet,
  12      >                    filtet, pertet, famtet,
  13      >                    hetpyr, arepyr,
  14      >                    filpyr, perpyr, fampyr,
  15      >                    hethex, arehex,
  16      >                    filhex, perhex, famhex,
  17      >                    cfahex,
  18      >                    ulsort, langue, codret )
  19 c ______________________________________________________________________
  20 c
  21 c                             H O M A R D
  22 c
  23 c Outil de Maillage Adaptatif par Raffinement et Deraffinement d'EDF R&D
  24 c
  25 c Version originale enregistree le 18 juin 1996 sous le numero 96036
  26 c aupres des huissiers de justice Simart et Lavoir a Clamart
  27 c Version 11.2 enregistree le 13 fevrier 2015 sous le numero 2015/014
  28 c aupres des huissiers de justice
  29 c Lavoir, Silinski & Cherqui-Abrahmi a Clamart
  30 c
  31 c    HOMARD est une marque deposee d'Electricite de France
  32 c
  33 c Copyright EDF 1996
  34 c Copyright EDF 1998
  35 c Copyright EDF 2002
  36 c Copyright EDF 2020
  37 c ______________________________________________________________________
  38 c
  39 c    Creation du Maillage - decoupage de conformite des Hexaedres
  40 c    -           -                                      -
  41 c ______________________________________________________________________
  42 c .        .     .        .                                            .
  43 c .  nom   . e/s . taille .           description                      .
  44 c .____________________________________________________________________.
  45 c . lehexa . e   .   1    . hexaedre a decouper                        .
  46 c . indnoe . es  .   1    . indice du dernier noeud cree               .
  47 c . indare . es  .   1    . indice de la derniere arete creee          .
  48 c . indtet . es  .   1    . indice du dernier tetraedre cree           .
  49 c . indpyr . es  .   1    . indice de la derniere pyramide creee       .
  50 c . indhex . es  .   1    . indice du dernier hexaedre cree            .
  51 c . indptp . es  .   1    . indice du dernier pere enregistre          .
  52 c . listso . e   .   8    . numeros globaux des sommets                .
  53 c . listar . e   .  12    . numeros globaux des aretes                 .
  54 c . listfa . e   .   6    . numeros globaux des faces                  .
  55 c . listcf . e   .   6    . codes des faces                            .
  56 c . coonoe . es  .nouvno*3. coordonnees des noeuds                     .
  57 c . hetnoe . es  . nouvno . historique de l'etat des noeuds            .
  58 c . arenoe . es  . nouvno . arete liee a un nouveau noeud              .
  59 c . famnoe . es  . nouvno . famille des noeuds                         .
  60 c . hetare . es  . nouvar . historique de l'etat des aretes            .
  61 c . somare . es  .2*nouvar. numeros des extremites d'arete             .
  62 c . filare . es  . nouvar . premiere fille des aretes                  .
  63 c . merare . es  . nouvar . mere des aretes                            .
  64 c . famare . es  . nouvar . famille des aretes                         .
  65 c . aretri . e   .nouvtr*3. numeros des 3 aretes des triangles         .
  66 c . arequa . e   .nouvqu*4. numeros des 4 aretes des quadrangles       .
  67 c . filqua . e   . nouvqu . premier fils des quadrangles               .
  68 c . hettet . es  . nouvte . historique de l'etat des tetraedres        .
  69 c . aretet . es  .nouvta*6. numeros des 6 aretes des tetraedres        .
  70 c . filtet . es  . nouvte . premier fils des tetraedres                .
  71 c . pertet . es  . nouvte . pere des tetraedres                        .
  72 c .        .     .        . si pertet(i) > 0 : numero du tetraedre     .
  73 c .        .     .        . si pertet(i) < 0 : -numero dans pthepe     .
  74 c . famtet . es  . nouvte . famille des tetraedres                     .
  75 c . hetpyr . es  . nouvpy . historique de l'etat des pyramides         .
  76 c . arepyr . es  .nouvya*8. numeros des 8 aretes des pyramides         .
  77 c . filpyr . es  . nouvpy . premier fils des pyramides                 .
  78 c . perpyr . es  . nouvpy . pere des pyramides                         .
  79 c .        .     .        . si perpyr(i) > 0 : numero de la pyramide   .
  80 c .        .     .        . si perpyr(i) < 0 : -numero dans pphepe     .
  81 c . fampyr . es  . nouvpy . famille des pyramides                      .
  82 c . hethex . es  . nouvhe . historique de l'etat des hexaedres         .
  83 c . arehex . es  .nouvha12. numeros des 12 aretes des hexaedres        .
  84 c . filhex . es  . nouvhe . premier fils des hexaedres                 .
  85 c . perhex . es  . nouvhe . pere des hexaedres                         .
  86 c . famhex . es  . nouvhe . famille des hexaedres                      .
  87 c . cfahex . e   . nctfhe. codes des familles des hexaedres            .
  88 c .        .     . nbfhex .   1 : famille MED                          .
  89 c .        .     .        .   2 : type d'hexaedres                     .
  90 c .        .     .        .   3 : famille des tetraedres de conformite .
  91 c .        .     .        .   4 : famille des pyramides de conformite  .
  92 c . ulsort . e   .   1    . unite logique de la sortie generale        .
  93 c . langue . e   .    1   . langue des messages                        .
  94 c .        .     .        . 1 : francais, 2 : anglais                  .
  95 c . codret . es  .    1   . code de retour des modules                 .
  96 c ______________________________________________________________________
  97 c
  98 c====
  99 c 0. declarations et dimensionnement
 100 c====
 101 c
 102 c 0.1. ==> generalites
 103 c
 104       implicit none
 105       save
 106 c
 107       integer nbarin
 108       character*6 nompro
 109       parameter ( nompro ='CMH608' )
 110       parameter ( nbarin = 18 )
 111 c
 112       integer nbsomm
 113       parameter ( nbsomm = 8 )
 114 c
 115 #include "nblang.h"
 116 #include "cofpfh.h"
 117 c
 118 c 0.2. ==> communs
 119 c
 120 #include "envex1.h"
 121 c
 122 #include "envca1.h"
 123 #include "dicfen.h"
 124 #include "nbfami.h"
 125 #include "nouvnb.h"
 126 c
 127 c 0.3. ==> arguments
 128 c
 129       integer lehexa
 130       integer indnoe, indare, indtet, indpyr, indhex
 131       integer indptp
 132       integer listso(8), listar(12), listfa(6), listcf(6)
 133       integer hetnoe(nouvno), arenoe(nouvno)
 134       integer famnoe(nouvno)
 135       integer hetare(nouvar), somare(2,nouvar)
 136       integer filare(nouvar), merare(nouvar), famare(nouvar)
 137       integer aretri(nouvtr,3)
 138       integer arequa(nouvqu,4)
 139       integer filqua(nouvqu)
 140       integer hettet(nouvte), aretet(nouvta,6)
 141       integer filtet(nouvte), pertet(nouvte), famtet(nouvte)
 142       integer hetpyr(nouvpy), arepyr(nouvya,8)
 143       integer filpyr(nouvpy), perpyr(nouvpy), fampyr(nouvpy)
 144       integer arehex(nouvha,12)
 145       integer hethex(nouvhe)
 146       integer filhex(nouvhe), perhex(nouvhe)
 147       integer cfahex(nctfhe,nbfhex), famhex(nouvhe)
 148 c
 149       double precision coonoe(nouvno,sdim)
 150 c
 151       integer ulsort, langue, codret
 152 c
 153 c 0.4. ==> variables locales
 154 c
 155       integer iaux, jaux
 156 c
 157       integer lesnoe(nbarin), areint(nbarin)
 158       integer lisomm(10), liarin(10)
 159       integer fdnume, fdcode
 160       integer are1, are2, are3, are4
 161       integer are5, are6, are7, are8
 162
 163 c
 164       integer nbmess
 165       parameter ( nbmess = 10 )
 166       character*80 texte(nblang,nbmess)
 167 c
 168 c 0.5. ==> initialisations
 169 c ______________________________________________________________________
 170 c
 171 c====
 172 c 1. messages
 173 c====
 174 c
 175 #include "impr01.h"
 176 #include "impr03.h"
 177 c
 178 #ifdef _DEBUG_HOMARD_
 179       write (ulsort,texte(langue,1)) 'Entree', nompro
 180       call dmflsh (iaux)
 181 #endif
 182 c
 183 #ifdef _DEBUG_HOMARD_
 184       write (ulsort,90002) 'indnoe', indnoe
 185       write (ulsort,90002) 'indtet', indtet
 186       write (ulsort,90002) 'indpyr', indpyr
 187       write (ulsort,90002) 'indhex', indhex
 188 #endif
 189 #ifdef _DEBUG_HOMARD_
 190       write (ulsort,90002) 'listar  1-8', (listar(iaux),iaux=1,8)
 191       write (ulsort,90002) 'listar 9-12', (listar(iaux),iaux=9,12)
 192       write (ulsort,90002) 'listso', listso
 193       write (ulsort,90002) 'listfa', listfa
 194       write (ulsort,90002) 'listcf', listcf
 195 #endif
 196 c
 197       codret = 0
 198 c
 199 c====
 200 c 2. Recuperation
 201 c    . des sommets de l'hexaedre
 202 c    . des noeuds milieux des 6 aretes coupees
 203 c    . des noeuds milieux des 4 faces coupees en 3 quadrangles
 204 c====
 205 c
 206       do 21 , iaux = 1 , 8
 207         lesnoe(iaux) = listso(iaux)
 208    21 continue
 209 c
 210       lesnoe(9) = somare(2,filare(listar(1)))
 211       lesnoe(10) = somare(2,filare(listar(2)))
 212       lesnoe(11) = somare(2,filare(listar(7)))
 213       lesnoe(12) = somare(2,filare(listar(8)))
 214       lesnoe(13) = somare(2,filare(listar(9)))
 215       lesnoe(14) = somare(2,filare(listar(11)))
 216 c
 217       iaux = filqua(listfa(1))
 218       lesnoe(15) = somare(2,arequa(iaux,4))
 219       iaux = filqua(listfa(3))
 220       lesnoe(16) = somare(2,arequa(iaux,4))
 221       iaux = filqua(listfa(4))
 222       lesnoe(17) = somare(2,arequa(iaux,4))
 223       iaux = filqua(listfa(6))
 224       lesnoe(18) = somare(2,arequa(iaux,4))
 225 #ifdef _DEBUG_HOMARD_
 226       do 2000 , iaux = 1 , nbarin
 227         write(ulsort,90015) 'lesnoe(',iaux,') = ', lesnoe(iaux)
 228  2000 continue
 229 #endif
 230 c
 231 c====
 232 c 3. Creation du noeud interne et des dix-huit aretes internes
 233 c====
 234 c
 235 #ifdef _DEBUG_HOMARD_
 236       write (ulsort,texte(langue,3)) 'CMCHPB', nompro
 237 #endif
 238       call cmchpb ( indnoe, indare, nbarin,
 239      >              nbsomm, lesnoe, areint,
 240      >              coonoe, hetnoe, arenoe,
 241      >              famnoe,
 242      >              hetare, somare,
 243      >              filare, merare, famare,
 244      >              ulsort, langue, codret )
 245 c
 246 c====
 247 c 4. Creation des seize pyramides
 248 c====
 249 c
 250       iaux = -indptp
 251       jaux = cfahex(cofpfh,famhex(lehexa))
 252 c
 253 c 4.1. ==> Sur la face 1
 254 c
 255       liarin(1) = areint(1)
 256       liarin(2) = areint(4)
 257       liarin(3) = areint(3)
 258       liarin(4) = areint(2)
 259       liarin(5) = areint(10)
 260       liarin(6) = areint(9)
 261       liarin(7) = areint(15)
 262       fdcode = listcf(1)
 263       fdnume = listfa(1)
 264 c
 265 #ifdef _DEBUG_HOMARD_
 266       write (ulsort,texte(langue,3)) 'CMCPY3 - face 1', nompro
 267 #endif
 268       call cmcpy3 ( lehexa, indpyr, indptp,
 269      >              fdnume, fdcode,
 270      >              liarin,
 271      >              arequa, filqua,
 272      >              arepyr, fampyr,
 273      >              hetpyr, filpyr, perpyr,
 274      >              famhex, cfahex,
 275      >              ulsort, langue, codret )
 276 c
 277 c 4.2. ==> Sur la face 2
 278 c
 279       lisomm(1) = lesnoe(2)
 280       liarin(1) = areint(2)
 281       lisomm(2) = lesnoe(5)
 282       liarin(2) = areint(5)
 283       lisomm(3) = lesnoe(6)
 284       liarin(3) = areint(6)
 285       lisomm(4) = lesnoe(1)
 286       liarin(4) = areint(1)
 287       liarin(5) = areint(9)
 288       liarin(6) = areint(13)
 289       are1 = listar(1)
 290       are2 = listar(6)
 291       are3 = listar(9)
 292       are4 = listar(5)
 293       fdnume = listfa(2)
 294 c
 295 #ifdef _DEBUG_HOMARD_
 296       write (ulsort,texte(langue,3)) 'CMCPY2 - face 2', nompro
 297 #endif
 298       call cmcpy2 ( lehexa, indpyr, indptp,
 299      >              fdnume,
 300      >              lisomm, liarin,
 301      >              are1, are2, are3, are4,
 302      >              filare, arequa, filqua,
 303      >              arepyr, fampyr,
 304      >              hetpyr, filpyr, perpyr,
 305      >              famhex, cfahex,
 306      >              ulsort, langue, codret )
 307 c
 308 c 4.3. ==> Sur la face 3
 309 c
 310       liarin(1) = areint(4)
 311       liarin(2) = areint(1)
 312       liarin(3) = areint(6)
 313       liarin(4) = areint(7)
 314       liarin(5) = areint(10)
 315       liarin(6) = areint(11)
 316       liarin(7) = areint(16)
 317       fdcode = listcf(3)
 318       fdnume = listfa(3)
 319 c
 320 #ifdef _DEBUG_HOMARD_
 321       write (ulsort,texte(langue,3)) 'CMCPY3 - face 3', nompro
 322 #endif
 323       call cmcpy3 ( lehexa, indpyr, indptp,
 324      >              fdnume, fdcode,
 325      >              liarin,
 326      >              arequa, filqua,
 327      >              arepyr, fampyr,
 328      >              hetpyr, filpyr, perpyr,
 329      >              famhex, cfahex,
 330      >              ulsort, langue, codret )
 331 c
 332 c 4.4. ==> Sur la face 4
 333 c
 334       liarin(1) = areint(8)
 335       liarin(2) = areint(5)
 336       liarin(3) = areint(2)
 337       liarin(4) = areint(3)
 338       liarin(5) = areint(14)
 339       liarin(6) = areint(12)
 340       liarin(7) = areint(17)
 341       fdcode = listcf(4)
 342       fdnume = listfa(4)
 343 c
 344 #ifdef _DEBUG_HOMARD_
 345       write (ulsort,texte(langue,3)) 'CMCPY3 - face 4', nompro
 346 #endif
 347       call cmcpy3 ( lehexa, indpyr, indptp,
 348      >              fdnume, fdcode,
 349      >              liarin,
 350      >              arequa, filqua,
 351      >              arepyr, fampyr,
 352      >              hetpyr, filpyr, perpyr,
 353      >              famhex, cfahex,
 354      >              ulsort, langue, codret )
 355 c
 356 c 4.5. ==> Sur la face 5
 357 c
 358       lisomm(1) = lesnoe(7)
 359       liarin(1) = areint(7)
 360       lisomm(2) = lesnoe(8)
 361       liarin(2) = areint(8)
 362       lisomm(3) = lesnoe(3)
 363       liarin(3) = areint(3)
 364       lisomm(4) = lesnoe(4)
 365       liarin(4) = areint(4)
 366       liarin(5) = areint(11)
 367       liarin(6) = areint(12)
 368       are1 = listar(7)
 369       are2 = listar(12)
 370       are3 = listar(8)
 371       are4 = listar(4)
 372       fdnume = listfa(5)
 373 c
 374 #ifdef _DEBUG_HOMARD_
 375       write (ulsort,texte(langue,3)) 'CMCPY2 - face 5', nompro
 376 #endif
 377       call cmcpy2 ( lehexa, indpyr, indptp,
 378      >              fdnume,
 379      >              lisomm, liarin,
 380      >              are1, are2, are3, are4,
 381      >              filare, arequa, filqua,
 382      >              arepyr, fampyr,
 383      >              hetpyr, filpyr, perpyr,
 384      >              famhex, cfahex,
 385      >              ulsort, langue, codret )
 386 c
 387 c 4.6. ==> Sur la face 6
 388 c
 389       liarin(1) = areint(5)
 390       liarin(2) = areint(8)
 391       liarin(3) = areint(7)
 392       liarin(4) = areint(6)
 393       liarin(5) = areint(14)
 394       liarin(6) = areint(13)
 395       liarin(7) = areint(18)
 396       fdcode = listcf(6)
 397       fdnume = listfa(6)
 398 c
 399 #ifdef _DEBUG_HOMARD_
 400       write (ulsort,texte(langue,3)) 'CMCPY3 - face 6', nompro
 401 #endif
 402       call cmcpy3 ( lehexa, indpyr, indptp,
 403      >              fdnume, fdcode,
 404      >              liarin,
 405      >              arequa, filqua,
 406      >              arepyr, fampyr,
 407      >              hetpyr, filpyr, perpyr,
 408      >              famhex, cfahex,
 409      >              ulsort, langue, codret )
 410 c
 411 c====
 412 c 5. la fin
 413 c====
 414 c
 415       if ( codret.ne.0 ) then
 416 c
 417 #include "envex2.h"
 418 c
 419       write (ulsort,texte(langue,1)) 'Sortie', nompro
 420       write (ulsort,texte(langue,2)) codret
 421 c
 422       endif
 423 c
 424 #ifdef _DEBUG_HOMARD_
 425       write (ulsort,texte(langue,1)) 'Sortie', nompro
 426       call dmflsh (iaux)
 427 #endif
 428 c
 429       end