products/compil_scripts/PyQt-5.15.bat

   1 @echo off
   2
   3 echo ##########################################################################
   4 echo PyQt %VERSION%
   5 echo ##########################################################################
   6
   7 IF NOT DEFINED SAT_DEBUG (
   8   SET SAT_DEBUG=0
   9 )
  10
  11 if NOT exist "%PRODUCT_INSTALL%" mkdir %PRODUCT_INSTALL%
  12 REM clean BUILD directory
  13 if exist "%BUILD_DIR%" rmdir /Q /S %BUILD_DIR%
  14 mkdir %BUILD_DIR%
  15 cd %SOURCE_DIR%
  16 xcopy * %BUILD_DIR%\ /E /I /Q
  17 cd %BUILD_DIR%
  18
  19 echo.
  20 echo --------------------------------------------------------------------------
  21 echo *** python configure.py
  22 echo --------------------------------------------------------------------------
  23
  24 SET BUILD_OPTIONS=
  25 if %SAT_DEBUG% == 1 (
  26  SET BUILD_OPTIONS= --debug --no-dist-info -u
  27 )
  28
  29 SET BUILD_OPTIONS=%BUILD_OPTIONS% -b %PRODUCT_INSTALL:\=/%/bin
  30 SET BUILD_OPTIONS=%BUILD_OPTIONS% -d %PRODUCT_INSTALL:\=/%
  31 SET BUILD_OPTIONS=%BUILD_OPTIONS% -v %PRODUCT_INSTALL:\=/%/sip
  32 SET BUILD_OPTIONS=%BUILD_OPTIONS% --stubsdir=%PRODUCT_INSTALL:\=/%/lib/site-packages
  33 SET BUILD_OPTIONS=%BUILD_OPTIONS% --designer-plugindir=%PRODUCT_INSTALL:\=/%/plugins/designer
  34 SET BUILD_OPTIONS=%BUILD_OPTIONS% --qml-plugindir=%PRODUCT_INSTALL:\=/%/plugins/qml
  35 SET BUILD_OPTIONS=%BUILD_OPTIONS% --no-qsci-api
  36 SET BUILD_OPTIONS=%BUILD_OPTIONS% --spec=win32-msvc
  37 SET BUILD_OPTIONS=%BUILD_OPTIONS% --confirm-license
  38 SET BUILD_OPTIONS=%BUILD_OPTIONS% --disable=QtNfc --disable=QtNetwork --disable=QtWebSockets
  39 SET BUILD_OPTIONS=%BUILD_OPTIONS% --target-py-version=%PYTHON_VERSION%
  40
  41 %PYTHONBIN% configure.py %BUILD_OPTIONS:\=/%
  42 if NOT %ERRORLEVEL% == 0 (
  43     echo ERROR on python configure.py %BUILD_OPTIONS:\=/%
  44     exit 1
  45 )
  46
  47 REM Compilation
  48 echo.
  49 echo --------------------------------------------------------------------------
  50 echo *** nmake
  51 echo --------------------------------------------------------------------------
  52
  53 nmake VERBOSE=1
  54 if NOT %ERRORLEVEL% == 0 (
  55     echo ERROR on nmake
  56     exit 2
  57 )
  58
  59 REM Installation
  60 echo.
  61 echo --------------------------------------------------------------------------
  62 echo *** nmake install
  63 echo --------------------------------------------------------------------------
  64
  65 nmake install
  66 if NOT %ERRORLEVEL% == 0 (
  67     echo "ERROR on nmake install"
  68     exit 3
  69 )
  70
  71 REM In debug mode, we need to rename all .pyd to _d.pyd.
  72 if %SAT_DEBUG% == 1 (
  73   cd %PRODUCT_INSTALL%\lib\%python_name%\site-packages\PyQt5
  74   powershell -Command "Get-ChildItem -File -Recurse *.pyd| ForEach-Object {if ((!$_.Name.EndsWith('_d.pyd'))) {  $_ | Copy-Item -Destination {$_.Name  -replace '.pyd','_d.pyd'}}}"
  75   powershell -Command "Get-ChildItem -File -Recurse *_d.pyd| ForEach-Object {if (($_.Name.EndsWith('_d.pyd'))) {  $_ | Copy-Item -Destination {$_.Name  -replace '_d.pyd','.pyd'}}}"
  76 )
  77
  78 echo.
  79 echo ########## END