adm/unix/config_files/ac_python_devel.m4

   1 # ===========================================================================
   2 #      http://www.gnu.org/software/autoconf-archive/ax_python_devel.html
   3 # ===========================================================================
   4 #
   5 # SYNOPSIS
   6 #
   7 #   AX_PYTHON_DEVEL([version])
   8 #
   9 # DESCRIPTION
  10 #
  11 #   Note: Defines as a precious variable "PYTHON_VERSION". Don't override it
  12 #   in your configure.ac.
  13 #
  14 #   This macro checks for Python and tries to get the include path to
  15 #   'Python.h'. It provides the $(PYTHON_CPPFLAGS) and $(PYTHON_LDFLAGS)
  16 #   output variables. It also exports $(PYTHON_EXTRA_LIBS) and
  17 #   $(PYTHON_EXTRA_LDFLAGS) for embedding Python in your code.
  18 #
  19 #   You can search for some particular version of Python by passing a
  20 #   parameter to this macro, for example ">= '2.3.1'", or "== '2.4'". Please
  21 #   note that you *have* to pass also an operator along with the version to
  22 #   match, and pay special attention to the single quotes surrounding the
  23 #   version number. Don't use "PYTHON_VERSION" for this: that environment
  24 #   variable is declared as precious and thus reserved for the end-user.
  25 #
  26 #   This macro should work for all versions of Python >= 2.1.0. As an end
  27 #   user, you can disable the check for the python version by setting the
  28 #   PYTHON_NOVERSIONCHECK environment variable to something else than the
  29 #   empty string.
  30 #
  31 #   If you need to use this macro for an older Python version, please
  32 #   contact the authors. We're always open for feedback.
  33 #
  34 # LICENSE
  35 #
  36 #   Copyright (c) 2009 Sebastian Huber <sebastian-huber@web.de>
  37 #   Copyright (c) 2009 Alan W. Irwin <irwin@beluga.phys.uvic.ca>
  38 #   Copyright (c) 2009 Rafael Laboissiere <rafael@laboissiere.net>
  39 #   Copyright (c) 2009 Andrew Collier <colliera@ukzn.ac.za>
  40 #   Copyright (c) 2009 Matteo Settenvini <matteo@member.fsf.org>
  41 #   Copyright (c) 2009 Horst Knorr <hk_classes@knoda.org>
  42 #
  43 #   This program is free software: you can redistribute it and/or modify it
  44 #   under the terms of the GNU General Public License as published by the
  45 #   Free Software Foundation, either version 3 of the License, or (at your
  46 #   option) any later version.
  47 #
  48 #   This program is distributed in the hope that it will be useful, but
  49 #   WITHOUT ANY WARRANTY; without even the implied warranty of
  50 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
  51 #   Public License for more details.
  52 #
  53 #   You should have received a copy of the GNU General Public License along
  54 #   with this program. If not, see <http://www.gnu.org/licenses/>.
  55 #
  56 #   As a special exception, the respective Autoconf Macro's copyright owner
  57 #   gives unlimited permission to copy, distribute and modify the configure
  58 #   scripts that are the output of Autoconf when processing the Macro. You
  59 #   need not follow the terms of the GNU General Public License when using
  60 #   or distributing such scripts, even though portions of the text of the
  61 #   Macro appear in them. The GNU General Public License (GPL) does govern
  62 #   all other use of the material that constitutes the Autoconf Macro.
  63 #
  64 #   This special exception to the GPL applies to versions of the Autoconf
  65 #   Macro released by the Autoconf Archive. When you make and distribute a
  66 #   modified version of the Autoconf Macro, you may extend this special
  67 #   exception to the GPL to apply to your modified version as well.
  68
  69 #serial 8
  70
  71 AC_DEFUN([AX_PYTHON_DEVEL],[
  72         #
  73         # Allow the use of a (user set) custom python version
  74         #
  75         AC_ARG_VAR([PYTHON_VERSION],[The installed Python
  76                 version to use, for example '2.3'. This string
  77                 will be appended to the Python interpreter
  78                 canonical name.])
  79
  80         AC_PATH_PROG([PYTHON],[python[$PYTHON_VERSION]])
  81         if test -z "$PYTHON"; then
  82            AC_MSG_ERROR([Cannot find python$PYTHON_VERSION in your system path])
  83            PYTHON_VERSION=""
  84         fi
  85
  86         #
  87         # Check for a version of Python >= 2.1.0
  88         #
  89         AC_MSG_CHECKING([for a version of Python >= '2.1.0'])
  90         ac_supports_python_ver=`$PYTHON -c "import sys; \
  91                 ver = sys.version.split ()[[0]]; \
  92                 print (ver >= '2.1.0')"`
  93         if test "$ac_supports_python_ver" != "True"; then
  94                 if test -z "$PYTHON_NOVERSIONCHECK"; then
  95                         AC_MSG_RESULT([no])
  96                         AC_MSG_FAILURE([
  97 This version of the AC@&t@_PYTHON_DEVEL macro
  98 doesn't work properly with versions of Python before
  99 2.1.0. You may need to re-run configure, setting the
 100 variables PYTHON_CPPFLAGS, PYTHON_LDFLAGS, PYTHON_SITE_PKG,
 101 PYTHON_EXTRA_LIBS and PYTHON_EXTRA_LDFLAGS by hand.
 102 Moreover, to disable this check, set PYTHON_NOVERSIONCHECK
 103 to something else than an empty string.
 104 ])
 105                 else
 106                         AC_MSG_RESULT([skip at user request])
 107                 fi
 108         else
 109                 AC_MSG_RESULT([yes])
 110         fi
 111
 112         #
 113         # if the macro parameter ``version'' is set, honour it
 114         #
 115         if test -n "$1"; then
 116                 AC_MSG_CHECKING([for a version of Python $1])
 117                 ac_supports_python_ver=`$PYTHON -c "import sys; \
 118                         ver = sys.version.split ()[[0]]; \
 119                         print (ver $1)"`
 120                 if test "$ac_supports_python_ver" = "True"; then
 121                    AC_MSG_RESULT([yes])
 122                 else
 123                         AC_MSG_RESULT([no])
 124                         AC_MSG_ERROR([this package requires Python $1.
 125 If you have it installed, but it isn't the default Python
 126 interpreter in your system path, please pass the PYTHON_VERSION
 127 variable to configure. See ``configure --help'' for reference.
 128 ])
 129                         PYTHON_VERSION=""
 130                 fi
 131         fi
 132
 133         #
 134         # Check if you have distutils, else fail
 135         #
 136         AC_MSG_CHECKING([for the distutils Python package])
 137         ac_distutils_result=`$PYTHON -c "import distutils" 2>&1`
 138         if test -z "$ac_distutils_result"; then
 139                 AC_MSG_RESULT([yes])
 140         else
 141                 AC_MSG_RESULT([no])
 142                 AC_MSG_ERROR([cannot import Python module "distutils".
 143 Please check your Python installation. The error was:
 144 $ac_distutils_result])
 145                 PYTHON_VERSION=""
 146         fi
 147
 148         #
 149         # Check for Python include path
 150         #
 151         AC_MSG_CHECKING([for Python include path])
 152         if test -z "$PYTHON_CPPFLAGS"; then
 153                 python_path=`$PYTHON -c "import distutils.sysconfig; \
 154                         print (distutils.sysconfig.get_python_inc ());"`
 155                 if test -n "${python_path}"; then
 156                         python_path="-I$python_path"
 157                 fi
 158                 PYTHON_CPPFLAGS=$python_path
 159         fi
 160         AC_MSG_RESULT([$PYTHON_CPPFLAGS])
 161         AC_SUBST([PYTHON_CPPFLAGS])
 162
 163         #
 164         # Check for Python library path
 165         #
 166         AC_MSG_CHECKING([for Python library path])
 167         if test -z "$PYTHON_LDFLAGS"; then
 168                 # (makes two attempts to ensure we've got a version number
 169                 # from the interpreter)
 170                 ac_python_version=`cat<<EOD | $PYTHON -
 171
 172 # join all versioning strings, on some systems
 173 # major/minor numbers could be in different list elements
 174 from distutils.sysconfig import *
 175 ret = ''
 176 for e in get_config_vars ('VERSION'):
 177         if (e != None):
 178                 ret += e
 179 print (ret)
 180 EOD`
 181
 182                 if test -z "$ac_python_version"; then
 183                         if test -n "$PYTHON_VERSION"; then
 184                                 ac_python_version=$PYTHON_VERSION
 185                         else
 186                                 ac_python_version=`$PYTHON -c "import sys; \
 187                                         print (sys.version[[:3]])"`
 188                         fi
 189                 fi
 190
 191                 # Make the versioning information available to the compiler
 192                 AC_DEFINE_UNQUOTED([HAVE_PYTHON], ["$ac_python_version"],
 193                                    [If available, contains the Python version number currently in use.])
 194
 195                 # First, the library directory:
 196                 ac_python_libdir=`cat<<EOD | $PYTHON -
 197
 198 # There should be only one
 199 import distutils.sysconfig
 200 for e in distutils.sysconfig.get_config_vars ('LIBDIR'):
 201         if e != None:
 202                 print (e)
 203                 break
 204 EOD`
 205
 206                 # Before checking for libpythonX.Y, we need to know
 207                 # the extension the OS we're on uses for libraries
 208                 # (we take the first one, if there's more than one fix me!):
 209                 ac_python_soext=`$PYTHON -c \
 210                   "import distutils.sysconfig; \
 211                   print (distutils.sysconfig.get_config_vars('SO')[[0]])"`
 212
 213                 # Now, for the library:
 214                 ac_python_soname=`$PYTHON -c \
 215                   "import distutils.sysconfig; \
 216                   print (distutils.sysconfig.get_config_vars('LDLIBRARY')[[0]])"`
 217
 218                 # Strip away extension from the end to canonicalize its name:
 219                 ac_python_library=`echo "$ac_python_soname" | sed "s/${ac_python_soext}$//"`
 220
 221                 # This small piece shamelessly adapted from PostgreSQL python macro;
 222                 # credits goes to momjian, I think. I'd like to put the right name
 223                 # in the credits, if someone can point me in the right direction... ?
 224                 #
 225                 if test -n "$ac_python_libdir" -a -n "$ac_python_library" \
 226                         -a x"$ac_python_library" != x"$ac_python_soname"
 227                 then
 228                         # use the official shared library
 229                         ac_python_library=`echo "$ac_python_library" | sed "s/^lib//"`
 230                         PYTHON_LDFLAGS="-L$ac_python_libdir -l$ac_python_library"
 231                 else
 232                         # old way: use libpython from python_configdir
 233                         ac_python_libdir=`$PYTHON -c \
 234                           "from distutils.sysconfig import get_python_lib as f; \
 235                           import os; \
 236                           print (os.path.join(f(plat_specific=1, standard_lib=1), 'config'));"`
 237                         PYTHON_LDFLAGS="-L$ac_python_libdir -lpython$ac_python_version"
 238                 fi
 239
 240                 if test -z "PYTHON_LDFLAGS"; then
 241                         AC_MSG_ERROR([
 242   Cannot determine location of your Python DSO. Please check it was installed with
 243   dynamic libraries enabled, or try setting PYTHON_LDFLAGS by hand.
 244                         ])
 245                 fi
 246         fi
 247         AC_MSG_RESULT([$PYTHON_LDFLAGS])
 248         AC_SUBST([PYTHON_LDFLAGS])
 249
 250         #
 251         # Check for site packages
 252         #
 253         AC_MSG_CHECKING([for Python site-packages path])
 254         if test -z "$PYTHON_SITE_PKG"; then
 255                 PYTHON_SITE_PKG=`$PYTHON -c "import distutils.sysconfig; \
 256                         print (distutils.sysconfig.get_python_lib(0,0));"`
 257         fi
 258         AC_MSG_RESULT([$PYTHON_SITE_PKG])
 259         AC_SUBST([PYTHON_SITE_PKG])
 260
 261         #
 262         # libraries which must be linked in when embedding
 263         #
 264         AC_MSG_CHECKING(python extra libraries)
 265         if test -z "$PYTHON_EXTRA_LIBS"; then
 266            PYTHON_EXTRA_LIBS=`$PYTHON -c "import distutils.sysconfig; \
 267                 conf = distutils.sysconfig.get_config_var; \
 268                 print (conf('LOCALMODLIBS') + ' ' + conf('LIBS'))"`
 269         fi
 270         AC_MSG_RESULT([$PYTHON_EXTRA_LIBS])
 271         AC_SUBST(PYTHON_EXTRA_LIBS)
 272
 273         #
 274         # linking flags needed when embedding
 275         #
 276         AC_MSG_CHECKING(python extra linking flags)
 277         if test -z "$PYTHON_EXTRA_LDFLAGS"; then
 278                 PYTHON_EXTRA_LDFLAGS=`$PYTHON -c "import distutils.sysconfig; \
 279                         conf = distutils.sysconfig.get_config_var; \
 280                         print (conf('LINKFORSHARED'))"`
 281         fi
 282         AC_MSG_RESULT([$PYTHON_EXTRA_LDFLAGS])
 283         AC_SUBST(PYTHON_EXTRA_LDFLAGS)
 284
 285         #
 286         # final check to see if everything compiles alright
 287         #
 288         AC_MSG_CHECKING([consistency of all components of python development environment])
 289         # save current global flags
 290         ac_save_LIBS="$LIBS"
 291         ac_save_CPPFLAGS="$CPPFLAGS"
 292         LIBS="$ac_save_LIBS $PYTHON_LDFLAGS $PYTHON_EXTRA_LDFLAGS $PYTHON_EXTRA_LIBS"
 293         CPPFLAGS="$ac_save_CPPFLAGS $PYTHON_CPPFLAGS"
 294         AC_LANG_PUSH([C])
 295         AC_LINK_IFELSE([
 296                 AC_LANG_PROGRAM([[#include <Python.h>]],
 297                                 [[Py_Initialize();]])
 298                 ],[pythonexists=yes],[pythonexists=no])
 299         AC_LANG_POP([C])
 300         # turn back to default flags
 301         CPPFLAGS="$ac_save_CPPFLAGS"
 302         LIBS="$ac_save_LIBS"
 303
 304         AC_MSG_RESULT([$pythonexists])
 305
 306         if test ! "x$pythonexists" = "xyes"; then
 307            AC_MSG_FAILURE([
 308   Could not link test program to Python. Maybe the main Python library has been
 309   installed in some non-standard library path. If so, pass it to configure,
 310   via the LDFLAGS environment variable.
 311   Example: ./configure LDFLAGS="-L/usr/non-standard-path/python/lib"
 312   ============================================================================
 313    ERROR!
 314    You probably have to install the development version of the Python package
 315    for your distribution.  The exact name of this package varies among them.
 316   ============================================================================
 317            ])
 318           PYTHON_VERSION=""
 319         fi
 320
 321         #
 322         # all done!
 323         #
 324 ])
 325 AC_DEFUN([AC_PYTHON_DEVEL], [AX_PYTHON_DEVEL])