adm/unix/config_files/ac_pkg_swig.m4

   1 dnl  Copyright (C) 2006-2008  CEA/DEN, EDF R&D
   2 dnl
   3 dnl  This library is free software; you can redistribute it and/or
   4 dnl  modify it under the terms of the GNU Lesser General Public
   5 dnl  License as published by the Free Software Foundation; either
   6 dnl  version 2.1 of the License.
   7 dnl
   8 dnl  This library is distributed in the hope that it will be useful,
   9 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  11 dnl  Lesser General Public License for more details.
  12 dnl
  13 dnl  You should have received a copy of the GNU Lesser General Public
  14 dnl  License along with this library; if not, write to the Free Software
  15 dnl  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
  16 dnl
  17 dnl  See http://www.salome-platform.org/ or email : webmaster.salome@opencascade.com
  18 dnl
  19 dnl @synopsis AC_PROG_SWIG([major.minor.micro])
  20 dnl This macro searches for a SWIG installation on your system. If found you
  21 dnl should) SWIG via $(SWIG).  You can use the optional first argument to check
  22 dnl if the version of the available SWIG is greater than or equal to the
  23 dnl value of the argument.  It should have the format: N[.N[.N]] (N is a
  24 dnl number between 0 and 999.  Only the first N is mandatory.)
  25 dnl If the version argument is given (e.g. 1.3.17), AC_PROG_SWIG checks that the
  26 dnl swig package is this version number or higher.
  27 dnl In configure.in, use as:
  28 dnl             AC_PROG_SWIG(1.3.17)
  29 dnl             SWIG_ENABLE_CXX
  30 dnl             SWIG_MULTI_MODULE_SUPPORT
  31 dnl             SWIG_PYTHON
  32 dnl @authors Sebastian Huber <address@hidden>, Alan W. Irwin
  33 dnl <address@hidden>, Rafael Laboissiere <address@hidden> and
  34 dnl Andrew Collier <address@hidden>.
  35 dnl
  36 AC_DEFUN([AC_PROG_SWIG],[
  37   swig_ok=no
  38         AC_PATH_PROG([SWIG],[swig])
  39         if test -z "$SWIG" ; then
  40                 AC_MSG_WARN([cannot find 'swig' program. You should look at http://www.swig.org])
  41                 SWIG='echo "Error: SWIG is not installed. You should look at http://www.swig.org" ; false'
  42         elif test -n "$1" ; then
  43                 AC_MSG_CHECKING([for SWIG version])
  44                 [swig_version=`$SWIG -version 2>&1 | grep 'SWIG Version' | sed 's/.*\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\).*/\1/g'`]
  45                 AC_MSG_RESULT([$swig_version])
  46                 if test -n "$swig_version" ; then
  47                         # Calculate the required version number components
  48                         [required=$1]
  49                         [required_major=`echo $required | sed 's/[^0-9].*//'`]
  50                         if test -z "$required_major" ; then
  51                                 [required_major=0]
  52                         fi
  53                         [required=`echo $required | sed 's/[0-9]*[^0-9]//'`]
  54                         [required_minor=`echo $required | sed 's/[^0-9].*//'`]
  55                         if test -z "$required_minor" ; then
  56                                 [required_minor=0]
  57                         fi
  58                         [required=`echo $required | sed 's/[0-9]*[^0-9]//'`]
  59                         [required_patch=`echo $required | sed 's/[^0-9].*//'`]
  60                         if test -z "$required_patch" ; then
  61                                 [required_patch=0]
  62                         fi
  63                         # Calculate the available version number components
  64                         [available=$swig_version]
  65                         [available_major=`echo $available | sed 's/[^0-9].*//'`]
  66                         if test -z "$available_major" ; then
  67                                 [available_major=0]
  68                         fi
  69                         [available=`echo $available | sed 's/[0-9]*[^0-9]//'`]
  70                         [available_minor=`echo $available | sed 's/[^0-9].*//'`]
  71                         if test -z "$available_minor" ; then
  72                                 [available_minor=0]
  73                         fi
  74                         [available=`echo $available | sed 's/[0-9]*[^0-9]//'`]
  75                         [available_patch=`echo $available | sed 's/[^0-9].*//'`]
  76                         if test -z "$available_patch" ; then
  77                                 [available_patch=0]
  78                         fi
  79                         if test $available_major -ne $required_major \
  80                                 -o $available_minor -ne $required_minor \
  81                                 -o $available_patch -lt $required_patch ; then
  82                                 AC_MSG_WARN([SWIG version >= $1 is required.  You have $swig_version.  You should look at http://www.swig.org])
  83                                 SWIG='echo "Error: SWIG version >= $1 is required.  You have '"$swig_version"'.  You should look at http://www.swig.org" ; false'
  84                         else
  85                                 AC_MSG_NOTICE([SWIG executable is '$SWIG'])
  86         swig_ok=yes
  87                                 SWIG_LIB=`$SWIG -swiglib`
  88                                 AC_MSG_NOTICE([SWIG runtime library directory is '$SWIG_LIB'])
  89                         fi
  90                 else
  91                         AC_MSG_WARN([cannot determine SWIG version])
  92                         SWIG='echo "Error: Cannot determine SWIG version.  You should look at http://www.swig.org" ; false'
  93                 fi
  94         fi
  95         AC_SUBST([SWIG_LIB])
  96 ])
  97
  98 # SWIG_ENABLE_CXX()
  99 #
 100 # Enable SWIG C++ support.  This affects all invocations of $(SWIG).
 101 AC_DEFUN([SWIG_ENABLE_CXX],[
 102         AC_REQUIRE([AC_PROG_SWIG])
 103         AC_REQUIRE([AC_PROG_CXX])
 104         SWIG="$SWIG -c++"
 105 ])
 106
 107 # SWIG_MULTI_MODULE_SUPPORT()
 108 #
 109 # Enable support for multiple modules.  This effects all invocations
 110 # of $(SWIG).  You have to link all generated modules against the
 111 # appropriate SWIG runtime library.  If you want to build Python
 112 # modules for example, use the SWIG_PYTHON() macro and link the
 113 # modules against $(SWIG_PYTHON_LIBS).
 114 AC_DEFUN([SWIG_MULTI_MODULE_SUPPORT],[
 115         AC_REQUIRE([AC_PROG_SWIG])
 116         SWIG="$SWIG -c"
 117 ])
 118
 119 # SWIG_PYTHON([use-shadow-classes = {no, yes}])
 120 #
 121 # Checks for Python and provides the $(SWIG_PYTHON_CPPFLAGS),
 122 # $(SWIG_PYTHON_LIBS) and $(SWIG_PYTHON_OPT) output variables.
 123 # $(SWIG_PYTHON_OPT) contains all necessary SWIG options to generate
 124 # code for Python.  Shadow classes are enabled unless the value of the
 125 # optional first argument is exactly 'no'.  If you need multi module
 126 # support (provided by the SWIG_MULTI_MODULE_SUPPORT() macro) use
 127 # $(SWIG_PYTHON_LIBS) to link against the appropriate library.  It
 128 # contains the SWIG Python runtime library that is needed by the type
 129 # check system for example.
 130 AC_DEFUN([SWIG_PYTHON],[
 131         AC_REQUIRE([AC_PROG_SWIG])
 132         AC_REQUIRE([AC_PYTHON_DEVEL])
 133         test "x$1" != "xno" || swig_shadow=" -noproxy"
 134         AC_SUBST([SWIG_PYTHON_OPT],[-python$swig_shadow])
 135         AC_SUBST([SWIG_PYTHON_CPPFLAGS],[$PYTHON_CPPFLAGS])
 136         AC_SUBST([SWIG_PYTHON_LIBS],["-L$SWIG_LIB -lswigpy"])
 137 ])
 138
 139
 140 dnl @synopsis AC_LIB_WAD
 141 dnl
 142 dnl This macro searches for installed WAD library.
 143 dnl
 144 AC_DEFUN([AC_LIB_WAD],
 145 [
 146         AC_REQUIRE([AC_PYTHON_DEVEL])
 147         AC_ARG_ENABLE(wad,
 148         AC_HELP_STRING([--enable-wad], [enable wad module]),
 149         [
 150                 case "${enableval}" in
 151                         no)     ;;
 152                         *)      if test "x${enableval}" = xyes;
 153                                 then
 154                                         check_wad="yes"
 155                                 fi ;;
 156                 esac
 157         ], [])
 158
 159         if test -n "$check_wad";
 160         then
 161                 AC_CHECK_LIB(wadpy, _init, [WADPY=-lwadpy], [], $PYTHON_LDFLAGS $PYTHON_EXTRA_LIBS)
 162                 AC_SUBST(WADPY)
 163         fi
 164 ])