products/compil_scripts/PyQt-5.9.bat

   1 @echo off
   2
   3 echo ##########################################################################
   4 echo PyQt %VERSION%
   5 echo ##########################################################################
   6
   7 IF NOT DEFINED SAT_DEBUG (
   8   SET SAT_DEBUG=0
   9 )
  10
  11 if NOT exist "%PRODUCT_INSTALL%" mkdir %PRODUCT_INSTALL%
  12 REM clean BUILD directory
  13 if exist "%BUILD_DIR%" rmdir /Q /S %BUILD_DIR%
  14 mkdir %BUILD_DIR%
  15
  16 cd %SOURCE_DIR%
  17
  18 call :NORMALIZEPATH "%PRODUCT_INSTALL%\..\Python"
  19 set python_exe=%RETVAL%\python.exe
  20 set python_name=python%PYTHON_VERSION%
  21
  22 call :NORMALIZEPATH "%PRODUCT_INSTALL%\..\sip"
  23 set sip_incdir=%RETVAL%\include\%python_name%
  24
  25 echo.
  26 echo --------------------------------------------------------------------------
  27 echo *** python configure.py
  28 echo --------------------------------------------------------------------------
  29
  30 set PRODUCT_BUILD_TYPE=
  31 if %SAT_DEBUG% == 1 (
  32    python configure.py --confirm-license --no-designer-plugin --debug --bindir=%PRODUCT_INSTALL%\bin --destdir=%PRODUCT_INSTALL%\lib\%python_name%\site-packages --sipdir=%PRODUCT_INSTALL%\sip --spec=win32-msvc --sip-incdir=%sip_incdir% --pyuic5-interpreter=%python_exe% --disable QtNfc --disable=QtNetwork --disable=QtWebSockets 2>&1
  33 ) else (
  34    python configure.py --confirm-license --no-designer-plugin --bindir=%PRODUCT_INSTALL%\bin --destdir=%PRODUCT_INSTALL%\lib\%python_name%\site-packages --sipdir=%PRODUCT_INSTALL%\sip --spec=win32-msvc --sip-incdir=%sip_incdir% --pyuic5-interpreter=%python_exe% --disable QtNfc --disable=QtNetwork --disable=QtWebSockets 2>&1
  35 )
  36 if NOT %ERRORLEVEL% == 0 (
  37     echo ERROR on python configure.py
  38     exit 1
  39 )
  40
  41 REM Compilation
  42 echo.
  43 echo --------------------------------------------------------------------------
  44 echo *** nmake
  45 echo --------------------------------------------------------------------------
  46
  47 nmake VERBOSE=1
  48 if NOT %ERRORLEVEL% == 0 (
  49     echo ERROR on nmake
  50     exit 2
  51 )
  52
  53 REM Installation
  54 echo.
  55 echo --------------------------------------------------------------------------
  56 echo *** nmake install
  57 echo --------------------------------------------------------------------------
  58
  59 nmake install
  60 if NOT %ERRORLEVEL% == 0 (
  61     echo "ERROR on nmake install"
  62     exit 3
  63 )
  64
  65 REM In debug mode, we need to rename all .pyd to _d.pyd.
  66 if %SAT_DEBUG% == 1 (
  67   cd %PRODUCT_INSTALL%\lib\%python_name%\site-packages\PyQt5
  68   powershell -Command "Get-ChildItem -File -Recurse *.pyd| ForEach-Object {if ((!$_.Name.EndsWith('_d.pyd'))) {  $_ | Copy-Item -Destination {$_.Name  -replace '.pyd','_d.pyd'}}}"
  69   powershell -Command "Get-ChildItem -File -Recurse *_d.pyd| ForEach-Object {if (($_.Name.EndsWith('_d.pyd'))) {  $_ | Copy-Item -Destination {$_.Name  -replace '_d.pyd','.pyd'}}}"
  70 )
  71
  72 echo.
  73 echo ########## END
  74
  75 :: ========== FUNCTIONS ==========
  76 EXIT /B
  77
  78 :NORMALIZEPATH
  79   SET RETVAL=%~dpfn1
  80   EXIT /B