config_files/check_qt.m4

   1 dnl  Copyright (C) 2007-2008  CEA/DEN, EDF R&D, OPEN CASCADE
   2 dnl
   3 dnl  Copyright (C) 2003-2007  OPEN CASCADE, EADS/CCR, LIP6, CEA/DEN,
   4 dnl  CEDRAT, EDF R&D, LEG, PRINCIPIA R&D, BUREAU VERITAS
   5 dnl
   6 dnl  This library is free software; you can redistribute it and/or
   7 dnl  modify it under the terms of the GNU Lesser General Public
   8 dnl  License as published by the Free Software Foundation; either
   9 dnl  version 2.1 of the License.
  10 dnl
  11 dnl  This library is distributed in the hope that it will be useful,
  12 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14 dnl  Lesser General Public License for more details.
  15 dnl
  16 dnl  You should have received a copy of the GNU Lesser General Public
  17 dnl  License along with this library; if not, write to the Free Software
  18 dnl  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
  19 dnl
  20 dnl  See http://www.salome-platform.org/ or email : webmaster.salome@opencascade.com
  21 dnl
  22 dnl  OPTIONS_QT
  23 dnl  ------------------------------------------------------------------------
  24 dnl  Adds the --with-qt=path
  25 dnl
  26 AC_DEFUN([OPTIONS_QT], [
  27   AC_ARG_WITH([qt],
  28               [AC_HELP_STRING([--with-qt], [Possible usage:
  29                                              "Qt_Install_Path" - prefix to path where Qt was installd;
  30                                              "" or "yes" or "auto" - means seaching installed Qt product in the system (checking $QTDIR and then - standard system paths );
  31                                              "no" - not use Qt product (is not supported)
  32                                             By default "" option is used)])],
  33               [with_qt=$withval], [with_qt=""])
  34 ])
  35
  36 AC_DEFUN([CHECK_QT],[
  37 AC_REQUIRE([AC_PROG_CC])dnl
  38 AC_REQUIRE([AC_PROG_CXX])dnl
  39 AC_REQUIRE([AC_PROG_CPP])dnl
  40 AC_REQUIRE([AC_PROG_CXXCPP])dnl
  41 AC_REQUIRE([CHECK_OPENGL])dnl
  42 AC_REQUIRE([AC_LINKER_OPTIONS])dnl
  43
  44 AC_REQUIRE([OPTIONS_QT])dnl
  45
  46 AC_CHECKING(for Qt)
  47
  48 if test "x$OpenGL_ok" != "xyes" ; then
  49    AC_MSG_WARN(Qt needs OpenGL correct configuration, check configure output)
  50 fi
  51
  52 qt_ok=yes
  53
  54 AC_LANG_SAVE
  55 AC_LANG_CPLUSPLUS
  56
  57 dnl QT install dir
  58 if test -z $with_qt ; then
  59   with_qt=""
  60 fi
  61 if test "x$with_qt" = "xyes" ; then
  62   dnl in case user wrote --with-qt=yes
  63   with_qt=""
  64 fi
  65 if test "x$with_qt" = "xauto" ; then
  66   dnl in case user wrote --with-qt=auto
  67   with_qt=""
  68 fi
  69 if test "x$with_qt" = "xno" ; then
  70   dnl in case user wrote --with-qt=no
  71   with_qt=""
  72   AC_MSG_WARN(Value no, specified for option --with-qt, is not supported)
  73 fi
  74
  75 if test "x$with_qt" != "x" ; then
  76   dnl Using "--with-qt" prefix path
  77   QTDIR="$with_qt"
  78 elif test "$QTDIR" = "/usr/lib/qt3" ; then
  79   dnl Using QTDIR environment variable
  80   AC_MSG_RESULT(current QTDIR is $QTDIR)
  81   dnl
  82   if test -d /usr/lib/qt4 ; then
  83     AC_MSG_RESULT(it is strange for a qt4 installation !)
  84     AC_MSG_RESULT(/usr/lib/qt4 is present)
  85     AC_MSG_RESULT(replacing QTDIR by /usr/lib/qt4)
  86     QTDIR=/usr/lib/qt4
  87   fi
  88 elif test -z $QTDIR ; then
  89   AC_MSG_WARN(undefined QTDIR variable which specify where Qt product was installed)
  90   for d in /usr/local/lib/qt4 /usr/lib/qt4 /usr ; do
  91     if test -f ${d}/lib/libQtCore.so ; then
  92       AC_MSG_RESULT(trying ${d})
  93       QTDIR="${d}"
  94       break
  95     elif test -f ${d}/lib64/libQtCore.so ; then
  96       AC_MSG_RESULT(trying ${d})
  97       QTDIR="${d}"
  98       break
  99     elif test -f ${d}/libQtCore.so ; then
 100       AC_MSG_RESULT(trying ${d})
 101       QTDIR="${d}"
 102       break
 103     fi
 104   done
 105 fi
 106
 107 #
 108 # check QTDIR environment variable
 109 #
 110 if test "x$QTDIR" = "x"
 111 then
 112    AC_MSG_RESULT(Please define correct path in "--with-qt" option or use correct $QTDIR variable)
 113    qt_ok=no
 114 fi
 115
 116 #
 117 # check Qt version
 118 #
 119 if  test "x$qt_ok" = "xyes"
 120 then
 121    qt_inc_ok=no
 122    QTINC=""
 123    AC_CHECK_FILE(${QTDIR}/include/qt4/QtCore/qglobal.h,QTINC="/qt4",QTINC="")
 124    if test "x$QTINC" = "x"
 125    then
 126      AC_CHECK_FILE(${QTDIR}/include${QTINC}/QtCore/qglobal.h,qt_inc_ok=yes,qt_inc_ok=no)
 127    else
 128      qt_inc_ok=yes
 129    fi
 130    if test "x$qt_inc_ok" = "xyes"
 131    then
 132      AC_MSG_CHECKING(whether Qt version >= 4.0)
 133      QT_VERSION=`grep "QT_VERSION_STR" ${QTDIR}/include${QTINC}/QtCore/qglobal.h | sed -e 's%^#define QT_VERSION_STR[[:space:]]*\"\([[:digit:]\.]*\)\"%\1%g'`
 134      QT_VERSION_ID=`echo $QT_VERSION | awk -F. '{v=$[1]*10000+$[2]*100+$[3];print v}'`
 135      if test $QT_VERSION_ID -ge 40000
 136      then
 137        AC_MSG_RESULT(yes)
 138      else
 139        AC_MSG_RESULT(no)
 140        qt_ok=no
 141      fi
 142      AC_MSG_CHECKING(Qt version)
 143      AC_MSG_RESULT($QT_VERSION)
 144    else
 145      qt_ok=no
 146    fi
 147 fi
 148
 149 #
 150 # check moc presence (meta-object compiler)
 151 #
 152 if  test "x$qt_ok" = "xyes"
 153 then
 154   if test -f ${QTDIR}/bin/moc
 155   then
 156     MOC=${QTDIR}/bin/moc
 157   else
 158     AC_PATH_PROG(MOC, moc)
 159   fi
 160   if test "x$MOC" = "x"
 161   then
 162     qt_ok=no
 163     AC_MSG_RESULT(moc (Qt meta-object compiler) is not in the PATH variable)
 164   else
 165     qt_ok=yes
 166     AC_MSG_RESULT(moc (Qt meta-object compiler) is found)
 167   fi
 168
 169   if test "x$qt_ok" = "xyes"
 170   then
 171     dnl check moc version
 172     AC_MSG_CHECKING(cheching equality Qt and moc tool version)
 173     MOC_VERSION=`$MOC -v 2>&1 | awk 'BEGIN{FS="[[ ()]]"};{print $(NF-1)}'`
 174     if test "x$QT_VERSION" = "x$MOC_VERSION"
 175     then
 176       AC_MSG_RESULT(yes)
 177       qt_ok=yes
 178     else
 179       AC_MSG_RESULT(moc tool and Qt product are incompatible $MOC_VERSION)
 180       qt_ok=no
 181     fi
 182   fi
 183 fi
 184
 185 #
 186 # check uic presence (user interface compiler)
 187 #
 188 if  test "x$qt_ok" = "xyes"
 189 then
 190   if test -f ${QTDIR}/bin/uic
 191   then
 192     UIC=${QTDIR}/bin/uic
 193   else
 194     AC_PATH_PROG(UIC, uic)
 195   fi
 196   if test "x$UIC" = "x"
 197   then
 198     qt_ok=no
 199     AC_MSG_RESULT(uic (Qt user interface compiler) is not in the PATH variable)
 200   else
 201     qt_ok=yes
 202     AC_MSG_RESULT(uic (Qt user interface compiler) is found)
 203   fi
 204 fi
 205
 206 #
 207 # check rcc presence (resources compiler)
 208 #
 209 if  test "x$qt_ok" = "xyes"
 210 then
 211   if test -f ${QTDIR}/bin/rcc
 212   then
 213     QRCC=${QTDIR}/bin/rcc
 214   else
 215     AC_PATH_PROG(QRCC, rcc)
 216   fi
 217   if test "x$QRCC" = "x"
 218   then
 219     qt_ok=no
 220     AC_MSG_RESULT(rcc (Qt resources compiler) is not in the PATH variable)
 221   else
 222     qt_ok=yes
 223     AC_MSG_RESULT(rcc (Qt resources compiler) is found)
 224   fi
 225
 226   if test "x$qt_ok" = "xyes"
 227   then
 228     dnl check rcc version
 229     AC_MSG_CHECKING(cheching equality Qt and rcc tool version)
 230     QRCC_VERSION=`$QRCC -v 2>&1 | awk '{print $NF}'`
 231     if test "x$QT_VERSION" = "x$QRCC_VERSION"
 232     then
 233       AC_MSG_RESULT(yes)
 234       qt_ok=yes
 235     else
 236       AC_MSG_RESULT(rcc tool and Qt product are incompatible)
 237       qt_ok=no
 238     fi
 239   fi
 240 fi
 241
 242 #
 243 # check lrelease presence (translation files compiler)
 244 #
 245 if  test "x$qt_ok" = "xyes"
 246 then
 247   if test -f ${QTDIR}/bin/lrelease
 248   then
 249     LRELEASE=${QTDIR}/bin/lrelease
 250   else
 251     AC_PATH_PROG(LRELEASE, lrelease)
 252   fi
 253   if test "x$LRELEASE" = "x"
 254   then
 255     qt_ok=no
 256     AC_MSG_RESULT(lrelease (Qt translation files compiler) is not in the PATH variable)
 257   else
 258     qt_ok=yes
 259     AC_MSG_RESULT(lrelease (Qt translation files compiler) is found)
 260   fi
 261
 262   if test "x$qt_ok" = "xyes"
 263   then
 264     dnl check lrelease version
 265     AC_MSG_CHECKING( equality of Qt and lrelease tool version)
 266     LRELEASE_VERSION=`$LRELEASE -version 2>&1 | awk '{print $NF}'`
 267     if test "x$QT_VERSION" = "x$LRELEASE_VERSION"
 268     then
 269       AC_MSG_RESULT(yes)
 270       qt_ok=yes
 271     else
 272       AC_MSG_RESULT(lrelease tool and Qt product are incompatible)
 273       qt_ok=no
 274     fi
 275   fi
 276 fi
 277
 278 QT_ROOT=$QTDIR
 279
 280 #
 281 # check Qt header files
 282 #
 283 if  test "x$qt_ok" = "xyes"
 284 then
 285   AC_CHECKING(include Qt header files)
 286
 287   CPPFLAGS_old=$CPPFLAGS
 288   CPPFLAGS="$CPPFLAGS -I${QTDIR}/include${QTINC} -I${QTDIR}/include${QTINC}/QtCore"
 289   AC_CHECK_HEADER(QObject,qt_ok=yes,qt_ok=no)
 290   CPPFLAGS=$CPPFLAGS_old
 291
 292   if  test "x$qt_ok" = "xno"
 293   then
 294     AC_MSG_RESULT(qt header files are not found in $QTDIR/include${QTINC}/QtCore)
 295     AC_MSG_RESULT(QTDIR environment variable may be wrong (probably too old Qt version))
 296   else
 297     AC_MSG_RESULT(qt header files seem to be OK)
 298     QT_INCLUDES="-I${QTDIR}/include${QTINC}"
 299     # user header files
 300     QT_INCLUDES="${QT_INCLUDES} -I${QTDIR}/include${QTINC}/QtCore"
 301     QT_INCLUDES="${QT_INCLUDES} -I${QTDIR}/include${QTINC}/QtGui"
 302     QT_INCLUDES="${QT_INCLUDES} -I${QTDIR}/include${QTINC}/QtOpenGL"
 303     QT_INCLUDES="${QT_INCLUDES} -I${QTDIR}/include${QTINC}/QtXml"
 304     # not used currently header files (uncomment if required)
 305     #QT_INCLUDES="${QT_INCLUDES} -I$(QTDIR)/include${QTINC}/QtAssistant"
 306     #QT_INCLUDES="${QT_INCLUDES} -I$(QTDIR)/include${QTINC}/QtDBus"
 307     #QT_INCLUDES="${QT_INCLUDES} -I$(QTDIR)/include${QTINC}/QtDesigner"
 308     #QT_INCLUDES="${QT_INCLUDES} -I$(QTDIR)/include${QTINC}/QtNetwork"
 309     #QT_INCLUDES="${QT_INCLUDES} -I$(QTDIR)/include${QTINC}/QtSql"
 310     #QT_INCLUDES="${QT_INCLUDES} -I$(QTDIR)/include${QTINC}/QtSvg"
 311     #QT_INCLUDES="${QT_INCLUDES} -I$(QTDIR)/include${QTINC}/QtTest"
 312     #QT_INCLUDES="${QT_INCLUDES} -I$(QTDIR)/include${QTINC}/QtUiTools"
 313
 314     QT_ASSISTANT_INCLUDES="${QT_ASSISTANT_INCLUDES} -I${QTDIR}/include${QTINC}/QtAssistant"
 315     QT_ASSISTANT_INCLUDES="${QT_ASSISTANT_INCLUDES} -I${QTDIR}/include${QTINC}/QtNetwork"
 316
 317     # this flag is obsolete with Qt 4
 318     QT_MT_INCLUDES="$QT_INCLUDES"
 319   fi
 320 fi
 321
 322 #
 323 # test Qt libraries
 324 #
 325 if  test "x$qt_ok" = "xyes"
 326 then
 327   AC_MSG_CHECKING(linking against Qt library)
 328
 329   CXXFLAGS_old=$CXXFLAGS
 330   CXXFLAGS="$CXXFLAGS $QT_INCLUDES"
 331
 332   LIBS_old=$LIBS
 333   if test "x$QTDIR" = "x/usr" ; then
 334     QT_LIB_DIR=""
 335   elif test -d ${QTDIR}/lib; then
 336     QT_LIB_DIR="-L$QTDIR/lib"
 337   elif test -d ${QTDIR}/lib64; then
 338     QT_LIB_DIR="-L$QTDIR/lib64"
 339   elif test "x$QTDIR" = "x/usr/lib/qt4" ; then
 340     QT_LIB_DIR=""
 341   else
 342     AC_MSG_ERROR(Can't detect of Qt library directory )
 343     qt_ok=no
 344   fi
 345   LIBS="$LIBS $QT_LIB_DIR -lQtCore"
 346
 347   AC_CACHE_VAL(salome_cv_lib_qt,[
 348     AC_TRY_LINK(
 349 #include <QCoreApplication>
 350 ,   int n;
 351     char **s;
 352     QCoreApplication a(n, s);
 353     a.exec();,
 354     eval "salome_cv_lib_qt=yes",eval "salome_cv_lib_qt=no")
 355   ])
 356   qt_ok="$salome_cv_lib_qt"
 357
 358   # BEGIN: for CCRT (installation of qt have only a "lib" directory)
 359   if  test "x$qt_ok" = "xno"
 360   then
 361     QT_LIB_DIR="-L$QTDIR/lib"
 362     LIBS="$LIBS_old $QT_LIB_DIR -lQtCore"
 363
 364     AC_CACHE_VAL(salome_cv_lib_qt,[
 365       AC_TRY_LINK(
 366 #include <QCoreApplication>
 367 ,     int n;
 368       char **s;
 369       QCoreApplication a(n, s);
 370       a.exec();,
 371       eval "salome_cv_lib_qt=yes",eval "salome_cv_lib_qt=no")
 372     ])
 373     qt_ok="$salome_cv_lib_qt"
 374   fi
 375   # END: for CCRT
 376
 377   if  test "x$qt_ok" = "xno"
 378   then
 379     AC_MSG_RESULT(no)
 380     AC_MSG_RESULT(unable to link with qt library)
 381     AC_MSG_RESULT(QTDIR environment variable may be wrong (probably too old Qt version))
 382   else
 383     AC_MSG_RESULT(yes)
 384     # core libs
 385     QT_CORE_LIBS="$QT_LIB_DIR -lQtCore -lQtXml"
 386     # gui libs
 387     QT_GUI_LIBS="$QT_LIB_DIR -lQtGui -lQtOpenGL"
 388     # other libs (currently not used)
 389     QT_OTHER_LIBS="$QT_LIB_DIR"
 390     # other libs (can be used if necessary)
 391     #QT_OTHER_LIBS="$QT_LIB_DIR -lQt3Support -lQtAssistantClient -lQtDesigner -lQtNetwork -lQtSql -lQtSvg -lQtTest -ltQtUiTools"
 392     QT_ASSISTANT_LIBS="$QT_LIB_DIR -lQtAssistantClient -lQtNetwork"
 393     # all libs
 394     QT_LIBS="$QT_CORE_LIBS $QT_GUI_LIBS $QT_OTHER_LIBS"
 395     # this flag is obsolete with Qt 4
 396     QT_MT_LIBS="$QT_LIBS"
 397   fi
 398   LIBS=$LIBS_old
 399   CXXFLAGS=$CXXFLAGS_old
 400 fi
 401
 402 AC_SUBST(QTDIR)
 403 AC_SUBST(MOC)
 404 AC_SUBST(UIC)
 405 AC_SUBST(QRCC)
 406 AC_SUBST(LRELEASE)
 407
 408 AC_SUBST(QT_ROOT)
 409 AC_SUBST(QT_INCLUDES)
 410 AC_SUBST(QT_MT_INCLUDES)
 411 AC_SUBST(QT_ASSISTANT_INCLUDES)
 412 AC_SUBST(QT_LIB_DIR)
 413 AC_SUBST(QT_CORE_LIBS)
 414 AC_SUBST(QT_GUI_LIBS)
 415 AC_SUBST(QT_OTHER_LIBS)
 416 AC_SUBST(QT_LIBS)
 417 AC_SUBST(QT_MT_LIBS)
 418 AC_SUBST(QT_ASSISTANT_LIBS)
 419 AC_SUBST(QT_VERSION)
 420 AC_SUBST(QT_VERSION_ID)
 421
 422 AC_LANG_RESTORE
 423
 424 AC_MSG_RESULT(for Qt: $qt_ok)
 425
 426 # Save cache
 427 AC_CACHE_SAVE
 428
 429 ])dnl
 430 dnl