scripts/parse3.awk

   1 # This awk program contains the type mapping tables - and the treatments
   2 # --
   3 # Copyright (C) CEA, EDF
   4 # Author : Nicolas Crouzet (CEA)
   5 # --
   6 # for code generation
   7 #
   8 BEGIN {
   9 #
  10 # file name generation
  11   idl_file="code_idl"
  12   hxx_file="code_hxx"
  13   cxx_file="code_cxx"
  14   class_i=class_name"_i"
  15   print "\t// generated part" > idl_file
  16   printf "    // generated part\n" > hxx_file
  17   printf "//\n// generated part\n//\n" > cxx_file
  18   print "Functions parsing (for debug)" > "parse_result"
  19 #
  20 #
  21 # type mapping from c++ component to idl
  22 #
  23   idl_arg_type["int"]="in long"
  24   idl_arg_type["bool"]="in boolean"
  25   idl_arg_type["double"]="in double"
  26   idl_arg_type["float"]="in float"
  27   idl_arg_type["long"]="in long"
  28   idl_arg_type["short"]="in short"
  29   idl_arg_type["unsigned"]="in unsigned long"
  30   idl_arg_type["const char*"]="in string"
  31   idl_arg_type["const std::string&"]="in string"
  32   idl_arg_type["int&"]="out long"
  33   idl_arg_type["bool&"]="out boolean"
  34   idl_arg_type["double&"]="out double"
  35   idl_arg_type["float&"]="out float"
  36   idl_arg_type["long&"]="out long"
  37   idl_arg_type["short&"]="out short"
  38   idl_arg_type["unsigned&"]="out unsigned long"
  39   idl_arg_type["std::string&"]="out string"
  40   idl_arg_type["const MEDMEM::MESH&"]="in SALOME_MED::MESH"
  41   idl_arg_type["const MEDMEM::MESH*"]="in SALOME_MED::MESH"
  42   idl_arg_type["const MEDMEM::SUPPORT&"]="in SALOME_MED::SUPPORT"
  43   idl_arg_type["const MEDMEM::SUPPORT*"]="in SALOME_MED::SUPPORT"
  44   idl_arg_type["const MEDMEM::FIELD<double>*"]="in SALOME_MED::FIELDDOUBLE"
  45   idl_arg_type["const MEDMEM::FIELD<double>&"]="in SALOME_MED::FIELDDOUBLE"
  46   idl_arg_type["MEDMEM::FIELD<double>*&"]="out SALOME_MED::FIELDDOUBLE"
  47   idl_arg_type["const std::vector<double>&"]="in SALOME::vectorOfDouble"
  48   idl_arg_type["const std::vector<std::vector<double> >&"]="in SALOME::Matrix"
  49   idl_arg_type["std::vector<double>*&"]="out SALOME::vectorOfDouble"
  50   idl_arg_type["const MEDMEM::FIELD<int>*"]="in SALOME_MED::FIELDINT"
  51   idl_arg_type["const MEDMEM::FIELD<int>&"]="in SALOME_MED::FIELDINT"
  52   idl_arg_type["MEDMEM::FIELD<int>*&"]="out SALOME_MED::FIELDINT"
  53   idl_arg_type["const std::vector<int>&"]="in SALOME::vectorOfLong"
  54   idl_arg_type["std::vector<int>*&"]="out SALOME::vectorOfLong"
  55   idl_arg_type["const ParaMEDMEM::MEDCouplingFieldDouble*"]="in SALOME_MED::MEDCouplingFieldDoubleCorbaInterface"
  56   idl_arg_type["const ParaMEDMEM::MEDCouplingFieldDouble&"]="in SALOME_MED::MEDCouplingFieldDoubleCorbaInterface"
  57   idl_arg_type["ParaMEDMEM::MEDCouplingFieldDouble*&"]="out SALOME_MED::MEDCouplingFieldDoubleCorbaInterface"
  58 #
  59 #
  60 # mapping for returned types
  61 #
  62   idl_rtn_type["void"]="void"
  63   idl_rtn_type["int"]="long"
  64   idl_rtn_type["bool"]="boolean"
  65   idl_rtn_type["double"]="double"
  66   idl_rtn_type["float"]="float"
  67   idl_rtn_type["long"]="long"
  68   idl_rtn_type["short"]="short"
  69   idl_rtn_type["unsigned"]="unsigned long"
  70   idl_rtn_type["const char*"]="string"
  71   idl_rtn_type["char*"]="string"
  72   idl_rtn_type["std::string"]="string"
  73   idl_rtn_type["const MEDMEM::MESH&"]="SALOME_MED::MESH"
  74   idl_rtn_type["MEDMEM::MESH&"]="SALOME_MED::MESH"
  75   idl_rtn_type["MEDMEM::MESH*"]="SALOME_MED::MESH"
  76   idl_rtn_type["const MEDMEM::MESH*"]="SALOME_MED::MESH"
  77   idl_rtn_type["MEDMEM::SUPPORT*"]="SALOME_MED::SUPPORT"
  78   idl_rtn_type["const MEDMEM::FIELD<double>*"]="SALOME_MED::FIELDDOUBLE"
  79   idl_rtn_type["MEDMEM::FIELD<double>*"]="SALOME_MED::FIELDDOUBLE"
  80   idl_rtn_type["MEDMEM::FIELD<double>&"]="SALOME_MED::FIELDDOUBLE"
  81   idl_rtn_type["const MEDMEM::FIELD<double>&"]="SALOME_MED::FIELDDOUBLE"
  82   idl_rtn_type["std::vector<double>*"]="SALOME::vectorOfDouble"
  83   idl_rtn_type["std::vector<std::vector<double> >*"]="SALOME::Matrix"
  84   idl_rtn_type["const MEDMEM::FIELD<int>*"]="SALOME_MED::FIELDINT"
  85   idl_rtn_type["MEDMEM::FIELD<int>*"]="SALOME_MED::FIELDINT"
  86   idl_rtn_type["MEDMEM::FIELD<int>&"]="SALOME_MED::FIELDINT"
  87   idl_rtn_type["const MEDMEM::FIELD<int>&"]="SALOME_MED::FIELDINT"
  88   idl_rtn_type["std::vector<int>*"]="SALOME::vectorOfLong"
  89   idl_rtn_type["std::vector<std::string>"]="StrSeq"
  90   idl_rtn_type["ParaMEDMEM::MEDCouplingUMesh*"]="SALOME_MED::MEDCouplingUMeshCorbaInterface"
  91   idl_rtn_type["ParaMEDMEM::MEDCouplingFieldDouble*"]="SALOME_MED::MEDCouplingFieldDoubleCorbaInterface"
  92 #
  93 #
  94 # Corba mapping table (for argument's types and returned types)
  95 #
  96   idl_impl_hxx["in long"]="CORBA::Long"
  97   idl_impl_hxx["in boolean"]="CORBA::Boolean"
  98   idl_impl_hxx["in double"]="CORBA::Double"
  99   idl_impl_hxx["in float"]="CORBA::Float"
 100   idl_impl_hxx["in short"]="CORBA::Short"
 101   idl_impl_hxx["in unsigned long"]="CORBA::ULong"
 102   idl_impl_hxx["in string"]="const char*"
 103   idl_impl_hxx["out long"]="CORBA::Long_out"
 104   idl_impl_hxx["out boolean"]="CORBA::Boolean_out"
 105   idl_impl_hxx["out double"]="CORBA::Double_out"
 106   idl_impl_hxx["out float"]="CORBA::Float_out"
 107   idl_impl_hxx["out short"]="CORBA::Short_out"
 108   idl_impl_hxx["out unsigned long"]="CORBA::ULong_out"
 109   idl_impl_hxx["out string"]="CORBA::String_out"
 110   idl_impl_hxx["in SALOME_MED::MESH"]="SALOME_MED::MESH_ptr"
 111   idl_impl_hxx["in SALOME_MED::SUPPORT"]="SALOME_MED::SUPPORT_ptr"
 112   idl_impl_hxx["in SALOME_MED::FIELDDOUBLE"]="SALOME_MED::FIELDDOUBLE_ptr"
 113   idl_impl_hxx["out SALOME_MED::FIELDDOUBLE"]="SALOME_MED::FIELDDOUBLE_out"
 114   idl_impl_hxx["in SALOME::vectorOfDouble"]="const SALOME::vectorOfDouble&"
 115   idl_impl_hxx["out SALOME::vectorOfDouble"]="SALOME::vectorOfDouble_out"
 116   idl_impl_hxx["in SALOME::Matrix"]="SALOME::Matrix_ptr"
 117   idl_impl_hxx["in SALOME_MED::FIELDINT"]="SALOME_MED::FIELDINT_ptr"
 118   idl_impl_hxx["out SALOME_MED::FIELDINT"]="SALOME_MED::FIELDINT_out"
 119   idl_impl_hxx["in SALOME::vectorOfLong"]="const SALOME::vectorOfLong&"
 120   idl_impl_hxx["out SALOME::vectorOfLong"]="SALOME::vectorOfLong_out"
 121   idl_impl_hxx["void"]="void"
 122   idl_impl_hxx["long"]="CORBA::Long"
 123   idl_impl_hxx["boolean"]="CORBA::Boolean"
 124   idl_impl_hxx["double"]="CORBA::Double"
 125   idl_impl_hxx["unsigned long"]="CORBA::ULong"
 126   idl_impl_hxx["string"]="char*"
 127   idl_impl_hxx["SALOME_MED::MESH"]="SALOME_MED::MESH_ptr"
 128   idl_impl_hxx["SALOME_MED::SUPPORT"]="SALOME_MED::SUPPORT_ptr"
 129   idl_impl_hxx["SALOME_MED::FIELDDOUBLE"]="SALOME_MED::FIELDDOUBLE_ptr"
 130   idl_impl_hxx["SALOME::vectorOfDouble"]="SALOME::vectorOfDouble*"
 131   idl_impl_hxx["SALOME::Matrix"]="SALOME::Matrix_ptr"
 132   idl_impl_hxx["SALOME_MED::FIELDINT"]="SALOME_MED::FIELDINT_ptr"
 133   idl_impl_hxx["SALOME::vectorOfLong"]="SALOME::vectorOfLong*"
 134   idl_impl_hxx["StrSeq"]=class_name"_ORB::StrSeq*"
 135   idl_impl_hxx["in SALOME_MED::MEDCouplingFieldDoubleCorbaInterface"]="SALOME_MED::MEDCouplingFieldDoubleCorbaInterface_ptr"
 136   idl_impl_hxx["SALOME_MED::MEDCouplingUMeshCorbaInterface"]="SALOME_MED::MEDCouplingUMeshCorbaInterface_ptr"
 137   idl_impl_hxx["SALOME_MED::MEDCouplingFieldDoubleCorbaInterface"]="SALOME_MED::MEDCouplingFieldDoubleCorbaInterface_ptr"
 138   idl_impl_hxx["out SALOME_MED::MEDCouplingFieldDoubleCorbaInterface"]="SALOME_MED::MEDCouplingFieldDoubleCorbaInterface_out"
 139 #
 140 #
 141 # table for c++ code generation : argument's processing
 142 #
 143   cpp_impl_a["int"]="\tint _%s(%s);\n"
 144   cpp_impl_a["bool"]="\tbool _%s(%s);\n"
 145   cpp_impl_a["double"]="\tdouble _%s(%s);\n"
 146   cpp_impl_a["float"]="\tfloat _%s(%s);\n"
 147   cpp_impl_a["long"]="\tlong _%s(%s);\n"
 148   cpp_impl_a["short"]="\tshort _%s(%s);\n"
 149   cpp_impl_a["unsigned"]="\tunsigned _%s(%s);\n"
 150   cpp_impl_a["const char*"]="\tconst char* _%s(%s);\n"
 151   cpp_impl_a["const std::string&"]="\tconst std::string _%s(%s);\n"
 152   cpp_impl_a["int&"]="\tint _%s;\n"
 153   cpp_impl_a["bool&"]="\tbool _%s;\n"
 154   cpp_impl_a["double&"]="\tdouble _%s;\n"
 155   cpp_impl_a["float&"]="\tfloat _%s;\n"
 156   cpp_impl_a["long&"]="\tlong _%s;\n"
 157   cpp_impl_a["short&"]="\tshort _%s;\n"
 158   cpp_impl_a["unsigned&"]="\tunsigned _%s;\n"
 159   cpp_impl_a["std::string&"]="\tstd::string _%s;\n"
 160   cpp_impl_a["const MEDMEM::MESH&"]="\tMEDMEM::MESHClient* _%s = new MEDMEM::MESHClient(%s);\n\t _%s->fillCopy();\n" # MESHClient cannot be created on the stack (private constructor), so we create it on the heap and dereference it later (in treatment 4)
 161   cpp_impl_a["const MEDMEM::MESH*"]="\tMEDMEM::MESHClient* _%s = new MEDMEM::MESHClient(%s);\n\t _%s->fillCopy();\n"
 162   cpp_impl_a["const MEDMEM::SUPPORT&"]="\tMEDMEM::SUPPORTClient* _%s = new MEDMEM::SUPPORTClient(%s);\n" # SUPPORTClient cannot be created on the stack (protected destructor), so we create it on the heap and dereference it later (in treatment 4)
 163   cpp_impl_a["const MEDMEM::SUPPORT*"]="\tMEDMEM::SUPPORTClient* _%s = new MEDMEM::SUPPORTClient(%s);\n"
 164   cpp_impl_a["MEDMEM::FIELD<double>*&"]="\tMEDMEM::FIELD<double>* _%s;\n"
 165   cpp_impl_a["const MEDMEM::FIELD<double>*"]="\tstd::auto_ptr<MEDMEM::FIELD<double> > _%s ( new MEDMEM::FIELDClient<double,MEDMEM::FullInterlace>(%s) );\n"
 166   cpp_impl_a["const MEDMEM::FIELD<double>&"]="\tMEDMEM::FIELDClient<double,MEDMEM::FullInterlace> _%s(%s);\n"
 167   cpp_impl_a["const std::vector<double>&"]="\tlong _%s_size=%s.length();\n\tconst double *_%s_value = &%s[0];\n"\
 168              "\tstd::vector<double> _%s(_%s_value,_%s_value+_%s_size);\n"
 169 #  cpp_impl_a["const std::vector<double>&"]="\tlong _%s_size;\n\tdouble *_%s_value = ReceiverFactory::getValue(%s,_%s_size);\n"\
 170 #             "\tstd::vector<double> _%s(_%s_value,_%s_value+_%s_size);\n\tdelete [] _%s_value;"
 171   cpp_impl_a["std::vector<double>*&"]="\tstd::vector<double>* _%s;\n"
 172   cpp_impl_a["const std::vector<std::vector<double> >&"]="\tMatrixClient _%s_client;\n\tint _%s_nbRow;\n\tint _%s_nbCol;\n"\
 173              "\tdouble* _%s_tab = _%s_client.getValue(%s,_%s_nbCol,_%s_nbRow);\n\tstd::vector<std::vector<double> > _%s(_%s_nbRow);\n"\
 174              "\tfor (int i=0; i!=_%s_nbRow; ++i)\n\t{\n\t    _%s[i].resize(_%s_nbCol);\n"\
 175              "\t    std::copy(_%s_tab+_%s_nbCol*i,_%s_tab+_%s_nbCol*(i+1), _%s[i].begin());\n\t}\n\tdelete [] _%s_tab;\n"
 176   cpp_impl_a["MEDMEM::FIELD<int>*&"]="\tMEDMEM::FIELD<int>* _%s;\n"
 177   cpp_impl_a["const MEDMEM::FIELD<int>*"]="\tstd::auto_ptr<MEDMEM::FIELD<int> > _%s ( new MEDMEM::FIELDClient<int>(%s) );\n"
 178   cpp_impl_a["const MEDMEM::FIELD<int>&"]="\tMEDMEM::FIELDClient<int> _%s(%s);\n"
 179   cpp_impl_a["const std::vector<int>&"]="\tlong _%s_size=%s.length();\n"\
 180                          "\tstd::vector<int> _%s(_%s_size);\n"\
 181                          "\tfor (int i=0; i!=_%s_size; ++i)\n\t    _%s[i]=%s[i];"
 182 #  cpp_impl_a["const std::vector<int>&"]="\tlong _%s_size;\n\tint *_%s_value = ReceiverFactory::getValue(%s,_%s_size);\n"\
 183 #             "\tstd::vector<int> _%s(_%s_value,_%s_value+_%s_size);\n\tdelete [] _%s_value;"
 184   cpp_impl_a["std::vector<int>*&"]="\tstd::vector<int>* _%s;\n"
 185   cpp_impl_a["const ParaMEDMEM::MEDCouplingFieldDouble*"]=\
 186             "\tParaMEDMEM::MEDCouplingFieldDouble* _%s=ParaMEDMEM::MEDCouplingFieldDoubleClient::New(%s);\n"
 187   cpp_impl_a["const ParaMEDMEM::MEDCouplingFieldDouble&"]=\
 188             "\tParaMEDMEM::MEDCouplingFieldDouble* __%s=ParaMEDMEM::MEDCouplingFieldDoubleClient::New(%s);\n"\
 189             "\tParaMEDMEM::MEDCouplingFieldDouble& _%s=*__%s;\n"
 190   cpp_impl_a["ParaMEDMEM::MEDCouplingFieldDouble*&"]="\tParaMEDMEM::MEDCouplingFieldDouble* _%s;\n"
 191 #
 192 #
 193 # table for c++ code generation : returned value processing
 194 #
 195   cpp_impl_b["void"]=""
 196   cpp_impl_b["int"]="\tCORBA::Long _rtn_ior(_rtn_cpp);\n"
 197   cpp_impl_b["bool"]="\tCORBA::Boolean _rtn_ior(_rtn_cpp);\n"
 198   cpp_impl_b["double"]="\tCORBA::Double _rtn_ior(_rtn_cpp);\n"
 199   cpp_impl_b["float"]="\tCORBA::Float _rtn_ior(_rtn_cpp);\n"
 200   cpp_impl_b["long"]="\tCORBA::Long _rtn_ior(_rtn_cpp);\n"
 201   cpp_impl_b["short"]="\tCORBA::Short _rtn_ior(_rtn_cpp);\n"
 202   cpp_impl_b["unsigned"]="\tCORBA::ULong _rtn_ior(_rtn_cpp);\n"
 203   cpp_impl_b["const char*"]="\tchar* _rtn_ior = CORBA::string_dup(_rtn_cpp);\n"
 204   cpp_impl_b["char*"]="\tchar* _rtn_ior(_rtn_cpp);\n"
 205   cpp_impl_b["std::string"]="\tchar* _rtn_ior=CORBA::string_dup(_rtn_cpp.c_str());\n"
 206              "\tstd::copy(_rtn_cpp.begin(),_rtn_cpp.end(),_rtn_ior);\n"
 207   cpp_impl_b["const MEDMEM::MESH&"]=\
 208              "\tMEDMEM::MESH_i * _rtn_mesh_i = new MEDMEM::MESH_i(const_cast<MEDMEM::MESH*>(&_rtn_cpp));\n"\
 209              "\tSALOME_MED::MESH_ptr _rtn_ior = _rtn_mesh_i->_this();\n"
 210   cpp_impl_b["MEDMEM::MESH&"]=\
 211              "\tMEDMEM::MESH_i * _rtn_mesh_i = new MEDMEM::MESH_i(&_rtn_cpp);\n"\
 212              "\tSALOME_MED::MESH_ptr _rtn_ior = _rtn_mesh_i->_this();\n"
 213   cpp_impl_b["MEDMEM::MESH*"]=\
 214              "\tMEDMEM::MESH_i * _rtn_mesh_i = new MEDMEM::MESH_i(_rtn_cpp);\n"\
 215              "\tSALOME_MED::MESH_ptr _rtn_ior = _rtn_mesh_i->_this();\n"
 216   cpp_impl_b["const MEDMEM::MESH*"]=\
 217              "\tMEDMEM::MESH_i * _rtn_mesh_i = new MEDMEM::MESH_i(const_cast<MEDMEM::MESH*>(_rtn_cpp));\n"\
 218              "\tSALOME_MED::MESH_ptr _rtn_ior = _rtn_mesh_i->_this();\n"
 219   cpp_impl_b["MEDMEM::SUPPORT*"]=\
 220              "\tMEDMEM::SUPPORT_i * _rtn_support_i = new MEDMEM::SUPPORT_i(_rtn_cpp);\n"\
 221              "\tSALOME_MED::SUPPORT_ptr _rtn_ior = _rtn_support_i->_this();\n"
 222   cpp_impl_b["const MEDMEM::FIELD<double>*"]=\
 223              "\tMEDMEM::FIELDTEMPLATE_I<double,MEDMEM::FullInterlace> * _rtn_field_i = new MEDMEM::FIELDTEMPLATE_I<double,MEDMEM::FullInterlace>(const_cast<MEDMEM::FIELD<double>*>(_rtn_cpp),false);\n"\
 224              "\tSALOME_MED::FIELDDOUBLE_ptr _rtn_ior = _rtn_field_i->_this();\n"
 225   cpp_impl_b["MEDMEM::FIELD<double>*"]=\
 226              "\tMEDMEM::FIELDTEMPLATE_I<double,MEDMEM::FullInterlace> * _rtn_field_i = new MEDMEM::FIELDTEMPLATE_I<double,MEDMEM::FullInterlace>(_rtn_cpp,true);\n"\
 227              "\tSALOME_MED::FIELDDOUBLE_ptr _rtn_ior = _rtn_field_i->_this();\n"
 228   cpp_impl_b["MEDMEM::FIELD<double>&"]=\
 229              "\tMEDMEM::FIELDTEMPLATE_I<double,MEDMEM::FullInterlace> * _rtn_field_i = new MEDMEM::FIELDTEMPLATE_I<double,MEDMEM::FullInterlace>(&_rtn_cpp,false);\n"\
 230              "\tSALOME_MED::FIELDDOUBLE_ptr _rtn_ior = _rtn_field_i->_this();\n"
 231   cpp_impl_b["const MEDMEM::FIELD<double>&"]=\
 232              "\tMEDMEM::FIELDTEMPLATE_I<double,MEDMEM::FullInterlace> * _rtn_field_i = new MEDMEM::FIELDTEMPLATE_I<double,MEDMEM::FullInterlace>(const_cast<MEDMEM::FIELD<double>*>(&_rtn_cpp),false);\n"\
 233              "\tSALOME_MED::FIELDDOUBLE_ptr _rtn_ior = _rtn_field_i->_this();\n"
 234   cpp_impl_b["std::vector<double>*"]=\
 235              "\tSALOME::vectorOfDouble * _rtn_ior = new SALOME::vectorOfDouble;\n"\
 236              "\tint _rtn_cpp_length=(*_rtn_cpp).size();\n"\
 237              "\t_rtn_ior->length(_rtn_cpp_length);\n"\
 238              "\tfor (int i=0; i<_rtn_cpp_length; ++i)\n\t    (*_rtn_ior)[i] = (*_rtn_cpp)[i];\n"
 239 #  cpp_impl_b["std::vector<double>*"]=\
 240 #             "\tSALOME::SenderDouble_ptr _rtn_ior = SenderFactory::buildSender(*this,&(*_rtn_cpp)[0],(*_rtn_cpp).size(),true);\n"
 241   cpp_impl_b["std::vector<std::vector<double> >*"]=\
 242              "\tint _rtn_cpp_i=(*_rtn_cpp).size();\n\tint _rtn_cpp_j=(*_rtn_cpp)[0].size();\n"\
 243              "\tdouble* _rtn_tab = new double[_rtn_cpp_i*_rtn_cpp_j];\n"\
 244              "\tfor (int i=0; i!=_rtn_cpp_i; ++i)\n\t    std::copy((*_rtn_cpp)[i].begin(),(*_rtn_cpp)[i].end(),_rtn_tab+i*_rtn_cpp_j);\n"\
 245              "\tSALOME_Matrix_i* _rtn_matrix_i = new SALOME_Matrix_i(*this,_rtn_tab,_rtn_cpp_i,_rtn_cpp_j,true);\n"\
 246              "\tSALOME::Matrix_ptr _rtn_ior = _rtn_matrix_i->_this();\n\tdelete _rtn_cpp;\n"
 247   cpp_impl_b["const MEDMEM::FIELD<int>*"]=\
 248              "\tMEDMEM::FIELDINT_i * _rtn_field_i = new MEDMEM::FIELDINT_i(const_cast<MEDMEM::FIELD<int>*>(_rtn_cpp),false);\n"\
 249              "\tSALOME_MED::FIELDINT_ptr _rtn_ior = _rtn_field_i->_this();\n"
 250   cpp_impl_b["MEDMEM::FIELD<int>*"]=\
 251              "\tMEDMEM::FIELDINT_i * _rtn_field_i = new MEDMEM::FIELDINT_i(_rtn_cpp,true);\n"\
 252              "\tSALOME_MED::FIELDINT_ptr _rtn_ior = _rtn_field_i->_this();\n"
 253   cpp_impl_b["MEDMEM::FIELD<int>&"]=\
 254              "\tMEDMEM::FIELDINT_i * _rtn_field_i = new MEDMEM::FIELDINT_i(&_rtn_cpp,false);\n"\
 255              "\tSALOME_MED::FIELDINT_ptr _rtn_ior = _rtn_field_i->_this();\n"
 256   cpp_impl_b["const MEDMEM::FIELD<int>&"]=\
 257              "\tMEDMEM::FIELDINT_i * _rtn_field_i = new MEDMEM::FIELDINT_i(const_cast<MEDMEM::FIELD<int>*>(&_rtn_cpp),false);\n"\
 258              "\tSALOME_MED::FIELDINT_ptr _rtn_ior = _rtn_field_i->_this();\n"
 259   cpp_impl_b["std::vector<int>*"]=\
 260              "\tSALOME::vectorOfLong * _rtn_ior = new SALOME::vectorOfLong;\n"\
 261              "\tint _rtn_cpp_length=(*_rtn_cpp).size();\n"\
 262              "\t_rtn_ior->length(_rtn_cpp_length);\n"\
 263              "\tfor (int i=0; i<_rtn_cpp_length; ++i)\n\t    (*_rtn_ior)[i] = (*_rtn_cpp)[i];\n"
 264   cpp_impl_b["std::vector<std::string>"]=\
 265              "\t"class_name"_ORB::StrSeq*_rtn_ior = new "class_name"_ORB::StrSeq;\n"\
 266              "\tint _rtn_cpp_length=_rtn_cpp.size();\n"\
 267              "\t_rtn_ior->length(_rtn_cpp_length);\n"\
 268              "\tfor (int i=0; i<_rtn_cpp_length; ++i)\n"\
 269              "\t    (*_rtn_ior)[i] = _rtn_cpp[i].c_str();\n"
 270   cpp_impl_b["ParaMEDMEM::MEDCouplingFieldDouble*"]=\
 271              "\tParaMEDMEM::MEDCouplingFieldDoubleServant * _rtn_field_i = new ParaMEDMEM::MEDCouplingFieldDoubleServant(_rtn_cpp);\n"\
 272              "\t_rtn_cpp->decrRef();\n"\
 273              "\tSALOME_MED::MEDCouplingFieldDoubleCorbaInterface_ptr _rtn_ior = _rtn_field_i->_this();\n"
 274   cpp_impl_b["ParaMEDMEM::MEDCouplingUMesh*"]=\
 275              "\tParaMEDMEM::MEDCouplingUMeshServant * _rtn_mesh_i = new ParaMEDMEM::MEDCouplingUMeshServant(_rtn_cpp);\n"\
 276              "\t_rtn_cpp->decrRef();\n"\
 277              "\tSALOME_MED::MEDCouplingUMeshCorbaInterface_ptr _rtn_ior = _rtn_mesh_i->_this();\n"
 278 #  cpp_impl_b["std::vector<int>*"]=\
 279 #             "\tSALOME::SenderInt_ptr _rtn_ior = SenderFactory::buildSender(*this,&(*_rtn_cpp)[0],(*_rtn_cpp).size(),true);\n"
 280
 281 #
 282 #
 283 # table for c++ code generation : out parameters processing and removeRef for reference counted objects
 284 #
 285   cpp_impl_c["MEDMEM::FIELD<double>*&"]=\
 286              "\tMEDMEM::FIELDTEMPLATE_I<double,MEDMEM::FullInterlace> * %s_ior = new MEDMEM::FIELDTEMPLATE_I<double,MEDMEM::FullInterlace>(_%s, true);\n"\
 287              "\t%s = %s_ior->_this();\n"
 288   cpp_impl_c["MEDMEM::FIELD<int>*&"]=\
 289              "\tMEDMEM::FIELDINT_i * %s_ior = new MEDMEM::FIELDINT_i(_%s, true);\n"\
 290              "\t%s = %s_ior->_this();\n"
 291   cpp_impl_c["std::vector<double>*&"]=\
 292              "\t%s = new SALOME::vectorOfDouble;\n"\
 293              "\t%s->length((*_%s).size());\n"\
 294              "\tfor (int i=0; i<(*_%s).size(); ++i)\n\t    (*%s)[i] = (*_%s)[i];\n"
 295 #             "\t%s = SenderFactory::buildSender(*this,&(*_%s)[0],(*_%s).size(),true);\n"
 296   cpp_impl_c["std::vector<int>*&"]=\
 297              "\t%s = new SALOME::vectorOfLong;\n"\
 298              "\t%s->length((*_%s).size());\n"\
 299              "\tfor (int i=0; i<(*_%s).size(); ++i)\n\t    (*%s)[i] = (*_%s)[i];\n"
 300 #             "\t%s = SenderFactory::buildSender(*this,&(*_%s)[0],(*_%s).size(),true);\n"
 301   cpp_impl_c["std::string&"]="\t%s = CORBA::string_dup(_%s.c_str());\n"
 302   cpp_impl_c["int&"]="\t%s = _%s;\n"
 303   cpp_impl_c["bool&"]="\t%s = _%s;\n"
 304   cpp_impl_c["double&"]="\t%s = _%s;\n"
 305   cpp_impl_c["float&"]="\t%s = _%s;\n"
 306   cpp_impl_c["long&"]="\t%s = _%s;\n"
 307   cpp_impl_c["short&"]="\t%s = _%s;\n"
 308   cpp_impl_c["unsigned&"]="\t%s = _%s;\n"
 309   cpp_impl_c["const MEDMEM::MESH&"]="\t_%s->removeReference();\n"
 310   cpp_impl_c["const MEDMEM::MESH*"]="\t_%s->removeReference();\n"
 311   cpp_impl_c["const MEDMEM::SUPPORT&"]="\t_%s->removeReference();\n"
 312   cpp_impl_c["const MEDMEM::SUPPORT*"]="\t_%s->removeReference();\n"
 313   cpp_impl_c["const ParaMEDMEM::MEDCouplingFieldDouble*"]="\t_%s->decrRef();\n"
 314   cpp_impl_c["const ParaMEDMEM::MEDCouplingFieldDouble&"]="\t__%s->decrRef();\n"
 315   cpp_impl_c["ParaMEDMEM::MEDCouplingFieldDouble*&"]= \
 316       "\tParaMEDMEM::MEDCouplingFieldDoubleServant * %s_out=new ParaMEDMEM::MEDCouplingFieldDoubleServant(_%s);\
 317         _%s->decrRef();                                                 \
 318         %s = %s_out->_this();\n"
 319 #
 320 #
 321 # record sep is ");\n" whith blanks all around, and optional "(" at the beginning
 322   RS="[(]?[ \t]*[)][ \t]*(const)?[ \t]*[;][ \t]*[\n]"
 323   FS="[ \t]*[(,][ \t]*"  # field sep is either "(" or "," surrounded by blanks
 324 }
 325
 326 # --------------------- treatment 1 ----------------------------------
 327 #
 328 #  extract from fields types, function name, and argument's names
 329 #
 330 {
 331   print "Function : ",$0 >> "parse_result"  # print for debug
 332   for (i=1; i<=NF; i++) {
 333       print "\t-> ",i," : ",$i >> "parse_result"
 334   }
 335   ok1=0;ok=1
 336   error_message="\t  The non compatible types are : "
 337   # check if returned type ($1) is one of the accepted types (idl_rtn_type)
 338   for (cpptype in idl_rtn_type) {
 339     if ( substr($1,1,length(cpptype)) == cpptype ) {
 340       # if compatible, store returned type and function name
 341       type[1]=cpptype
 342       name[1]=substr($1,length(cpptype)+1)
 343       sub("^[ \t]*","",name[1]) # get rid of leading blanks
 344       ok1=1
 345       break
 346     }
 347   }
 348   ok*=ok1
 349   if ( ! ok1) {
 350       split($1,tab," ")
 351       error_message=error_message sprintf("\n\t\t-> %s (return type)",tab[1])
 352   }
 353   # for each argument ($i), check if it is compatible (belongs to idl_arg_type)
 354   for (i=2; i<=NF; i++) {
 355     ok2=0
 356     split($i,tab,"=") # get rid of default value
 357     item=tab[1]
 358     sub("/[ \t]*&[ \t]*/", "&", item) # supress spaces around * and $
 359     sub("/[ \t]**[ \t]*/", "*", item)
 360     for (cpptype in idl_arg_type) {
 361         l = length(cpptype)
 362         s0 = substr(item,1,l) # to discriminate between int and int&, ...
 363         s1 = " "
 364         if (length(item) > l)
 365             s1 = substr(item, l+1, 1)
 366
 367         if ( (s0 == cpptype) && (s1 == " ") ) {
 368           # if compatible, store argument type and name
 369           type[i]=cpptype
 370           name[i]=substr(item,length(cpptype)+1)
 371           sub("^[ \t]*","",name[i]) # get rid of leading blanks
 372           if ( length(name[i]) == 0 ) # automatic name if argument's name wasn't precised
 373              name[i]=sprintf("_arg%d",i-1)
 374           ok2=1
 375           break
 376        }
 377     }
 378     ok*=ok2 # ok=0 if one of the type is not compatible
 379     if ( ! ok2) {
 380         error_message=error_message "\n\t\t-> "item
 381     }
 382   }
 383
 384   # print compatibility
 385   if ( $0 !~ class_name ) { # constructor are not considered, but we don't print it
 386       if ( ok == 0){ # if one of the c++ type is not compatible
 387           printf "     [KO]     :  %s",$0
 388       }
 389       else
 390           printf "     [OK]     :  %s",$0
 391
 392       if ( $0 !~ /\(/  ) {
 393           printf "(" # if there is no argument, parenthesis was suppressed, so we add it for printing
 394       }
 395       printf ");\n"
 396       if ( ok == 0){ #print the error message
 397           printf "%s\n\n",error_message
 398       }
 399   }
 400   if ( ok == 0) # pass to the next function if one of the c++ type is not compatible
 401       next
 402 }
 403 #
 404 # --------------------- treatment 2 ----------------------------------
 405 #
 406 #  generate the Corba interface (idl file)
 407 #
 408 {
 409   printf "\t%s %s(", idl_rtn_type[type[1]],name[1] >> idl_file  # return type and name of function
 410   if ( NF >= 2 ){  # if there is arguments, print them
 411     for (i=2; i<=NF-1; i++)
 412       printf "%s %s,",idl_arg_type[type[i]],name[i] >> idl_file
 413     printf "%s %s", idl_arg_type[type[NF]],name[NF] >> idl_file
 414   }
 415   printf ") raises (SALOME::SALOME_Exception);\n" >> idl_file
 416 }
 417 #
 418 # --------------------- treatment 3 ----------------------------------
 419 #
 420 #  generate the C++ implementation of component (hxx file)
 421 #
 422 {
 423   printf "    %s %s(",idl_impl_hxx[idl_rtn_type[type[1]]],name[1] >> hxx_file
 424   if ( NF >= 2 ){  # if there is arguments, print them
 425       for (i=2; i<=NF-1; i++)
 426           printf "%s %s,",idl_impl_hxx[idl_arg_type[type[i]]],name[i] >> hxx_file
 427       printf "%s %s", idl_impl_hxx[idl_arg_type[type[NF]]],name[NF] >> hxx_file
 428   }
 429   printf ") throw (SALOME::SALOME_Exception);\n" >> hxx_file
 430 }
 431 #
 432 # --------------------- treatment 4 ----------------------------------
 433 #
 434 #  generate the C++ implementation of component (cxx file)
 435 #
 436 {
 437   # a) generate the function declaration + macro declarations
 438   func_name=class_name"_i::"name[1]
 439   printf "%s %s(",idl_impl_hxx[idl_rtn_type[type[1]]],func_name >> cxx_file
 440   if ( NF >= 2 ){  # if there is arguments, print them
 441       for (i=2; i<=NF-1; i++)
 442           printf "%s %s,",idl_impl_hxx[idl_arg_type[type[i]]],name[i] >> cxx_file
 443       printf "%s %s", idl_impl_hxx[idl_arg_type[type[NF]]],name[NF] >> cxx_file
 444   }
 445   printf ") throw (SALOME::SALOME_Exception)\n{\n    beginService(\"%s\");\n    BEGIN_OF(\"%s\");\n    try\n    {\n",func_name,func_name >> cxx_file
 446
 447   # b) generate the argument processing part
 448   if ( NF >= 2 ){
 449       printf "//\tArguments processing\n" >> cxx_file
 450       for (i=2; i<=NF; i++)
 451           printf cpp_impl_a[type[i]],name[i],name[i],name[i],name[i],name[i],name[i],name[i],name[i],name[i],\
 452                            name[i],name[i],name[i],name[i],name[i],name[i],name[i],name[i],name[i],name[i] >> cxx_file
 453   }
 454
 455   # c) generate the call to the c++ component
 456   if ( type[1] == "void" ) # if return type is void, the call syntax is different.
 457       printf "//\tCall cpp component\n\tcppCompo_->%s(",name[1] >> cxx_file
 458   else
 459       printf "//\tCall cpp component\n\t%s _rtn_cpp = cppCompo_->%s(",type[1],name[1] >> cxx_file
 460   if ( NF >= 2 ){  # if there is arguments, print them
 461       for (i=2; i<=NF; i++) {
 462           # special treatment for some arguments
 463           post=""
 464           pre=""
 465           if ( cpp_impl_a[type[i]] ~ "auto_ptr" )
 466              post=".get()" # for auto_ptr argument, retrieve the raw pointer behind
 467           if ( type[i] == "const MEDMEM::MESH&" || type[i] == "const MEDMEM::SUPPORT&" )
 468              pre="*"  # we cannot create MESHClient on the stack (private constructor), so we create it on the heap and dereference it
 469           if ( i < NF )
 470              post=post"," # separator between arguments
 471           printf " %s_%s%s",pre,name[i],post >> cxx_file
 472       }
 473   }
 474
 475   # d) generate the post_processing of returned and out parameters
 476   printf ");\n//\tPost-processing & return\n" >> cxx_file
 477   for (i=2; i<=NF; i++)
 478       printf cpp_impl_c[type[i]],name[i],name[i],name[i],name[i],name[i],name[i] >> cxx_file  # process for out parameters
 479   printf cpp_impl_b[type[1]] >> cxx_file  # process for returned value
 480   printf "\tendService(\"%s\");\n\tEND_OF(\"%s\");\n",func_name,func_name >> cxx_file
 481   if ( type[1] != "void" )
 482       printf "\treturn _rtn_ior;\n" >> cxx_file
 483   printf "    }\n    catch (std::exception& ex)\n    {\n        THROW_SALOME_CORBA_EXCEPTION( ex.what(), SALOME::INTERNAL_ERROR );\n    }\n" >> cxx_file
 484   printf "}\n\n" >> cxx_file
 485 }
 486 #
 487 #
 488 END {
 489 # CNC peut être mis dans le template directement printf "\nprivate:\n    std::auto_ptr<%s> cppImpl_;\n",class_name >> hxx_file
 490 }