salome_adm/unix/config_files/check_cas.m4

   1 dnl Copyright (C) 2007-2011  CEA/DEN, EDF R&D, OPEN CASCADE
   2 dnl
   3 dnl Copyright (C) 2003-2007  OPEN CASCADE, EADS/CCR, LIP6, CEA/DEN,
   4 dnl CEDRAT, EDF R&D, LEG, PRINCIPIA R&D, BUREAU VERITAS
   5 dnl
   6 dnl This library is free software; you can redistribute it and/or
   7 dnl modify it under the terms of the GNU Lesser General Public
   8 dnl License as published by the Free Software Foundation; either
   9 dnl version 2.1 of the License.
  10 dnl
  11 dnl This library is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14 dnl Lesser General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU Lesser General Public
  17 dnl License along with this library; if not, write to the Free Software
  18 dnl Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
  19 dnl
  20 dnl See http://www.salome-platform.org/ or email : webmaster.salome@opencascade.com
  21 dnl
  22
  23 AC_DEFUN([CHECK_CAS],[
  24 AC_REQUIRE([AC_PROG_CXX])dnl
  25 AC_REQUIRE([AC_PROG_CXXCPP])dnl
  26
  27 AC_CHECKING(for OpenCascade)
  28
  29 AC_LANG_SAVE
  30 AC_LANG_CPLUSPLUS
  31
  32 AC_SUBST(CAS_CPPFLAGS)
  33 AC_SUBST(CAS_CXXFLAGS)
  34 AC_SUBST(CAS_KERNEL)
  35 AC_SUBST(CAS_MATH)
  36 AC_SUBST(CAS_VIEWER)
  37 AC_SUBST(CAS_TKTopAlgo)
  38 AC_SUBST(CAS_MODELER)
  39 AC_SUBST(CAS_OCAF)
  40 AC_SUBST(CAS_OCAFVIS)
  41 AC_SUBST(CAS_DATAEXCHANGE)
  42 AC_SUBST(CAS_LDFLAGS)
  43 AC_SUBST(CAS_LDPATH)
  44 AC_SUBST(CAS_STDPLUGIN)
  45 AC_SUBST(CAS_LIBDIR)
  46 AC_SUBST(CAS_DATADIR)
  47 AC_SUBST(CASROOT)
  48
  49 CAS_CPPFLAGS=""
  50 CAS_CXXFLAGS=""
  51 CAS_LDFLAGS=""
  52 occ_ok=no
  53 config_h=no
  54
  55 dnl libraries directory location
  56 case $host_os in
  57    linux*)
  58       casdir=Linux
  59       ;;
  60    freebsd*)
  61       casdir=Linux
  62       ;;
  63    irix5.*)
  64       casdir=Linux
  65       ;;
  66    irix6.*)
  67       casdir=Linux
  68       ;;
  69    osf*)
  70       casdir=Linux
  71       ;;
  72    solaris2.*)
  73       casdir=Linux
  74       ;;
  75    *)
  76       casdir=Linux
  77       ;;
  78 esac
  79
  80 AC_MSG_CHECKING(for OpenCascade directories)
  81
  82 if test -z "$CASROOT"; then
  83   AC_MSG_RESULT(CASROOT not defined)
  84   for d in `echo $LD_LIBRARY_PATH | sed -e "s/:/ /g"` ; do
  85     if test -f $d/libTKernel.so ; then
  86       AC_MSG_RESULT(libTKernel.so detected in $d)
  87       CASROOT=$d
  88       CASROOT=`echo ${CASROOT} | sed -e "s,[[^/]]*$,,;s,/$,,;s,^$,.,"`
  89       break
  90     fi
  91   done
  92 fi
  93
  94 CAS_LIBDIR="$CASROOT/$casdir/lib"
  95 if test -d ${CAS_LIBDIR}; then
  96   AC_MSG_RESULT(yes)
  97 else
  98   if test -d ${CASROOT}/lib; then
  99     CAS_LIBDIR="$CASROOT/lib"
 100     AC_MSG_RESULT(yes)
 101   else
 102     AC_MSG_RESULT(no)
 103   fi
 104 fi
 105   CAS_LDPATH="-L$CAS_LIBDIR "
 106
 107 dnl were is OCC ?
 108 if test -z "$CASROOT"; then
 109   AC_MSG_WARN(You must provide CASROOT variable : see OCC installation manual)
 110 else
 111   occ_ok=yes
 112   OCC_VERSION_MAJOR=0
 113   OCC_VERSION_MINOR=0
 114   OCC_VERSION_MAINTENANCE=0
 115   if test -f $CASROOT/inc/Standard_Version.hxx; then
 116     ff=$CASROOT/inc/Standard_Version.hxx
 117   else
 118     ff=$CASROOT/include/opencascade/Standard_Version.hxx
 119   fi
 120   if test -f $ff; then
 121     grep "define OCC_VERSION_MAJOR" $ff > /dev/null
 122     if test $? = 0 ; then
 123       OCC_VERSION_MAJOR=`grep "define OCC_VERSION_MAJOR" $ff | awk '{i=3 ; print $i}'`
 124     fi
 125     grep "define OCC_VERSION_MINOR" $ff > /dev/null
 126     if test $? = 0 ; then
 127       OCC_VERSION_MINOR=`grep "define OCC_VERSION_MINOR" $ff | awk '{i=3 ; print $i}'`
 128     fi
 129     grep "define OCC_VERSION_MAINTENANCE" $ff > /dev/null
 130     if test $? = 0 ; then
 131       OCC_VERSION_MAINTENANCE=`grep "define OCC_VERSION_MAINTENANCE" $ff | awk '{i=3 ; print $i}'`
 132     fi
 133     AC_MSG_CHECKING(for OpenCascade data files)
 134     if test -f ${CASROOT}/src/UnitsAPI/Lexi_Expr.dat; then
 135       CAS_DATADIR=${CASROOT}
 136       AC_MSG_RESULT(found in $CAS_DATADIR/src)
 137     else
 138       if test -f ${CASROOT}/share/opencascade/${OCC_VERSION_MAJOR}.${OCC_VERSION_MINOR}.${OCC_VERSION_MAINTENANCE}/src/UnitsAPI/Lexi_Expr.dat; then
 139         CAS_DATADIR=${CASROOT}/share/opencascade/${OCC_VERSION_MAJOR}.${OCC_VERSION_MINOR}.${OCC_VERSION_MAINTENANCE}
 140         AC_MSG_RESULT(found in $CAS_DATADIR/src)
 141       else
 142         occ_ok=no
 143         AC_MSG_RESULT(not found, check OpenCascade installation)
 144       fi
 145     fi
 146   fi
 147 fi
 148
 149 if test "x$occ_ok" = "xyes"; then
 150
 151 dnl test c++ compiler flag for unsigned character
 152   for opt in -funsigned-char -unsigned ; do
 153     AC_CXX_OPTION($opt,CAS_CXXFLAGS,flag=yes,flag=no)
 154     if test "$flag" = "yes"; then
 155       break
 156     fi
 157   done
 158
 159 dnl cascade headers
 160
 161   CPPFLAGS_old="$CPPFLAGS"
 162 case $host_os in
 163    linux*)
 164       CAS_CPPFLAGS="-DOCC_VERSION_MAJOR=$OCC_VERSION_MAJOR -DOCC_VERSION_MINOR=$OCC_VERSION_MINOR -DOCC_VERSION_MAINTENANCE=$OCC_VERSION_MAINTENANCE -DLIN -DLINTEL -DCSFDB -DNo_exception -DHAVE_CONFIG_H -DHAVE_LIMITS_H -DHAVE_WOK_CONFIG_H"
 165
 166       OCC_VERSION_STRING="$OCC_VERSION_MAJOR.$OCC_VERSION_MINOR.$OCC_VERSION_MAINTENANCE"
 167       case $OCC_VERSION_STRING in
 168         [[0-5]].* | 6.0.* | 6.1.0) # catch versions < 6.1.1
 169           CAS_CPPFLAGS="$CAS_CPPFLAGS -DNO_CXX_EXCEPTION"
 170           ;;
 171         *)
 172           CAS_CPPFLAGS="$CAS_CPPFLAGS -DOCC_CONVERT_SIGNALS"
 173           ;;
 174       esac
 175       CAS_CPPFLAGS="$CAS_CPPFLAGS -I$CASROOT/inc -I$CASROOT/include/opencascade"
 176       ;;
 177    osf*)
 178       CAS_CPPFLAGS="-DOCC_VERSION_MAJOR=$OCC_VERSION_MAJOR -DOCC_VERSION_MINOR=$OCC_VERSION_MINOR -DOCC_VERSION_MAINTENANCE=$OCC_VERSION_MAINTENANCE -DLIN -DLINTEL -DCSFDB -DNo_exception -DHAVE_CONFIG_H -DHAVE_LIMITS_H -DHAVE_WOK_CONFIG_H -I$CASROOT/inc"
 179       ;;
 180 esac
 181   CPPFLAGS="$CPPFLAGS $CAS_CPPFLAGS"
 182
 183   echo
 184   echo testing config.h
 185
 186   AC_CHECK_HEADER(config.h, config_h=yes, [
 187         echo "config.h file not found!"
 188   ])
 189
 190   if test "x$config_h" = xno ; then
 191       AC_MSG_WARN(config.h file not found)
 192       dnl There is no consequence for SALOME building because
 193       dnl this file is not used. SALOME uses SALOMEconfig.h instead!
 194   else
 195       AC_MSG_RESULT(config.h file ok)
 196   fi
 197
 198   AC_CHECK_HEADER(Standard_Type.hxx,occ_ok=yes ,occ_ok=no)
 199
 200 fi
 201
 202 if test "x$occ_ok" = xyes ; then
 203
 204   AC_MSG_CHECKING(for OpenCascade libraries)
 205
 206   LIBS_old="$LIBS"
 207   LIBS="$LIBS $CAS_LDPATH -lTKernel"
 208
 209   AC_CACHE_VAL(salome_cv_lib_occ,[
 210     AC_TRY_LINK(
 211 #include <TCollection_AsciiString.hxx>
 212 ,    TCollection_AsciiString aStr ("toto");
 213     aStr.Capitalize();,
 214     eval "salome_cv_lib_occ=yes",eval "salome_cv_lib_occ=no")
 215   ])
 216   occ_ok="$salome_cv_lib_occ"
 217
 218 fi
 219 CPPFLAGS="$CPPFLAGS_old"
 220 LIBS="$LIBS_old"
 221
 222 if test "x$occ_ok" = xno ; then
 223   AC_MSG_RESULT(no)
 224   AC_MSG_WARN(Opencascade libraries not found)
 225 else
 226   AC_MSG_RESULT(yes)
 227   CAS_KERNEL="$CAS_LDPATH -lTKernel"
 228   CAS_MATH="$CAS_LDPATH -lTKMath"
 229
 230   CAS_OCAF="$CAS_LDPATH -lPTKernel -lTKernel -lTKCDF -lTKLCAF -lTKPCAF -lTKStdSchema"
 231   CAS_OCAFVIS="$CAS_LDPATH -lTKCAF -lTKPLCAF -lTKPShape -lTKStdLSchema -lTKShapeSchema"
 232
 233   if test -f $CASROOT/$casdir/lib/libStdPlugin.so ; then
 234     # standard plugin library libStdPlugin has been added in CASCADE 5.2.3
 235     CAS_STDPLUGIN="StdPlugin"
 236     CAS_OCAFVIS="$CAS_OCAFVIS -lStdPlugin -lStdLPlugin"
 237   elif test -f $CASROOT/$casdir/lib/libTKStdSchema.so ; then
 238     # standard plugin has been renamed in CASCADE 6.5
 239     CAS_STDPLUGIN=TKStdSchema
 240     CAS_OCAFVIS="$CAS_OCAFVIS -lTKStdSchema -lTKStdLSchema"
 241   fi
 242
 243   CAS_TKV3d="$CAS_LDPATH -lTKV3d"
 244   CAS_VIEWER="$CAS_TKV3d -lTKService"
 245
 246   CAS_TKBRep="$CAS_LDPATH -lTKG2d -lTKG3d -lTKGeomBase -lTKBRep"
 247
 248   CAS_TKTopAlgo="$CAS_TKBRep -lTKGeomAlgo -lTKTopAlgo"
 249   CAS_TKPrim="$CAS_TKTopAlgo -lTKPrim"
 250
 251   CAS_MODELER="$CAS_TKPrim -lTKBO -lTKBool -lTKHLR -lTKFillet -lTKOffset -lTKFeat"
 252
 253   CAS_DATAEXCHANGE="$CAS_LDPATH -lTKIGES -lTKSTEP"
 254
 255   CAS_LDFLAGS="$CAS_KERNEL $CAS_MATH $CAS_OCAF $CAS_OCAFVIS $CAS_VIEWER $CAS_MODELER $CAS_DATAEXCHANGE"
 256
 257 fi
 258
 259 AC_LANG_RESTORE
 260
 261 ])dnl
 262
 263