src/tool/Creation_Maillage/cmh308.F

   1       subroutine cmh308 ( lehexa,
   2      >                    indnoe, indare, indtet, indpyr, indhex,
   3      >                    indptp,
   4      >                    listso, listar, listfa, listcf,
   5      >                    coonoe, hetnoe, arenoe,
   6      >                    famnoe,
   7      >                    hetare, somare,
   8      >                    filare, merare, famare,
   9      >                    aretri,
  10      >                    arequa, filqua,
  11      >                    hettet, aretet,
  12      >                    filtet, pertet, famtet,
  13      >                    hetpyr, arepyr,
  14      >                    filpyr, perpyr, fampyr,
  15      >                    hethex, arehex,
  16      >                    filhex, perhex, famhex,
  17      >                    cfahex,
  18      >                    ulsort, langue, codret )
  19 c ______________________________________________________________________
  20 c
  21 c                             H O M A R D
  22 c
  23 c Outil de Maillage Adaptatif par Raffinement et Deraffinement d'EDF R&D
  24 c
  25 c Version originale enregistree le 18 juin 1996 sous le numero 96036
  26 c aupres des huissiers de justice Simart et Lavoir a Clamart
  27 c Version 11.2 enregistree le 13 fevrier 2015 sous le numero 2015/014
  28 c aupres des huissiers de justice
  29 c Lavoir, Silinski & Cherqui-Abrahmi a Clamart
  30 c
  31 c    HOMARD est une marque deposee d'Electricite de France
  32 c
  33 c Copyright EDF 1996
  34 c Copyright EDF 1998
  35 c Copyright EDF 2002
  36 c Copyright EDF 2020
  37 c ______________________________________________________________________
  38 c
  39 c    Creation du Maillage - decoupage de conformite des Hexaedres
  40 c    -           -                                      -
  41 c ______________________________________________________________________
  42 c .        .     .        .                                            .
  43 c .  nom   . e/s . taille .           description                      .
  44 c .____________________________________________________________________.
  45 c . lehexa . e   .   1    . hexaedre a decouper                        .
  46 c . indnoe . es  .   1    . indice du dernier noeud cree               .
  47 c . indare . es  .   1    . indice de la derniere arete creee          .
  48 c . indtet . es  .   1    . indice du dernier tetraedre cree           .
  49 c . indpyr . es  .   1    . indice de la derniere pyramide creee       .
  50 c . indhex . es  .   1    . indice du dernier hexaedre cree            .
  51 c . indptp . es  .   1    . indice du dernier pere enregistre          .
  52 c . listso . e   .   8    . numeros globaux des sommets                .
  53 c . listar . e   .  12    . numeros globaux des aretes                 .
  54 c . listfa . e   .   6    . numeros globaux des faces                  .
  55 c . listcf . e   .   6    . codes des faces                            .
  56 c . coonoe . es  .nouvno*3. coordonnees des noeuds                     .
  57 c . hetnoe . es  . nouvno . historique de l'etat des noeuds            .
  58 c . arenoe . es  . nouvno . arete liee a un nouveau noeud              .
  59 c . famnoe . es  . nouvno . famille des noeuds                         .
  60 c . hetare . es  . nouvar . historique de l'etat des aretes            .
  61 c . somare . es  .2*nouvar. numeros des extremites d'arete             .
  62 c . filare . es  . nouvar . premiere fille des aretes                  .
  63 c . merare . es  . nouvar . mere des aretes                            .
  64 c . famare . es  . nouvar . famille des aretes                         .
  65 c . aretri . e   .nouvtr*3. numeros des 3 aretes des triangles         .
  66 c . arequa . e   .nouvqu*4. numeros des 4 aretes des quadrangles       .
  67 c . filqua . e   . nouvqu . premier fils des quadrangles               .
  68 c . hettet . es  . nouvte . historique de l'etat des tetraedres        .
  69 c . aretet . es  .nouvta*6. numeros des 6 aretes des tetraedres        .
  70 c . filtet . es  . nouvte . premier fils des tetraedres                .
  71 c . pertet . es  . nouvte . pere des tetraedres                        .
  72 c .        .     .        . si pertet(i) > 0 : numero du tetraedre     .
  73 c .        .     .        . si pertet(i) < 0 : -numero dans pthepe     .
  74 c . famtet . es  . nouvte . famille des tetraedres                     .
  75 c . hetpyr . es  . nouvpy . historique de l'etat des pyramides         .
  76 c . arepyr . es  .nouvya*8. numeros des 8 aretes des pyramides         .
  77 c . filpyr . es  . nouvpy . premier fils des pyramides                 .
  78 c . perpyr . es  . nouvpy . pere des pyramides                         .
  79 c .        .     .        . si perpyr(i) > 0 : numero de la pyramide   .
  80 c .        .     .        . si perpyr(i) < 0 : -numero dans pphepe     .
  81 c . fampyr . es  . nouvpy . famille des pyramides                      .
  82 c . hethex . es  . nouvhe . historique de l'etat des hexaedres         .
  83 c . arehex . es  .nouvha12. numeros des 12 aretes des hexaedres        .
  84 c . filhex . es  . nouvhe . premier fils des hexaedres                 .
  85 c . perhex . es  . nouvhe . pere des hexaedres                         .
  86 c . famhex . es  . nouvhe . famille des hexaedres                      .
  87 c . cfahex . e   . nctfhe. codes des familles des hexaedres            .
  88 c .        .     . nbfhex .   1 : famille MED                          .
  89 c .        .     .        .   2 : type d'hexaedres                     .
  90 c .        .     .        .   3 : famille des tetraedres de conformite .
  91 c .        .     .        .   4 : famille des pyramides de conformite  .
  92 c . ulsort . e   .   1    . unite logique de la sortie generale        .
  93 c . langue . e   .    1   . langue des messages                        .
  94 c .        .     .        . 1 : francais, 2 : anglais                  .
  95 c . codret . es  .    1   . code de retour des modules                 .
  96 c ______________________________________________________________________
  97 c
  98 c====
  99 c 0. declarations et dimensionnement
 100 c====
 101 c
 102 c 0.1. ==> generalites
 103 c
 104       implicit none
 105       save
 106 c
 107       integer nbarin
 108       character*6 nompro
 109       parameter ( nompro ='CMH308' )
 110       parameter ( nbarin = 13 )
 111 c
 112       integer nbsomm
 113       parameter ( nbsomm = 8 )
 114 c
 115 #include "nblang.h"
 116 #include "cofpfh.h"
 117 c
 118 c 0.2. ==> communs
 119 c
 120 #include "envex1.h"
 121 c
 122 #include "envca1.h"
 123 #include "dicfen.h"
 124 #include "nbfami.h"
 125 #include "nouvnb.h"
 126 c
 127 c 0.3. ==> arguments
 128 c
 129       integer lehexa
 130       integer indnoe, indare, indtet, indpyr, indhex
 131       integer indptp
 132       integer listso(8), listar(12), listfa(6), listcf(6)
 133       integer hetnoe(nouvno), arenoe(nouvno)
 134       integer famnoe(nouvno)
 135       integer hetare(nouvar), somare(2,nouvar)
 136       integer filare(nouvar), merare(nouvar), famare(nouvar)
 137       integer aretri(nouvtr,3)
 138       integer arequa(nouvqu,4)
 139       integer filqua(nouvqu)
 140       integer hettet(nouvte), aretet(nouvta,6)
 141       integer filtet(nouvte), pertet(nouvte), famtet(nouvte)
 142       integer hetpyr(nouvpy), arepyr(nouvya,8)
 143       integer filpyr(nouvpy), perpyr(nouvpy), fampyr(nouvpy)
 144       integer arehex(nouvha,12)
 145       integer hethex(nouvhe)
 146       integer filhex(nouvhe), perhex(nouvhe)
 147       integer cfahex(nctfhe,nbfhex), famhex(nouvhe)
 148 c
 149       double precision coonoe(nouvno,sdim)
 150 c
 151       integer ulsort, langue, codret
 152 c
 153 c 0.4. ==> variables locales
 154 c
 155       integer iaux, jaux
 156 c
 157       integer lesnoe(nbarin), areint(nbarin)
 158       integer lisomm(10), liarin(10)
 159       integer fdnume, fdcode
 160       integer are1, are2, are3, are4
 161       integer are5, are6, are7, are8
 162
 163 c
 164       integer nbmess
 165       parameter ( nbmess = 10 )
 166       character*80 texte(nblang,nbmess)
 167 c
 168 c 0.5. ==> initialisations
 169 c ______________________________________________________________________
 170 c
 171 c====
 172 c 1. messages
 173 c====
 174 c
 175 #include "impr01.h"
 176 #include "impr03.h"
 177 c
 178 #ifdef _DEBUG_HOMARD_
 179       write (ulsort,texte(langue,1)) 'Entree', nompro
 180       call dmflsh (iaux)
 181 #endif
 182 c
 183 #ifdef _DEBUG_HOMARD_
 184       write (ulsort,90002) 'indnoe', indnoe
 185       write (ulsort,90002) 'indtet', indtet
 186       write (ulsort,90002) 'indpyr', indpyr
 187       write (ulsort,90002) 'indhex', indhex
 188 #endif
 189 #ifdef _DEBUG_HOMARD_
 190       write (ulsort,90002) 'listar  1-8', (listar(iaux),iaux=1,8)
 191       write (ulsort,90002) 'listar 9-12', (listar(iaux),iaux=9,12)
 192       write (ulsort,90002) 'listso', listso
 193       write (ulsort,90002) 'listfa', listfa
 194       write (ulsort,90002) 'listcf', listcf
 195 #endif
 196 c
 197       codret = 0
 198 c
 199 c====
 200 c 2. Recuperation
 201 c    . des sommets de l'hexaedre
 202 c    . des noeuds milieux des 3 aretes coupees
 203 c    . des noeuds milieux des 2 faces coupees en 3 quadrangles
 204 c====
 205 c
 206       do 21 , iaux = 1 , 8
 207         lesnoe(iaux) = listso(iaux)
 208    21 continue
 209 c
 210       lesnoe(9) = somare(2,filare(listar(1)))
 211       lesnoe(10) = somare(2,filare(listar(2)))
 212       lesnoe(11) = somare(2,filare(listar(7)))
 213 c
 214       iaux = filqua(listfa(1))
 215       lesnoe(12) = somare(2,arequa(iaux,4))
 216       iaux = filqua(listfa(3))
 217       lesnoe(13) = somare(2,arequa(iaux,4))
 218 #ifdef _DEBUG_HOMARD_
 219       do 2000 , iaux = 1 , nbarin
 220         write(ulsort,90015) 'lesnoe(',iaux,') = ', lesnoe(iaux)
 221  2000 continue
 222 #endif
 223 c
 224 c====
 225 c 3. Creation du noeud interne et des treize aretes internes
 226 c====
 227 c
 228 #ifdef _DEBUG_HOMARD_
 229       write (ulsort,texte(langue,3)) 'CMCHPB', nompro
 230 #endif
 231       call cmchpb ( indnoe, indare, nbarin,
 232      >              nbsomm, lesnoe, areint,
 233      >              coonoe, hetnoe, arenoe,
 234      >              famnoe,
 235      >              hetare, somare,
 236      >              filare, merare, famare,
 237      >              ulsort, langue, codret )
 238 c
 239 c====
 240 c 4. Creation des huit pyramides et des six tetraedres
 241 c====
 242 c
 243       iaux = -indptp
 244       jaux = cfahex(cofpfh,famhex(lehexa))
 245 c
 246 c 4.1. ==> Sur la face 1
 247 c
 248       liarin(1) = areint(1)
 249       liarin(2) = areint(4)
 250       liarin(3) = areint(3)
 251       liarin(4) = areint(2)
 252       liarin(5) = areint(10)
 253       liarin(6) = areint(9)
 254       liarin(7) = areint(12)
 255       fdcode = listcf(1)
 256       fdnume = listfa(1)
 257 c
 258 #ifdef _DEBUG_HOMARD_
 259       write (ulsort,texte(langue,3)) 'CMCPY3 - face 1', nompro
 260 #endif
 261       call cmcpy3 ( lehexa, indpyr, indptp,
 262      >              fdnume, fdcode,
 263      >              liarin,
 264      >              arequa, filqua,
 265      >              arepyr, fampyr,
 266      >              hetpyr, filpyr, perpyr,
 267      >              famhex, cfahex,
 268      >              ulsort, langue, codret )
 269 c
 270 c 4.2. ==> Sur la face 2
 271 c
 272       liarin(1) = areint(2)
 273       liarin(2) = areint(5)
 274       liarin(3) = areint(6)
 275       liarin(4) = areint(1)
 276       liarin(5) = areint(9)
 277       fdnume = listfa(2)
 278       fdcode = listcf(2)
 279 c
 280 #ifdef _DEBUG_HOMARD_
 281       write (ulsort,texte(langue,3)) 'CMCTE3 - face 2', nompro
 282 #endif
 283       call cmcte3 ( lehexa, indtet, indptp,
 284      >              fdnume, fdcode, liarin,
 285      >              aretri, filqua,
 286      >              aretet, famtet,
 287      >              hettet, filtet, pertet,
 288      >              famhex, cfahex,
 289      >              ulsort, langue, codret )
 290 c
 291 c 4.3. ==> Sur la face 3
 292 c
 293       liarin(1) = areint(4)
 294       liarin(2) = areint(1)
 295       liarin(3) = areint(6)
 296       liarin(4) = areint(7)
 297       liarin(5) = areint(10)
 298       liarin(6) = areint(11)
 299       liarin(7) = areint(13)
 300       fdcode = listcf(3)
 301       fdnume = listfa(3)
 302 c
 303 #ifdef _DEBUG_HOMARD_
 304       write (ulsort,texte(langue,3)) 'CMCPY3 - face 3', nompro
 305 #endif
 306       call cmcpy3 ( lehexa, indpyr, indptp,
 307      >              fdnume, fdcode,
 308      >              liarin,
 309      >              arequa, filqua,
 310      >              arepyr, fampyr,
 311      >              hetpyr, filpyr, perpyr,
 312      >              famhex, cfahex,
 313      >              ulsort, langue, codret )
 314 c
 315 c 4.4. ==> Sur la face 4
 316 c
 317       are1 = areint(2)
 318       are2 = areint(3)
 319       are3 = areint(8)
 320       are4 = areint(5)
 321       are5 = listar(3)
 322       are6 = listar(8)
 323       are7 = listar(11)
 324       are8 = listar(6)
 325       indpyr = indpyr + 1
 326 #ifdef _DEBUG_HOMARD_
 327       write (ulsort,texte(langue,3)) 'CMCPYA - face 4', nompro
 328 #endif
 329       call cmcpya ( arepyr, fampyr, hetpyr, filpyr, perpyr,
 330      >              are1, are2, are3, are4,
 331      >              are5, are6, are7, are8,
 332      >              iaux,  jaux,   indpyr )
 333 c
 334 c 4.5. ==> Sur la face 5
 335 c
 336       liarin(1) = areint(7)
 337       liarin(2) = areint(8)
 338       liarin(3) = areint(3)
 339       liarin(4) = areint(4)
 340       liarin(5) = areint(11)
 341       fdnume = listfa(5)
 342       fdcode = listcf(5)
 343 c
 344 #ifdef _DEBUG_HOMARD_
 345       write (ulsort,texte(langue,3)) 'CMCTE3 - face 5', nompro
 346 #endif
 347       call cmcte3 ( lehexa, indtet, indptp,
 348      >              fdnume, fdcode, liarin,
 349      >              aretri, filqua,
 350      >              aretet, famtet,
 351      >              hettet, filtet, pertet,
 352      >              famhex, cfahex,
 353      >              ulsort, langue, codret )
 354 c
 355 c 4.6. ==> Sur la face 6
 356 c
 357       are1 = areint(6)
 358       are2 = areint(5)
 359       are3 = areint(8)
 360       are4 = areint(7)
 361       are5 = listar(9)
 362       are6 = listar(11)
 363       are7 = listar(12)
 364       are8 = listar(10)
 365       indpyr = indpyr + 1
 366 #ifdef _DEBUG_HOMARD_
 367       write (ulsort,texte(langue,3)) 'CMCPYA - face 6', nompro
 368 #endif
 369       call cmcpya ( arepyr, fampyr, hetpyr, filpyr, perpyr,
 370      >              are1, are2, are3, are4,
 371      >              are5, are6, are7, are8,
 372      >              iaux,  jaux,   indpyr )
 373 c
 374 c====
 375 c 5. la fin
 376 c====
 377 c
 378       if ( codret.ne.0 ) then
 379 c
 380 #include "envex2.h"
 381 c
 382       write (ulsort,texte(langue,1)) 'Sortie', nompro
 383       write (ulsort,texte(langue,2)) codret
 384 c
 385       endif
 386 c
 387 #ifdef _DEBUG_HOMARD_
 388       write (ulsort,texte(langue,1)) 'Sortie', nompro
 389       call dmflsh (iaux)
 390 #endif
 391 c
 392       end