products/compil_scripts/ispc.bat

   1 @echo off
   2
   3 echo ##########################################################################
   4 echo ISPC %VERSION%
   5 echo ##########################################################################
   6
   7 IF NOT DEFINED SAT_DEBUG (
   8   SET SAT_DEBUG=0
   9 )
  10
  11 IF NOT DEFINED CMAKE_GENERATOR (
  12   SET CMAKE_GENERATOR="Visual Studio 15 2017"
  13 )
  14
  15 SET PRODUCT_BUILD_TYPE=Release
  16 REM Building ISPC in DEBUG mode is definitely not relevant.
  17 REM if %SAT_DEBUG% == 1 (
  18 REM   set PRODUCT_BUILD_TYPE=Debug
  19 REM )
  20
  21 if NOT exist "%PRODUCT_INSTALL%" mkdir %PRODUCT_INSTALL%
  22 REM clean BUILD directory
  23 if exist "%BUILD_DIR%" rmdir /Q /S %BUILD_DIR%
  24 mkdir %BUILD_DIR%
  25
  26 if NOT defined CYGWIN_ROOT_DIR (
  27   echo ERROR: Please set the environment variable: CYGWIN_ROOT_DIR
  28   exit 1
  29 ) else (
  30   echo INFO: Cygwin suite environment variable is set to: %CYGWIN_ROOT_DIR%
  31 )
  32
  33 set PATH=%PATH%;%CYGWIN_ROOT_DIR%\bin
  34
  35 SET CMAKE_OPTIONS=
  36 SET CMAKE_OPTIONS=%CMAKE_OPTIONS% -DCMAKE_INSTALL_PREFIX:STRING=%PRODUCT_INSTALL:\=/%
  37 SET CMAKE_OPTIONS=%CMAKE_OPTIONS% -DCMAKE_BUILD_TYPE:STRING=%PRODUCT_BUILD_TYPE%
  38 SET CMAKE_OPTIONS=%CMAKE_OPTIONS% -DCMAKE_VERBOSE_MAKEFILE:BOOL=ON
  39 SET CMAKE_OPTIONS=%CMAKE_OPTIONS% -DPYTHON_EXECUTABLE=%PYTHON_ROOT_DIR:\=/%/python.exe
  40 SET CMAKE_OPTIONS=%CMAKE_OPTIONS% -G %CMAKE_GENERATOR% -A x64
  41
  42 cd %BUILD_DIR%
  43
  44 echo.
  45 echo --------------------------------------------------------------------------
  46 echo *** %CMAKE_ROOT%\bin\cmake %CMAKE_OPTIONS% %SOURCE_DIR%
  47 echo --------------------------------------------------------------------------
  48
  49 %CMAKE_ROOT%\bin\cmake %CMAKE_OPTIONS% %SOURCE_DIR%
  50 if NOT %ERRORLEVEL% == 0 (
  51     echo ERROR on CMake
  52     exit 1
  53 )
  54
  55 echo.
  56 echo --------------------------------------------------------------------------
  57 echo *** msbuild %MAKE_OPTIONS% ALL_BUILD.vcxproj /p:Configuration=%PRODUCT_BUILD_TYPE%  /p:Platform=x64
  58 echo --------------------------------------------------------------------------
  59
  60 msbuild %MAKE_OPTIONS% ALL_BUILD.vcxproj /p:Configuration=%PRODUCT_BUILD_TYPE% /p:Platform=x64
  61 if NOT %ERRORLEVEL% == 0 (
  62     echo ERROR on msbuild ALL_BUILD.vcxproj
  63     exit 2
  64 )
  65
  66 echo.
  67 echo --------------------------------------------------------------------------
  68 echo *** msbuild %MAKE_OPTIONS% INSTALL.vcxproj /p:Configuration=%PRODUCT_BUILD_TYPE%  /p:Platform=x64
  69 echo --------------------------------------------------------------------------
  70
  71 msbuild %MAKE_OPTIONS% INSTALL.vcxproj /p:Configuration=%PRODUCT_BUILD_TYPE%  /p:Platform=x64
  72 if NOT %ERRORLEVEL% == 0 (
  73     echo ERROR on msbuild INSTALL.vcxproj
  74     exit 3
  75 )
  76
  77 taskkill /F /IM "mspdbsrv.exe"
  78
  79 echo.
  80 echo ########## END