src/tool/Creation_Maillage/cmh603.F

   1       subroutine cmh603 ( lehexa,
   2      >                    indnoe, indare, indtet, indpyr, indhex,
   3      >                    indptp,
   4      >                    listso, listar, listfa, listcf,
   5      >                    coonoe, hetnoe, arenoe,
   6      >                    famnoe,
   7      >                    hetare, somare,
   8      >                    filare, merare, famare,
   9      >                    aretri,
  10      >                    arequa, filqua,
  11      >                    hettet, aretet,
  12      >                    filtet, pertet, famtet,
  13      >                    hetpyr, arepyr,
  14      >                    filpyr, perpyr, fampyr,
  15      >                    hethex, arehex,
  16      >                    filhex, perhex, famhex,
  17      >                    cfahex,
  18      >                    ulsort, langue, codret )
  19 c ______________________________________________________________________
  20 c
  21 c                             H O M A R D
  22 c
  23 c Outil de Maillage Adaptatif par Raffinement et Deraffinement d'EDF R&D
  24 c
  25 c Version originale enregistree le 18 juin 1996 sous le numero 96036
  26 c aupres des huissiers de justice Simart et Lavoir a Clamart
  27 c Version 11.2 enregistree le 13 fevrier 2015 sous le numero 2015/014
  28 c aupres des huissiers de justice
  29 c Lavoir, Silinski & Cherqui-Abrahmi a Clamart
  30 c
  31 c    HOMARD est une marque deposee d'Electricite de France
  32 c
  33 c Copyright EDF 1996
  34 c Copyright EDF 1998
  35 c Copyright EDF 2002
  36 c Copyright EDF 2020
  37 c ______________________________________________________________________
  38 c
  39 c    Creation du Maillage - decoupage de conformite des Hexaedres
  40 c    -           -                                      -
  41 c ______________________________________________________________________
  42 c .        .     .        .                                            .
  43 c .  nom   . e/s . taille .           description                      .
  44 c .____________________________________________________________________.
  45 c . lehexa . e   .   1    . hexaedre a decouper                        .
  46 c . indnoe . es  .   1    . indice du dernier noeud cree               .
  47 c . indare . es  .   1    . indice de la derniere arete creee          .
  48 c . indtet . es  .   1    . indice du dernier tetraedre cree           .
  49 c . indpyr . es  .   1    . indice de la derniere pyramide creee       .
  50 c . indhex . es  .   1    . indice du dernier hexaedre cree            .
  51 c . indptp . es  .   1    . indice du dernier pere enregistre          .
  52 c . listso . e   .   8    . numeros globaux des sommets                .
  53 c . listar . e   .  12    . numeros globaux des aretes                 .
  54 c . listfa . e   .   6    . numeros globaux des faces                  .
  55 c . listcf . e   .   6    . codes des faces                            .
  56 c . coonoe . es  .nouvno*3. coordonnees des noeuds                     .
  57 c . hetnoe . es  . nouvno . historique de l'etat des noeuds            .
  58 c . arenoe . es  . nouvno . arete liee a un nouveau noeud              .
  59 c . famnoe . es  . nouvno . famille des noeuds                         .
  60 c . hetare . es  . nouvar . historique de l'etat des aretes            .
  61 c . somare . es  .2*nouvar. numeros des extremites d'arete             .
  62 c . filare . es  . nouvar . premiere fille des aretes                  .
  63 c . merare . es  . nouvar . mere des aretes                            .
  64 c . famare . es  . nouvar . famille des aretes                         .
  65 c . aretri . e   .nouvtr*3. numeros des 3 aretes des triangles         .
  66 c . arequa . e   .nouvqu*4. numeros des 4 aretes des quadrangles       .
  67 c . filqua . e   . nouvqu . premier fils des quadrangles               .
  68 c . hettet . es  . nouvte . historique de l'etat des tetraedres        .
  69 c . aretet . es  .nouvta*6. numeros des 6 aretes des tetraedres        .
  70 c . filtet . es  . nouvte . premier fils des tetraedres                .
  71 c . pertet . es  . nouvte . pere des tetraedres                        .
  72 c .        .     .        . si pertet(i) > 0 : numero du tetraedre     .
  73 c .        .     .        . si pertet(i) < 0 : -numero dans pthepe     .
  74 c . famtet . es  . nouvte . famille des tetraedres                     .
  75 c . hetpyr . es  . nouvpy . historique de l'etat des pyramides         .
  76 c . arepyr . es  .nouvya*8. numeros des 8 aretes des pyramides         .
  77 c . filpyr . es  . nouvpy . premier fils des pyramides                 .
  78 c . perpyr . es  . nouvpy . pere des pyramides                         .
  79 c .        .     .        . si perpyr(i) > 0 : numero de la pyramide   .
  80 c .        .     .        . si perpyr(i) < 0 : -numero dans pphepe     .
  81 c . fampyr . es  . nouvpy . famille des pyramides                      .
  82 c . hethex . es  . nouvhe . historique de l'etat des hexaedres         .
  83 c . arehex . es  .nouvha12. numeros des 12 aretes des hexaedres        .
  84 c . filhex . es  . nouvhe . premier fils des hexaedres                 .
  85 c . perhex . es  . nouvhe . pere des hexaedres                         .
  86 c . famhex . es  . nouvhe . famille des hexaedres                      .
  87 c . cfahex . e   . nctfhe. codes des familles des hexaedres            .
  88 c .        .     . nbfhex .   1 : famille MED                          .
  89 c .        .     .        .   2 : type d'hexaedres                     .
  90 c .        .     .        .   3 : famille des tetraedres de conformite .
  91 c .        .     .        .   4 : famille des pyramides de conformite  .
  92 c . ulsort . e   .   1    . unite logique de la sortie generale        .
  93 c . langue . e   .    1   . langue des messages                        .
  94 c .        .     .        . 1 : francais, 2 : anglais                  .
  95 c . codret . es  .    1   . code de retour des modules                 .
  96 c ______________________________________________________________________
  97 c
  98 c====
  99 c 0. declarations et dimensionnement
 100 c====
 101 c
 102 c 0.1. ==> generalites
 103 c
 104       implicit none
 105       save
 106 c
 107       integer nbarin
 108       character*6 nompro
 109       parameter ( nompro ='CMH603' )
 110       parameter ( nbarin = 17 )
 111 c
 112       integer nbsomm
 113       parameter ( nbsomm = 8 )
 114 c
 115 #include "nblang.h"
 116 #include "cofpfh.h"
 117 c
 118 c 0.2. ==> communs
 119 c
 120 #include "envex1.h"
 121 c
 122 #include "envca1.h"
 123 #include "dicfen.h"
 124 #include "nbfami.h"
 125 #include "nouvnb.h"
 126 c
 127 c 0.3. ==> arguments
 128 c
 129       integer lehexa
 130       integer indnoe, indare, indtet, indpyr, indhex
 131       integer indptp
 132       integer listso(8), listar(12), listfa(6), listcf(6)
 133       integer hetnoe(nouvno), arenoe(nouvno)
 134       integer famnoe(nouvno)
 135       integer hetare(nouvar), somare(2,nouvar)
 136       integer filare(nouvar), merare(nouvar), famare(nouvar)
 137       integer aretri(nouvtr,3)
 138       integer arequa(nouvqu,4)
 139       integer filqua(nouvqu)
 140       integer hettet(nouvte), aretet(nouvta,6)
 141       integer filtet(nouvte), pertet(nouvte), famtet(nouvte)
 142       integer hetpyr(nouvpy), arepyr(nouvya,8)
 143       integer filpyr(nouvpy), perpyr(nouvpy), fampyr(nouvpy)
 144       integer arehex(nouvha,12)
 145       integer hethex(nouvhe)
 146       integer filhex(nouvhe), perhex(nouvhe)
 147       integer cfahex(nctfhe,nbfhex), famhex(nouvhe)
 148 c
 149       double precision coonoe(nouvno,sdim)
 150 c
 151       integer ulsort, langue, codret
 152 c
 153 c 0.4. ==> variables locales
 154 c
 155       integer iaux, jaux
 156 c
 157       integer lesnoe(nbarin), areint(nbarin)
 158       integer lisomm(10), liarin(10)
 159       integer fdnume, fdcode
 160       integer are1, are2, are3, are4
 161       integer are5, are6, are7, are8
 162
 163 c
 164       integer nbmess
 165       parameter ( nbmess = 10 )
 166       character*80 texte(nblang,nbmess)
 167 c
 168 c 0.5. ==> initialisations
 169 c ______________________________________________________________________
 170 c
 171 c====
 172 c 1. messages
 173 c====
 174 c
 175 #include "impr01.h"
 176 #include "impr03.h"
 177 c
 178 #ifdef _DEBUG_HOMARD_
 179       write (ulsort,texte(langue,1)) 'Entree', nompro
 180       call dmflsh (iaux)
 181 #endif
 182 c
 183 #ifdef _DEBUG_HOMARD_
 184       write (ulsort,90002) 'indnoe', indnoe
 185       write (ulsort,90002) 'indtet', indtet
 186       write (ulsort,90002) 'indpyr', indpyr
 187       write (ulsort,90002) 'indhex', indhex
 188 #endif
 189 #ifdef _DEBUG_HOMARD_
 190       write (ulsort,90002) 'listar  1-8', (listar(iaux),iaux=1,8)
 191       write (ulsort,90002) 'listar 9-12', (listar(iaux),iaux=9,12)
 192       write (ulsort,90002) 'listso', listso
 193       write (ulsort,90002) 'listfa', listfa
 194       write (ulsort,90002) 'listcf', listcf
 195 #endif
 196 c
 197       codret = 0
 198 c
 199 c====
 200 c 2. Recuperation
 201 c    . des sommets de l'hexaedre
 202 c    . des noeuds milieux des 6 aretes coupees
 203 c    . des noeuds milieux des 2 faces coupees en 3 quadrangles
 204 c    . du noeud milieu de la face coupee en 4 quadrangles
 205 c====
 206 c
 207       do 21 , iaux = 1 , 8
 208         lesnoe(iaux) = listso(iaux)
 209    21 continue
 210 c
 211       lesnoe(9) = somare(2,filare(listar(1)))
 212       lesnoe(10) = somare(2,filare(listar(2)))
 213       lesnoe(11) = somare(2,filare(listar(3)))
 214       lesnoe(12) = somare(2,filare(listar(4)))
 215       lesnoe(13) = somare(2,filare(listar(5)))
 216       lesnoe(14) = somare(2,filare(listar(11)))
 217 c
 218       iaux = filqua(listfa(1))
 219       lesnoe(15) = somare(2,arequa(iaux,2))
 220       iaux = filqua(listfa(2))
 221       lesnoe(16) = somare(2,arequa(iaux,4))
 222       iaux = filqua(listfa(3))
 223       lesnoe(17) = somare(2,arequa(iaux,4))
 224 #ifdef _DEBUG_HOMARD_
 225       do 2000 , iaux = 1 , nbarin
 226         write(ulsort,90015) 'lesnoe(',iaux,') = ', lesnoe(iaux)
 227  2000 continue
 228 #endif
 229 c
 230 c====
 231 c 3. Creation du noeud interne et des dix-sept aretes internes
 232 c====
 233 c
 234 #ifdef _DEBUG_HOMARD_
 235       write (ulsort,texte(langue,3)) 'CMCHPB', nompro
 236 #endif
 237       call cmchpb ( indnoe, indare, nbarin,
 238      >              nbsomm, lesnoe, areint,
 239      >              coonoe, hetnoe, arenoe,
 240      >              famnoe,
 241      >              hetare, somare,
 242      >              filare, merare, famare,
 243      >              ulsort, langue, codret )
 244 c
 245 c====
 246 c 4. Creation des douze pyramides et des six tetraedres
 247 c====
 248 c
 249       iaux = -indptp
 250       jaux = cfahex(cofpfh,famhex(lehexa))
 251 c
 252 c 4.1. ==> Sur la face 1
 253 c
 254       lisomm(1) = lesnoe(2)
 255       liarin(1) = areint(2)
 256       lisomm(2) = lesnoe(1)
 257       liarin(2) = areint(1)
 258       lisomm(3) = lesnoe(4)
 259       liarin(3) = areint(4)
 260       lisomm(4) = lesnoe(3)
 261       liarin(4) = areint(3)
 262       liarin(5) = areint(9)
 263       liarin(6) = areint(10)
 264       liarin(7) = areint(12)
 265       liarin(8) = areint(11)
 266       liarin(9) = areint(15)
 267       lisomm(5) = lesnoe(9)
 268       lisomm(6) = lesnoe(10)
 269       lisomm(7) = lesnoe(12)
 270       lisomm(8) = lesnoe(11)
 271       are1 = listar(1)
 272       are2 = listar(2)
 273       are3 = listar(4)
 274       are4 = listar(3)
 275       fdnume = listfa(1)
 276 c
 277 #ifdef _DEBUG_HOMARD_
 278       write (ulsort,texte(langue,3)) 'CMCPY4 - face 1', nompro
 279 #endif
 280       call cmcpy4 ( lehexa, indpyr, indptp,
 281      >              fdnume,
 282      >              lisomm, liarin, are1, are2, are3, are4,
 283      >              somare, filare, arequa, filqua,
 284      >              arepyr, fampyr,
 285      >              hetpyr, filpyr, perpyr,
 286      >              famhex, cfahex,
 287      >              ulsort, langue, codret )
 288 c
 289 c 4.2. ==> Sur la face 2
 290 c
 291       liarin(1) = areint(1)
 292       liarin(2) = areint(2)
 293       liarin(3) = areint(5)
 294       liarin(4) = areint(6)
 295       liarin(5) = areint(9)
 296       liarin(6) = areint(13)
 297       liarin(7) = areint(16)
 298       fdcode = listcf(2)
 299       fdnume = listfa(2)
 300 c
 301 #ifdef _DEBUG_HOMARD_
 302       write (ulsort,texte(langue,3)) 'CMCPY3 - face 2', nompro
 303 #endif
 304       call cmcpy3 ( lehexa, indpyr, indptp,
 305      >              fdnume, fdcode,
 306      >              liarin,
 307      >              arequa, filqua,
 308      >              arepyr, fampyr,
 309      >              hetpyr, filpyr, perpyr,
 310      >              famhex, cfahex,
 311      >              ulsort, langue, codret )
 312 c
 313 c 4.3. ==> Sur la face 3
 314 c
 315       liarin(1) = areint(1)
 316       liarin(2) = areint(6)
 317       liarin(3) = areint(7)
 318       liarin(4) = areint(4)
 319       liarin(5) = areint(13)
 320       liarin(6) = areint(10)
 321       liarin(7) = areint(17)
 322       fdcode = listcf(3)
 323       fdnume = listfa(3)
 324 c
 325 #ifdef _DEBUG_HOMARD_
 326       write (ulsort,texte(langue,3)) 'CMCPY3 - face 3', nompro
 327 #endif
 328       call cmcpy3 ( lehexa, indpyr, indptp,
 329      >              fdnume, fdcode,
 330      >              liarin,
 331      >              arequa, filqua,
 332      >              arepyr, fampyr,
 333      >              hetpyr, filpyr, perpyr,
 334      >              famhex, cfahex,
 335      >              ulsort, langue, codret )
 336 c
 337 c 4.4. ==> Sur la face 4
 338 c
 339       lisomm(1) = lesnoe(3)
 340       liarin(1) = areint(3)
 341       lisomm(2) = lesnoe(8)
 342       liarin(2) = areint(8)
 343       lisomm(3) = lesnoe(5)
 344       liarin(3) = areint(5)
 345       lisomm(4) = lesnoe(2)
 346       liarin(4) = areint(2)
 347       liarin(5) = areint(11)
 348       liarin(6) = areint(14)
 349       are1 = listar(3)
 350       are2 = listar(8)
 351       are3 = listar(11)
 352       are4 = listar(6)
 353       fdnume = listfa(4)
 354 c
 355 #ifdef _DEBUG_HOMARD_
 356       write (ulsort,texte(langue,3)) 'CMCPY2 - face 4', nompro
 357 #endif
 358       call cmcpy2 ( lehexa, indpyr, indptp,
 359      >              fdnume,
 360      >              lisomm, liarin,
 361      >              are1, are2, are3, are4,
 362      >              filare, arequa, filqua,
 363      >              arepyr, fampyr,
 364      >              hetpyr, filpyr, perpyr,
 365      >              famhex, cfahex,
 366      >              ulsort, langue, codret )
 367 c
 368 c 4.5. ==> Sur la face 5
 369 c
 370       liarin(1) = areint(4)
 371       liarin(2) = areint(7)
 372       liarin(3) = areint(8)
 373       liarin(4) = areint(3)
 374       liarin(5) = areint(12)
 375       fdnume = listfa(5)
 376       fdcode = listcf(5)
 377 c
 378 #ifdef _DEBUG_HOMARD_
 379       write (ulsort,texte(langue,3)) 'CMCTE3 - face 5', nompro
 380 #endif
 381       call cmcte3 ( lehexa, indtet, indptp,
 382      >              fdnume, fdcode, liarin,
 383      >              aretri, filqua,
 384      >              aretet, famtet,
 385      >              hettet, filtet, pertet,
 386      >              famhex, cfahex,
 387      >              ulsort, langue, codret )
 388 c
 389 c 4.6. ==> Sur la face 6
 390 c
 391       liarin(1) = areint(8)
 392       liarin(2) = areint(7)
 393       liarin(3) = areint(6)
 394       liarin(4) = areint(5)
 395       liarin(5) = areint(14)
 396       fdnume = listfa(6)
 397       fdcode = listcf(6)
 398 c
 399 #ifdef _DEBUG_HOMARD_
 400       write (ulsort,texte(langue,3)) 'CMCTE3 - face 6', nompro
 401 #endif
 402       call cmcte3 ( lehexa, indtet, indptp,
 403      >              fdnume, fdcode, liarin,
 404      >              aretri, filqua,
 405      >              aretet, famtet,
 406      >              hettet, filtet, pertet,
 407      >              famhex, cfahex,
 408      >              ulsort, langue, codret )
 409 c
 410 c====
 411 c 5. la fin
 412 c====
 413 c
 414       if ( codret.ne.0 ) then
 415 c
 416 #include "envex2.h"
 417 c
 418       write (ulsort,texte(langue,1)) 'Sortie', nompro
 419       write (ulsort,texte(langue,2)) codret
 420 c
 421       endif
 422 c
 423 #ifdef _DEBUG_HOMARD_
 424       write (ulsort,texte(langue,1)) 'Sortie', nompro
 425       call dmflsh (iaux)
 426 #endif
 427 c
 428       end