salome_adm/unix/config_files/check_med2.m4

   1 dnl  Copyright (C) 2003  OPEN CASCADE, EADS/CCR, LIP6, CEA/DEN,
   2 dnl  CEDRAT, EDF R&D, LEG, PRINCIPIA R&D, BUREAU VERITAS
   3 dnl
   4 dnl  This library is free software; you can redistribute it and/or
   5 dnl  modify it under the terms of the GNU Lesser General Public
   6 dnl  License as published by the Free Software Foundation; either
   7 dnl  version 2.1 of the License.
   8 dnl
   9 dnl  This library is distributed in the hope that it will be useful,
  10 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 dnl  Lesser General Public License for more details.
  13 dnl
  14 dnl  You should have received a copy of the GNU Lesser General Public
  15 dnl  License along with this library; if not, write to the Free Software
  16 dnl  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
  17 dnl
  18 dnl  See http://www.opencascade.org/SALOME/ or email : webmaster.salome@opencascade.org
  19 dnl
  20 dnl
  21 dnl
  22
  23 AC_DEFUN([CHECK_MED2],[
  24 AC_REQUIRE([AC_PROG_CC])dnl
  25 AC_REQUIRE([AC_PROG_CPP])dnl
  26 AC_REQUIRE([CHECK_HDF5])dnl
  27
  28 AC_CHECKING(for MED2)
  29
  30 AC_ARG_WITH(med2,
  31     [  --with-med2=DIR                 root directory path to med2 installation ],
  32     [MED2HOME="$withval"
  33       AC_MSG_RESULT("select $withval as path to med2")
  34     ])
  35
  36 AC_SUBST(MED2_INCLUDES)
  37 AC_SUBST(MED2_LIBS)
  38 AC_SUBST(MED2_MT_LIBS)
  39
  40 MED2_INCLUDES=""
  41 MED2_LIBS=""
  42 MED2_MT_LIBS=""
  43
  44 med2_ok=no
  45
  46 LOCAL_INCLUDES="$HDF5_INCLUDES"
  47 LOCAL_LIBS="-lmed $HDF5_LIBS"
  48
  49 if test -z $MED2HOME
  50 then
  51    AC_MSG_WARN(undefined MED2HOME variable which specify med2 installation directory)
  52 else
  53    LOCAL_INCLUDES="$LOCAL_INCLUDES -I$MED2HOME/include"
  54    LOCAL_LIBS="-L$MED2HOME/lib $LOCAL_LIBS"
  55 fi
  56
  57 dnl check med2 header
  58
  59 CPPFLAGS_old="$CPPFLAGS"
  60 dnl we must test system : linux = -DPCLINUX
  61 dnl we must test system : Alpha-OSF = -DOSF1
  62 case $host_os in
  63    linux*)
  64       CPPFLAGS="$CPPFLAGS -DPCLINUX $LOCAL_INCLUDES"
  65       ;;
  66    osf*)
  67       CPPFLAGS="$CPPFLAGS -DOSF1 $LOCAL_INCLUDES"
  68       ;;
  69 esac
  70 AC_CHECK_HEADER(med.h,med2_ok=yes ,med2_ok=no)
  71 CPPFLAGS="$CPPFLAGS_old"
  72
  73 if  test "x$med2_ok" = "xyes"
  74 then
  75
  76 dnl check med2 library
  77
  78   LIBS_old="$LIBS"
  79   LIBS="$LIBS $LOCAL_LIBS"
  80   AC_CHECK_LIB(med,MEDouvrir,med2_ok=yes,med2_ok=no)
  81   LIBS="$LIBS_old"
  82
  83 fi
  84
  85 if  test "x$med2_ok" = "xyes"
  86 then
  87 case $host_os in
  88    linux*)
  89         MED2_INCLUDES="-DPCLINUX $LOCAL_INCLUDES"
  90       ;;
  91    osf*)
  92       MED2_INCLUDES="-DOSF1 $LOCAL_INCLUDES"
  93       ;;
  94 esac
  95   MED2_LIBS="$LOCAL_LIBS"
  96   MED2_MT_LIBS="$LOCAL_LIBS"
  97 fi
  98
  99 AC_MSG_RESULT(for med2: $med2_ok)
 100
 101 ])dnl